diff --git a/ale_linters/rst/rstcheck.vim b/ale_linters/rst/rstcheck.vim
index e0cf0798..85886a11 100644
--- a/ale_linters/rst/rstcheck.vim
+++ b/ale_linters/rst/rstcheck.vim
@@ -1,5 +1,13 @@
-" Author: John Nduli https://github.com/jnduli
-" Description: Rstcheck for reStructuredText files
+" Authors:
+"   John Nduli https://github.com/jnduli,
+"   Michael Goerz https://github.com/goerz
+
+call ale#Set('rst_rstcheck_executable', 'rstcheck')
+call ale#Set('rst_rstcheck_options', '')
+
+function! ale_linters#rst#rstcheck#GetExecutable(buffer) abort
+    return ale#Var(a:buffer, 'rst_rstcheck_executable')
+endfunction
 
 function! ale_linters#rst#rstcheck#Handle(buffer, lines) abort
     " matches: 'bad_rst.rst:1: (SEVERE/4) Title overline & underline
@@ -21,11 +29,35 @@ function! ale_linters#rst#rstcheck#Handle(buffer, lines) abort
     return l:output
 endfunction
 
+function! ale_linters#rst#rstcheck#GetCommand(buffer, version) abort
+    let l:executable = ale_linters#rst#rstcheck#GetExecutable(a:buffer)
+    let l:options = ale#Var(a:buffer, 'rst_rstcheck_options')
+    let l:dir = expand('#' . a:buffer . ':p:h')
+    let l:exec_args = ale#Pad(l:options)
+
+    if ale#semver#GTE(a:version, [3, 4, 0])
+        let l:exec_args .= ' --config ' . ale#Escape(l:dir)
+    endif
+
+    return ale#Escape(l:executable)
+    \   . l:exec_args
+    \   . ' %t'
+endfunction
+
+function! ale_linters#rst#rstcheck#GetCommandWithVersionCheck(buffer) abort
+    return ale#semver#RunWithVersionCheck(
+    \   a:buffer,
+    \   ale_linters#rst#rstcheck#GetExecutable(a:buffer),
+    \   '%e --version',
+    \   function('ale_linters#rst#rstcheck#GetCommand')
+    \)
+endfunction
+
 call ale#linter#Define('rst', {
 \   'name': 'rstcheck',
 \   'executable': 'rstcheck',
 \   'cwd': '%s:h',
-\   'command': 'rstcheck %t',
+\   'command': function('ale_linters#rst#rstcheck#GetCommandWithVersionCheck'),
 \   'callback': 'ale_linters#rst#rstcheck#Handle',
 \   'output_stream': 'both',
 \})
diff --git a/test/linter/test_rst_rstcheck.vader b/test/linter/test_rst_rstcheck.vader
new file mode 100644
index 00000000..3d57ecb7
--- /dev/null
+++ b/test/linter/test_rst_rstcheck.vader
@@ -0,0 +1,63 @@
+Before:
+  call ale#assert#SetUpLinterTest('rst', 'rstcheck')
+
+After:
+  call ale#assert#TearDownLinterTest()
+
+Execute(The default command should include --config for rstcheck >= 3.4.0):
+  GivenCommandOutput ['rstcheck, version 3.4.0']
+
+  AssertLinter 'rstcheck', [
+  \ ale#Escape('rstcheck') . ' --version',
+  \ ale#Escape('rstcheck')
+  \   . ' --config '
+  \   . ale#Escape(expand('#' . bufnr('') . ':p:h'))
+  \   . ' %t',
+  \]
+
+Execute(The version check should be cached):
+  GivenCommandOutput ['rstcheck, version 3.4.0']
+
+  AssertLinter 'rstcheck', [
+  \ ale#Escape('rstcheck') . ' --version',
+  \ ale#Escape('rstcheck')
+  \   . ' --config '
+  \   . ale#Escape(expand('#' . bufnr('') . ':p:h'))
+  \   . ' %t',
+  \]
+
+  GivenCommandOutput []
+
+  AssertLinter 'rstcheck', [
+  \ ale#Escape('rstcheck')
+  \   . ' --config '
+  \   . ale#Escape(expand('#' . bufnr('') . ':p:h'))
+  \   . ' %t',
+  \]
+
+Execute(The default command should not include --config for older versions):
+  call ale#semver#ResetVersionCache()
+  GivenCommandOutput ['rstcheck, version 3.3.0']
+
+  AssertLinter 'rstcheck', [
+  \ ale#Escape('rstcheck') . ' --version',
+  \ ale#Escape('rstcheck') . ' %t',
+  \]
+
+Execute(The command executable and options should be configurable):
+  call ale#semver#ResetVersionCache()
+  let b:ale_rst_rstcheck_executable = 'rstcheck2'
+  let b:ale_rst_rstcheck_options = '--ignore-language=cpp'
+  GivenCommandOutput ['rstcheck2, version 3.4.0']
+
+  AssertLinter 'rstcheck', [
+  \ ale#Escape('rstcheck2') . ' --version',
+  \ ale#Escape('rstcheck2')
+  \   . ' --ignore-language=cpp'
+  \   . ' --config '
+  \   . ale#Escape(expand('#' . bufnr('') . ':p:h'))
+  \   . ' %t',
+  \]
+
+Execute(The linter should run with the current buffer directory as cwd):
+  AssertLinterCwd '%s:h'