mirror of
https://github.com/dense-analysis/ale.git
synced 2026-02-06 18:07:46 +08:00
31b7a2de41
The "ale#handlers#sh#GetShellType()" function currently falls back to the file type without checking for buffer-local variables first. This causes the function to return "sh" even when a script is known by Vim to be a script of a more specific type (e.g., "bash"). The "ale#handlers#shellcheck#GetDialectArgument()" function then erroneously uses this type even though a more fitting type should be used instead. Files without a "#!" line will be of type "sh" even though they may have a ".bash" suffix. This commit fixes the problem by checking for buffer-local shell type variables (set by Vim) before falling back to the file type.
38 lines
1.1 KiB
VimL
38 lines
1.1 KiB
VimL
" Author: w0rp <devw0rp@gmail.com>
|
|
|
|
function! ale#handlers#sh#GetShellType(buffer) abort
|
|
let l:shebang = get(getbufline(a:buffer, 1), 0, '')
|
|
|
|
let l:command = ''
|
|
|
|
" Take the shell executable from the shebang, if we can.
|
|
if l:shebang[:1] is# '#!'
|
|
" Remove options like -e, etc.
|
|
let l:command = substitute(l:shebang, ' --\?[a-zA-Z0-9]\+', '', 'g')
|
|
endif
|
|
|
|
" With no shebang line, attempt to use Vim's buffer-local variables.
|
|
if l:command is# ''
|
|
if getbufvar(a:buffer, 'is_bash', 0)
|
|
let l:command = 'bash'
|
|
elseif getbufvar(a:buffer, 'is_sh', 0)
|
|
let l:command = 'sh'
|
|
elseif getbufvar(a:buffer, 'is_kornshell', 0)
|
|
let l:command = 'ksh'
|
|
endif
|
|
endif
|
|
|
|
" If we couldn't find a shebang, try the filetype
|
|
if l:command is# ''
|
|
let l:command = &filetype
|
|
endif
|
|
|
|
for l:possible_shell in ['bash', 'dash', 'ash', 'tcsh', 'csh', 'zsh', 'ksh', 'sh']
|
|
if l:command =~# l:possible_shell . '\s*$'
|
|
return l:possible_shell
|
|
endif
|
|
endfor
|
|
|
|
return ''
|
|
endfunction
|