Add settings for the Alex linter

The executable for the Alex linter is currently hard-coded as 'alex',
which is an issue given the fact that it conflicts with the Haskell
lexer generator, whose executable is also called 'alex', has been around
a dozen years before the linter, and is packaged in the official
repositories of the major Linux distributions.

This commit adds options to use a local executable for the alex linter
(which is a node package), and an option to set a custom executable.

As side changes:
* The pattern in the alex handler is made more readable by turnig it
  into a very-magic regex.
* Alex handles plain text, markdown, and HTML. Specific flags for HTML
  and markdown are provided when instantiating the linters for the
  respective filetypes, while before those formats were treated as plain
  text.

autoload/ale/handlers/alex.vim

@@ -1,10 +1,23 @@
 " Author: Johannes Wienke <languitar@semipol.de>
 " Description: Error handling for errors in alex output format
 
+function! ale#handlers#alex#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'alex', [
+    \   'node_modules/.bin/alex',
+    \   'node_modules/alex/cli.js',
+    \])
+endfunction
+
+function! ale#handlers#alex#CreateCommandCallback(flags) abort
+    return {b -> ale#node#Executable(b, ale#handlers#alex#GetExecutable(b))
+    \            . ' %s '
+    \            . a:flags}
+endfunction
+
 function! ale#handlers#alex#Handle(buffer, lines) abort
     " Example output:
     "       6:256-6:262  warning  Be careful with “killed”, it’s profane in some cases      killed           retext-profanities
-    let l:pattern = '^ *\(\d\+\):\(\d\+\)-\(\d\+\):\(\d\+\) \+warning \+\(.\{-\}\)  \+\(.\{-\}\)  \+\(.\{-\}\)$'
+    let l:pattern = '\v^ *(\d+):(\d+)-(\d+):(\d+) +warning +(.{-})  +(.{-})  +(.{-})$'
     let l:output = []
 
     for l:match in ale#util#GetMatches(a:lines, l:pattern)
@@ -20,3 +33,21 @@ function! ale#handlers#alex#Handle(buffer, lines) abort
 
     return l:output
 endfunction
+
+" Define a linter for a specific filetype. Accept flags to adapt to the filetype.
+"    no flags  treat input as markdown
+"    --html    treat input as HTML
+"    --text    treat input as plaintext
+function! ale#handlers#alex#DefineLinter(filetype, flags) abort
+    call ale#Set('alex_executable', 'alex')
+    call ale#Set('alex_use_global', get(g:, 'ale_use_global_executables', 0))
+
+    call ale#linter#Define(a:filetype, {
+    \   'name': 'alex',
+    \   'executable_callback': 'ale#handlers#alex#GetExecutable',
+    \   'command_callback': ale#handlers#alex#CreateCommandCallback(a:flags),
+    \   'output_stream': 'stderr',
+    \   'callback': 'ale#handlers#alex#Handle',
+    \   'lint_file': 1,
+    \})
+endfunction