mirror of
https://github.com/dense-analysis/ale.git
synced 2026-08-16 04:37:58 +08:00
Niels Bennke
199a95d386
CI / Build (push) Canceled after 0s
CI / Neovim 0.10 Windows (push) Canceled after 0s
CI / Neovim 0.12 Windows (push) Canceled after 0s
CI / Vim 8.2 Windows (push) Canceled after 0s
CI / Vim 9.2 Windows (push) Canceled after 0s
CI / Lint (push) Canceled after 0s
CI / Lua (push) Canceled after 0s
CI / Neovim 0.10 Linux (push) Canceled after 0s
CI / Neovim 0.12 Linux (push) Canceled after 0s
CI / Vim 8.2 Linux (push) Canceled after 0s
CI / Vim 9.2 Linux (push) Canceled after 0s
* Rename erblint executable to erb_lint Fix warning: "Calling `erblint` is deprecated, please call the renamed executable `erb_lint` instead." * Update default erblint executable name Change default value of erblint executable from 'erblint' to 'erb_lint'. * Update tests to new excecutable default * fix test
52 lines
1.6 KiB
VimL
52 lines
1.6 KiB
VimL
" Author: Roeland Moors - https://github.com/roelandmoors
|
|
" based on the ale ruumba and robocop linters
|
|
" Description: ERB Lint, support for https://github.com/Shopify/erb-lint
|
|
|
|
call ale#Set('eruby_erblint_executable', 'erb_lint')
|
|
call ale#Set('eruby_erblint_options', '')
|
|
|
|
function! ale_linters#eruby#erblint#GetCommand(buffer) abort
|
|
let l:executable = ale#Var(a:buffer, 'eruby_erblint_executable')
|
|
|
|
return ale#ruby#EscapeExecutable(l:executable, 'erb_lint')
|
|
\ . ' --format json '
|
|
\ . ale#Var(a:buffer, 'eruby_erblint_options')
|
|
\ . ' --stdin %s'
|
|
endfunction
|
|
|
|
function! ale_linters#eruby#erblint#Handle(buffer, lines) abort
|
|
if empty(a:lines)
|
|
return []
|
|
endif
|
|
|
|
let l:errors = ale#util#FuzzyJSONDecode(a:lines[0], [])
|
|
|
|
if !has_key(l:errors, 'summary')
|
|
\|| l:errors['summary']['offenses'] == 0
|
|
\|| empty(l:errors['files'])
|
|
return []
|
|
endif
|
|
|
|
let l:output = []
|
|
|
|
for l:error in l:errors['files'][0]['offenses']
|
|
call add(l:output, {
|
|
\ 'lnum': l:error['location']['start_line'] + 0,
|
|
\ 'col': l:error['location']['start_column'] + 0,
|
|
\ 'end_col': l:error['location']['last_column'] + 0,
|
|
\ 'code': l:error['linter'],
|
|
\ 'text': l:error['message'],
|
|
\ 'type': 'W',
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('eruby', {
|
|
\ 'name': 'erblint',
|
|
\ 'executable': {b -> ale#Var(b, 'eruby_erblint_executable')},
|
|
\ 'command': function('ale_linters#eruby#erblint#GetCommand'),
|
|
\ 'callback': 'ale_linters#eruby#erblint#Handle',
|
|
\})
|