Add linting support for all formats supported by djlint (#4920)

* Refactor djlint linter code

This patch moves the code to the `autoload` directory, so it's available
when it's needed by a specific linter. This avoids redundant code when
another format supported by djlint is added.

* Add linting support for all formats supported by djlint

So far, the `djlint` linter in ALE only supported `html`, which is only
one of several file types supported by `djlint`.

This patch adds support for the following file types:

* gohtmltmpl
* handlebars
* htmlangular
* htmldjango
* jinja
* nunjucks

* Add djlint fixer for various HTML template formats

* Supported formats:
    - html
    - htmlangular
    - htmldjango
    - jinja
    - handlebars
    - nunjucks
    - gohtmltmpl

* Add doc entries

* Add vader tests

---------

Co-authored-by: Adrian Vollmer <computerfluesterer@protonmail.com>

autoload/ale/fix/registry.vim

@@ -98,6 +98,11 @@ let s:default_registry = {
 \       'suggested_filetypes': ['dhall'],
 \       'description': 'Standard code formatter for the Dhall language and removing dead code',
 \   },
+\   'djlint': {
+\       'function': 'ale#fixers#djlint#Fix',
+\       'suggested_filetypes': ['html', 'htmldjango', 'htmlangular', 'jinja', 'handlebars', 'nunjucks', 'gohtmltmpl'],
+\       'description': 'Fix HTML templates with `djlint --reformat`.',
+\   },
 \   'dune': {
 \       'function': 'ale#fixers#dune#Fix',
 \       'suggested_filetypes': ['dune'],

autoload/ale/fixers/djlint.vim

@@ -0,0 +1,48 @@
+" Author: Adrian Vollmer (computerfluesterer@protonmail.com)
+" Description: HTML template formatter using `djlint --reformat`
+
+call ale#Set('html_djlint_executable', 'djlint')
+call ale#Set('html_djlint_use_global', get(g:, 'ale_use_global_executables', 0))
+call ale#Set('html_djlint_options', '')
+
+function! ale#fixers#djlint#Fix(buffer) abort
+    let l:executable = ale#python#FindExecutable(
+    \   a:buffer,
+    \   'html_djlint',
+    \   ['djlint']
+    \)
+
+    let l:options = ale#Var(a:buffer, 'html_djlint_options')
+
+    let l:profile = ''
+    let l:filetypes = split(getbufvar(a:buffer, '&filetype'), '\.')
+
+    " Append the --profile flag depending on the current filetype (unless it's
+    " already set in g:html_djlint_options).
+    if match(l:options, '--profile') == -1
+        let l:djlint_profiles = {
+        \    'html': 'html',
+        \    'htmldjango': 'django',
+        \    'jinja': 'jinja',
+        \    'nunjucks': 'nunjucks',
+        \    'handlebars': 'handlebars',
+        \    'gohtmltmpl': 'golang',
+        \    'htmlangular': 'angular',
+        \}
+
+        for l:filetype in l:filetypes
+            if has_key(l:djlint_profiles, l:filetype)
+                let l:profile = l:djlint_profiles[l:filetype]
+                break
+            endif
+        endfor
+    endif
+
+    if !empty(l:profile)
+        let l:options = (!empty(l:options) ? l:options . ' ' : '') . '--profile ' . l:profile
+    endif
+
+    return {
+    \   'command': ale#Escape(l:executable) . ' --reformat ' . l:options . ' -',
+    \}
+endfunction

autoload/ale/handlers/djlint.vim

@@ -0,0 +1,64 @@
+" Author: Vivian De Smedt <vds2212@gmail.com>, Adrian Vollmer <computerfluesterer@protonmail.com>
+" Description: Adds support for djlint
+"
+function! ale#handlers#djlint#GetExecutable(buffer) abort
+    return ale#Var(a:buffer, 'html_djlint_executable')
+endfunction
+
+function! ale#handlers#djlint#GetCommand(buffer) abort
+    let l:executable = ale#handlers#djlint#GetExecutable(a:buffer)
+
+    let l:options = ale#Var(a:buffer, 'html_djlint_options')
+
+    let l:profile = ''
+    let l:filetypes = split(getbufvar(a:buffer, '&filetype'), '\.')
+
+    " Append the --profile flag depending on the current filetype (unless it's
+    " already set in g:html_djlint_options).
+    if match(l:options, '--profile') == -1
+        let l:djlint_profiles = {
+        \    'html': 'html',
+        \    'htmldjango': 'django',
+        \    'jinja': 'jinja',
+        \    'nunjucks': 'nunjucks',
+        \    'handlebars': 'handlebars',
+        \    'gohtmltmpl': 'golang',
+        \    'htmlangular': 'angular',
+        \}
+
+        for l:filetype in l:filetypes
+            if has_key(l:djlint_profiles, l:filetype)
+                let l:profile = l:djlint_profiles[l:filetype]
+                break
+            endif
+        endfor
+    endif
+
+    if !empty(l:profile)
+        let l:options = (!empty(l:options) ? l:options . ' ' : '') . '--profile ' . l:profile
+    endif
+
+    return ale#Escape(l:executable)
+    \ . (!empty(l:options) ? ' ' . l:options : '') . ' %s'
+endfunction
+
+function! ale#handlers#djlint#Handle(buffer, lines) abort
+    let l:output = []
+    let l:pattern = '\v^([A-Z]\d+) (\d+):(\d+) (.*)$'
+    let l:i = 0
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:i += 1
+        let l:item = {
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'vcol': 1,
+        \   'text': l:match[4],
+        \   'code': l:match[1],
+        \   'type': 'W',
+        \}
+        call add(l:output, l:item)
+    endfor
+
+    return l:output
+endfunction