Add ALERename (tsserver & LSP), ALEOrganizeImports (tsserver) and auto import support (tsserver) (#2709)

This commit adds support for renaming symbols in tsserver and with LSP tools, and for organising imports with tsserver. Completion results for symbols that can be imported are now suggested if enabled for tsserver completion done via ALE.

autoload/ale/code_action.vim

@@ -0,0 +1,163 @@
+" Author: Jerko Steiner <jerko.steiner@gmail.com>
+" Description: Code action support for LSP / tsserver
+
+function! ale#code_action#HandleCodeAction(code_action) abort
+    let l:current_buffer = bufnr('')
+    let l:changes = a:code_action.changes
+
+    for l:file_code_edit in l:changes
+        let l:buf = bufnr(l:file_code_edit.fileName)
+
+        if l:buf != -1 && l:buf != l:current_buffer && getbufvar(l:buf, '&mod')
+            call ale#util#Execute('echom ''Aborting action, file is unsaved''')
+
+            return
+        endif
+    endfor
+
+    for l:file_code_edit in l:changes
+        call ale#code_action#ApplyChanges(
+        \ l:file_code_edit.fileName, l:file_code_edit.textChanges)
+    endfor
+endfunction
+
+function! ale#code_action#ApplyChanges(filename, changes) abort
+    let l:current_buffer = bufnr('')
+    " The buffer is used to determine the fileformat, if available.
+    let l:buffer = bufnr(a:filename)
+    let l:is_current_buffer = l:buffer > 0 && l:buffer == l:current_buffer
+
+    if l:buffer > 0
+        let l:lines = getbufline(l:buffer, 1, '$')
+    else
+        let l:lines = readfile(a:filename, 'b')
+    endif
+
+    if l:is_current_buffer
+        let l:pos = getpos('.')[1:2]
+    else
+        let l:pos = [1, 1]
+    endif
+
+    " We have to keep track of how many lines we have added, and offset
+    " changes accordingly.
+    let l:line_offset = 0
+    let l:column_offset = 0
+    let l:last_end_line = 0
+
+    for l:code_edit in a:changes
+        if l:code_edit.start.line isnot l:last_end_line
+            let l:column_offset = 0
+        endif
+
+        let l:line = l:code_edit.start.line + l:line_offset
+        let l:column = l:code_edit.start.offset + l:column_offset
+        let l:end_line = l:code_edit.end.line + l:line_offset
+        let l:end_column = l:code_edit.end.offset + l:column_offset
+        let l:text = l:code_edit.newText
+
+        let l:cur_line = l:pos[0]
+        let l:cur_column = l:pos[1]
+
+        let l:last_end_line = l:end_line
+
+        " Adjust the ends according to previous edits.
+        if l:end_line > len(l:lines)
+            let l:end_line_len = 0
+        else
+            let l:end_line_len = len(l:lines[l:end_line - 1])
+        endif
+
+        let l:insertions = split(l:text, '\n', 1)
+
+        if l:line is 1
+            " Same logic as for column below. Vimscript's slice [:-1] will not
+            " be an empty list.
+            let l:start = []
+        else
+            let l:start = l:lines[: l:line - 2]
+        endif
+
+        if l:column is 1
+            " We need to handle column 1 specially, because we can't slice an
+            " empty string ending on index 0.
+            let l:middle = [l:insertions[0]]
+        else
+            let l:middle = [l:lines[l:line - 1][: l:column - 2] . l:insertions[0]]
+        endif
+
+        call extend(l:middle, l:insertions[1:])
+        let l:middle[-1] .= l:lines[l:end_line - 1][l:end_column - 1 :]
+
+        let l:lines_before_change = len(l:lines)
+        let l:lines = l:start + l:middle + l:lines[l:end_line :]
+
+        let l:current_line_offset = len(l:lines) - l:lines_before_change
+        let l:line_offset += l:current_line_offset
+        let l:column_offset = len(l:middle[-1]) - l:end_line_len
+
+        let l:pos = s:UpdateCursor(l:pos,
+        \ [l:line, l:column],
+        \ [l:end_line, l:end_column],
+        \ [l:current_line_offset, l:column_offset])
+    endfor
+
+    if l:lines[-1] is# ''
+        call remove(l:lines, -1)
+    endif
+
+    call ale#util#Writefile(l:buffer, l:lines, a:filename)
+
+    if l:is_current_buffer
+        call ale#util#Execute(':e!')
+        call setpos('.', [0, l:pos[0], l:pos[1], 0])
+    endif
+endfunction
+
+function! s:UpdateCursor(cursor, start, end, offset) abort
+    let l:cur_line = a:cursor[0]
+    let l:cur_column = a:cursor[1]
+    let l:line = a:start[0]
+    let l:column = a:start[1]
+    let l:end_line = a:end[0]
+    let l:end_column = a:end[1]
+    let l:line_offset = a:offset[0]
+    let l:column_offset = a:offset[1]
+
+    if l:end_line < l:cur_line
+        " both start and end lines are before the cursor. only line offset
+        " needs to be updated
+        let l:cur_line += l:line_offset
+    elseif l:end_line == l:cur_line
+        " end line is at the same location as cursor, which means
+        " l:line <= l:cur_line
+        if l:line < l:cur_line || l:column <= l:cur_column
+            " updates are happening either before or around the cursor
+            if l:end_column < l:cur_column
+                " updates are happening before the cursor, update the
+                " column offset for cursor
+                let l:cur_line += l:line_offset
+                let l:cur_column += l:column_offset
+            else
+                " updates are happening around the cursor, move the cursor
+                " to the end of the changes
+                let l:cur_line += l:line_offset
+                let l:cur_column = l:end_column + l:column_offset
+            endif
+        " else is not necessary, it means modifications are happening
+        " after the cursor so no cursor updates need to be done
+        endif
+    else
+        " end line is after the cursor
+        if l:line < l:cur_line || l:line == l:cur_line && l:column <= l:cur_column
+            " changes are happening around the cursor, move the cursor
+            " to the end of the changes
+            let l:cur_line = l:end_line + l:line_offset
+            let l:cur_column = l:end_column + l:column_offset
+        " else is not necesary, it means modifications are happening
+        " after the cursor so no cursor updates need to be done
+        endif
+    endif
+
+    return [l:cur_line, l:cur_column]
+endfunction

autoload/ale/completion.vim

@@ -15,6 +15,7 @@ onoremap <silent> <Plug>(ale_show_completion_menu) <Nop>
 let g:ale_completion_delay = get(g:, 'ale_completion_delay', 100)
 let g:ale_completion_excluded_words = get(g:, 'ale_completion_excluded_words', [])
 let g:ale_completion_max_suggestions = get(g:, 'ale_completion_max_suggestions', 50)
+let g:ale_completion_tsserver_autoimport = get(g:, 'ale_completion_tsserver_autoimport', 0)
 
 let s:timer_id = -1
 let s:last_done_pos = []
@@ -296,7 +297,10 @@ function! ale#completion#ParseTSServerCompletions(response) abort
     let l:names = []
 
     for l:suggestion in a:response.body
-        call add(l:names, l:suggestion.name)
+        call add(l:names, {
+        \ 'word': l:suggestion.name,
+        \ 'source': get(l:suggestion, 'source', ''),
+        \})
     endfor
 
     return l:names
@@ -330,13 +334,22 @@ function! ale#completion#ParseTSServerCompletionEntryDetails(response) abort
         endif
 
         " See :help complete-items
-        call add(l:results, {
+        let l:result = {
         \   'word': l:suggestion.name,
         \   'kind': l:kind,
         \   'icase': 1,
         \   'menu': join(l:displayParts, ''),
+        \   'dup': g:ale_completion_tsserver_autoimport,
         \   'info': join(l:documentationParts, ''),
-        \})
+        \}
+
+        if has_key(l:suggestion, 'codeActions')
+            let l:result.user_data = json_encode({
+            \   'codeActions': l:suggestion.codeActions,
+            \ })
+        endif
+
+        call add(l:results, l:result)
     endfor
 
     let l:names = getbufvar(l:buffer, 'ale_tsserver_completion_names', [])
@@ -345,12 +358,12 @@ function! ale#completion#ParseTSServerCompletionEntryDetails(response) abort
         let l:names_with_details = map(copy(l:results), 'v:val.word')
         let l:missing_names = filter(
         \   copy(l:names),
-        \   'index(l:names_with_details, v:val) < 0',
+        \   'index(l:names_with_details, v:val.word) < 0',
         \)
 
         for l:name in l:missing_names
             call add(l:results, {
-            \   'word': l:name,
+            \   'word': l:name.word,
             \   'kind': 'v',
             \   'icase': 1,
             \   'menu': '',
@@ -472,13 +485,22 @@ function! ale#completion#HandleTSServerResponse(conn_id, response) abort
         call setbufvar(l:buffer, 'ale_tsserver_completion_names', l:names)
 
         if !empty(l:names)
+            let l:identifiers = []
+
+            for l:name in l:names
+                call add(l:identifiers, {
+                \   'name': l:name.word,
+                \   'source': get(l:name, 'source', ''),
+                \})
+            endfor
+
             let b:ale_completion_info.request_id = ale#lsp#Send(
             \   b:ale_completion_info.conn_id,
             \   ale#lsp#tsserver_message#CompletionEntryDetails(
             \       l:buffer,
             \       b:ale_completion_info.line,
             \       b:ale_completion_info.column,
-            \       l:names,
+            \       l:identifiers,
             \   ),
             \)
         endif
@@ -525,6 +547,7 @@ function! s:OnReady(linter, lsp_details) abort
         \   b:ale_completion_info.line,
         \   b:ale_completion_info.column,
         \   b:ale_completion_info.prefix,
+        \   g:ale_completion_tsserver_autoimport,
         \)
     else
         " Send a message saying the buffer has changed first, otherwise
@@ -692,6 +715,26 @@ function! ale#completion#Queue() abort
     let s:timer_id = timer_start(g:ale_completion_delay, function('s:TimerHandler'))
 endfunction
 
+function! ale#completion#HandleUserData(completed_item) abort
+    let l:source = get(get(b:, 'ale_completion_info', {}), 'source', '')
+
+    if l:source isnot# 'ale-automatic' && l:source isnot# 'ale-manual'
+        return
+    endif
+
+    let l:user_data_json = get(a:completed_item, 'user_data', '')
+
+    if empty(l:user_data_json)
+        return
+    endif
+
+    let l:user_data = json_decode(l:user_data_json)
+
+    for l:code_action in get(l:user_data, 'codeActions', [])
+        call ale#code_action#HandleCodeAction(l:code_action)
+    endfor
+endfunction
+
 function! ale#completion#Done() abort
     silent! pclose
 
@@ -700,6 +743,10 @@ function! ale#completion#Done() abort
     let s:last_done_pos = getpos('.')[1:2]
 endfunction
 
+augroup ALECompletionActions
+    autocmd CompleteDone * call ale#completion#HandleUserData(v:completed_item)
+augroup END
+
 function! s:Setup(enabled) abort
     augroup ALECompletionGroup
         autocmd!

autoload/ale/lsp.vim

@@ -37,6 +37,7 @@ function! ale#lsp#Register(executable_or_address, project, init_options) abort
         \   'init_queue': [],
         \   'capabilities': {
         \       'hover': 0,
+        \       'rename': 0,
         \       'references': 0,
         \       'completion': 0,
         \       'completion_trigger_characters': [],
@@ -199,6 +200,10 @@ function! s:UpdateCapabilities(conn, capabilities) abort
         let a:conn.capabilities.references = 1
     endif
 
+    if get(a:capabilities, 'renameProvider') is v:true
+        let a:conn.capabilities.rename = 1
+    endif
+
     if !empty(get(a:capabilities, 'completionProvider'))
         let a:conn.capabilities.completion = 1
     endif
@@ -317,6 +322,7 @@ function! ale#lsp#MarkConnectionAsTsserver(conn_id) abort
     let l:conn.capabilities.completion_trigger_characters = ['.']
     let l:conn.capabilities.definition = 1
     let l:conn.capabilities.symbol_search = 1
+    let l:conn.capabilities.rename = 1
 endfunction
 
 function! s:SendInitMessage(conn) abort

autoload/ale/lsp/message.vim

@@ -162,3 +162,13 @@ function! ale#lsp#message#DidChangeConfiguration(buffer, config) abort
     \   'settings': a:config,
     \}]
 endfunction
+
+function! ale#lsp#message#Rename(buffer, line, column, new_name) abort
+    return [0, 'textDocument/rename', {
+    \   'textDocument': {
+    \       'uri': ale#path#ToURI(expand('#' . a:buffer . ':p')),
+    \   },
+    \   'position': {'line': a:line - 1, 'character': a:column - 1},
+    \   'newName': a:new_name,
+    \}]
+endfunction

autoload/ale/lsp/tsserver_message.vim

@@ -36,12 +36,14 @@ function! ale#lsp#tsserver_message#Geterr(buffer) abort
     return [1, 'ts@geterr', {'files': [expand('#' . a:buffer . ':p')]}]
 endfunction
 
-function! ale#lsp#tsserver_message#Completions(buffer, line, column, prefix) abort
+function! ale#lsp#tsserver_message#Completions(
+\ buffer, line, column, prefix, include_external) abort
     return [0, 'ts@completions', {
     \   'line': a:line,
     \   'offset': a:column,
     \   'file': expand('#' . a:buffer . ':p'),
     \   'prefix': a:prefix,
+    \   'includeExternalModuleExports': a:include_external,
     \}]
 endfunction
 
@@ -77,3 +79,27 @@ function! ale#lsp#tsserver_message#Quickinfo(buffer, line, column) abort
     \   'file': expand('#' . a:buffer . ':p'),
     \}]
 endfunction
+
+function! ale#lsp#tsserver_message#Rename(
+\ buffer, line, column, find_in_comments, find_in_strings) abort
+    return [0, 'ts@rename', {
+    \   'line': a:line,
+    \   'offset': a:column,
+    \   'file': expand('#' . a:buffer . ':p'),
+    \   'arguments': {
+    \       'findInComments': a:find_in_comments,
+    \       'findInStrings': a:find_in_strings,
+    \   }
+    \}]
+endfunction
+
+function! ale#lsp#tsserver_message#OrganizeImports(buffer) abort
+    return [0, 'ts@organizeImports', {
+    \   'scope': {
+    \       'type': 'file',
+    \       'args': {
+    \           'file': expand('#' . a:buffer . ':p'),
+    \       },
+    \   },
+    \}]
+endfunction

autoload/ale/organize_imports.vim

@@ -0,0 +1,59 @@
+" Author: Jerko Steiner <jerko.steiner@gmail.com>
+" Description: Organize imports support for tsserver
+"
+function! ale#organize_imports#HandleTSServerResponse(conn_id, response) abort
+    if get(a:response, 'command', '') isnot# 'organizeImports'
+        return
+    endif
+
+    if get(a:response, 'success', v:false) isnot v:true
+        return
+    endif
+
+    let l:file_code_edits =  a:response.body
+
+    call ale#code_action#HandleCodeAction({
+    \   'description': 'Organize Imports',
+    \   'changes': l:file_code_edits,
+    \})
+endfunction
+
+function! s:OnReady(linter, lsp_details) abort
+    let l:id = a:lsp_details.connection_id
+
+    if a:linter.lsp isnot# 'tsserver'
+        call ale#util#Execute('echom ''OrganizeImports currently only works with tsserver''')
+
+        return
+    endif
+
+    let l:buffer = a:lsp_details.buffer
+
+    let l:Callback = function('ale#organize_imports#HandleTSServerResponse')
+
+    call ale#lsp#RegisterCallback(l:id, l:Callback)
+
+    let l:message = ale#lsp#tsserver_message#OrganizeImports(l:buffer)
+
+    let l:request_id = ale#lsp#Send(l:id, l:message)
+endfunction
+
+function! s:OrganizeImports(linter) abort
+    let l:buffer = bufnr('')
+    let [l:line, l:column] = getpos('.')[1:2]
+
+    if a:linter.lsp isnot# 'tsserver'
+        let l:column = min([l:column, len(getline(l:line))])
+    endif
+
+    let l:Callback = function('s:OnReady')
+    call ale#lsp_linter#StartLSP(l:buffer, a:linter, l:Callback)
+endfunction
+
+function! ale#organize_imports#Execute() abort
+    for l:linter in ale#linter#Get(&filetype)
+        if !empty(l:linter.lsp)
+            call s:OrganizeImports(l:linter)
+        endif
+    endfor
+endfunction

autoload/ale/rename.vim

@@ -0,0 +1,225 @@
+" Author: Jerko Steiner <jerko.steiner@gmail.com>
+" Description: Rename symbol support for LSP / tsserver
+
+let s:rename_map = {}
+
+" Used to get the rename map in tests.
+function! ale#rename#GetMap() abort
+    return deepcopy(s:rename_map)
+endfunction
+
+" Used to set the rename map in tests.
+function! ale#rename#SetMap(map) abort
+    let s:rename_map = a:map
+endfunction
+
+function! ale#rename#ClearLSPData() abort
+    let s:rename_map = {}
+endfunction
+
+let g:ale_rename_tsserver_find_in_comments = get(g:, 'ale_rename_tsserver_find_in_comments')
+let g:ale_rename_tsserver_find_in_strings = get(g:, 'ale_rename_tsserver_find_in_strings')
+
+function! s:message(message) abort
+    call ale#util#Execute('echom ' . string(a:message))
+endfunction
+
+function! ale#rename#HandleTSServerResponse(conn_id, response) abort
+    if get(a:response, 'command', '') isnot# 'rename'
+        return
+    endif
+
+    if !has_key(s:rename_map, a:response.request_seq)
+        return
+    endif
+
+    let l:old_name = s:rename_map[a:response.request_seq].old_name
+    let l:new_name = s:rename_map[a:response.request_seq].new_name
+    call remove(s:rename_map, a:response.request_seq)
+
+    if get(a:response, 'success', v:false) is v:false
+        let l:message = get(a:response, 'message', 'unknown')
+        call s:message('Error renaming "' . l:old_name . '" to: "' . l:new_name
+        \ . '". Reason: ' . l:message)
+
+        return
+    endif
+
+    let l:changes = []
+
+    for l:response_item in a:response.body.locs
+        let l:filename = l:response_item.file
+        let l:text_changes = []
+
+        for l:loc in l:response_item.locs
+            call add(l:text_changes, {
+            \ 'start': {
+            \   'line': l:loc.start.line,
+            \   'offset': l:loc.start.offset,
+            \ },
+            \ 'end': {
+            \   'line': l:loc.end.line,
+            \   'offset': l:loc.end.offset,
+            \ },
+            \ 'newText': l:new_name,
+            \})
+        endfor
+
+        call add(l:changes, {
+        \   'fileName': l:filename,
+        \   'textChanges': l:text_changes,
+        \})
+    endfor
+
+    if empty(l:changes)
+        call s:message('Error renaming "' . l:old_name . '" to: "' . l:new_name . '"')
+
+        return
+    endif
+
+    call ale#code_action#HandleCodeAction({
+    \ 'description': 'rename',
+    \ 'changes': l:changes,
+    \})
+endfunction
+
+function! ale#rename#HandleLSPResponse(conn_id, response) abort
+    if has_key(a:response, 'id')
+    \&& has_key(s:rename_map, a:response.id)
+        call remove(s:rename_map, a:response.id)
+
+        if !has_key(a:response, 'result')
+            call s:message('No rename result received from server')
+
+            return
+        endif
+
+        let l:workspace_edit = a:response.result
+
+        if !has_key(l:workspace_edit, 'changes') || empty(l:workspace_edit.changes)
+            call s:message('No changes received from server')
+
+            return
+        endif
+
+        let l:changes = []
+
+        for l:file_name in keys(l:workspace_edit.changes)
+            let l:text_edits = l:workspace_edit.changes[l:file_name]
+            let l:text_changes = []
+
+            for l:edit in l:text_edits
+                let l:range = l:edit.range
+                let l:new_text = l:edit.newText
+
+                call add(l:text_changes, {
+                \ 'start': {
+                \   'line': l:range.start.line + 1,
+                \   'offset': l:range.start.character + 1,
+                \ },
+                \ 'end': {
+                \   'line': l:range.end.line + 1,
+                \   'offset': l:range.end.character + 1,
+                \ },
+                \ 'newText': l:new_text,
+                \})
+            endfor
+
+            call add(l:changes, {
+            \   'fileName': ale#path#FromURI(l:file_name),
+            \   'textChanges': l:text_changes,
+            \})
+        endfor
+
+        call ale#code_action#HandleCodeAction({
+        \   'description': 'rename',
+        \   'changes': l:changes,
+        \})
+    endif
+endfunction
+
+function! s:OnReady(line, column, old_name, new_name, linter, lsp_details) abort
+    let l:id = a:lsp_details.connection_id
+
+    if !ale#lsp#HasCapability(l:id, 'rename')
+        return
+    endif
+
+    let l:buffer = a:lsp_details.buffer
+
+    let l:Callback = a:linter.lsp is# 'tsserver'
+    \   ? function('ale#rename#HandleTSServerResponse')
+    \   : function('ale#rename#HandleLSPResponse')
+
+    call ale#lsp#RegisterCallback(l:id, l:Callback)
+
+    if a:linter.lsp is# 'tsserver'
+        let l:message = ale#lsp#tsserver_message#Rename(
+        \   l:buffer,
+        \   a:line,
+        \   a:column,
+        \   g:ale_rename_tsserver_find_in_comments,
+        \   g:ale_rename_tsserver_find_in_strings,
+        \)
+    else
+        " Send a message saying the buffer has changed first, or the
+        " rename position probably won't make sense.
+        call ale#lsp#NotifyForChanges(l:id, l:buffer)
+
+        let l:message = ale#lsp#message#Rename(
+        \   l:buffer,
+        \   a:line,
+        \   a:column,
+        \   a:new_name
+        \)
+    endif
+
+    let l:request_id = ale#lsp#Send(l:id, l:message)
+
+    let s:rename_map[l:request_id] = {
+    \   'new_name': a:new_name,
+    \   'old_name': a:old_name,
+    \}
+endfunction
+
+function! s:ExecuteRename(linter, old_name, new_name) abort
+    let l:buffer = bufnr('')
+    let [l:line, l:column] = getpos('.')[1:2]
+
+    if a:linter.lsp isnot# 'tsserver'
+        let l:column = min([l:column, len(getline(l:line))])
+    endif
+
+    let l:Callback = function(
+    \ 's:OnReady', [l:line, l:column, a:old_name, a:new_name])
+    call ale#lsp_linter#StartLSP(l:buffer, a:linter, l:Callback)
+endfunction
+
+function! ale#rename#Execute() abort
+    let l:lsp_linters = []
+
+    for l:linter in ale#linter#Get(&filetype)
+        if !empty(l:linter.lsp)
+            call add(l:lsp_linters, l:linter)
+        endif
+    endfor
+
+    if empty(l:lsp_linters)
+        call s:message('No active LSPs')
+
+        return
+    endif
+
+    let l:old_name = expand('<cword>')
+    let l:new_name = ale#util#Input('New name: ', l:old_name)
+
+    if empty(l:new_name)
+        call s:message('New name cannot be empty!')
+
+        return
+    endif
+
+    for l:lsp_linter in l:lsp_linters
+        call s:ExecuteRename(l:lsp_linter, l:old_name, l:new_name)
+    endfor
+endfunction

autoload/ale/util.vim

@@ -477,3 +477,6 @@ function! ale#util#FindItemAtCursor(buffer) abort
     return [l:info, l:loc]
 endfunction
 
+function! ale#util#Input(message, value) abort
+    return input(a:message, a:value)
+endfunction