mirror of
https://github.com/dense-analysis/ale.git
synced 2025-12-29 07:16:53 +08:00
56e67c5811
When set to true, and the buffer is currently inside a pipenv,
GetExecutable will return "pipenv", which will trigger the existing
functionality to append the correct pipenv arguments to run each linter.
Defaults to false.
I was going to implement ale#python#PipenvPresent by invoking
`pipenv --venv` or `pipenv --where`, but it seemed to be abominably
slow, even to the point where the test suite wasn't even finishing
("Tried to run tests 3 times"). The diff is:
diff --git a/autoload/ale/python.vim b/autoload/ale/python.vim
index 7baae079..8c100d41 100644
--- a/autoload/ale/python.vim
+++ b/autoload/ale/python.vim
@@ -106,5 +106,9 @@ endfunction
" Detects whether a pipenv environment is present.
function! ale#python#PipenvPresent(buffer) abort
- return findfile('Pipfile.lock', expand('#' . a:buffer . ':p:h') . ';') isnot# ''
+ let l:cd_string = ale#path#BufferCdString(a:buffer)
+ let l:output = systemlist(l:cd_string . 'pipenv --where')[0]
+ " `pipenv --where` returns the path to the dir containing the Pipfile
+ " if in a pipenv, or some error text otherwise.
+ return strpart(l:output, 0, 18) !=# "No Pipfile present"
endfunction
Using vim's `findfile` is much faster, behaves correctly in the majority
of situations, and also works reliably when the `pipenv` command doesn't
exist.
77 lines
2.5 KiB
VimL
77 lines
2.5 KiB
VimL
" Author: keith <k@keith.so>
|
|
" Description: pylint for python files
|
|
|
|
call ale#Set('python_pylint_executable', 'pylint')
|
|
call ale#Set('python_pylint_options', '')
|
|
call ale#Set('python_pylint_use_global', get(g:, 'ale_use_global_executables', 0))
|
|
call ale#Set('python_pylint_change_directory', 1)
|
|
call ale#Set('python_pylint_auto_pipenv', 0)
|
|
|
|
function! ale_linters#python#pylint#GetExecutable(buffer) abort
|
|
if ale#Var(a:buffer, 'python_pylint_auto_pipenv') && ale#python#PipenvPresent(a:buffer)
|
|
return 'pipenv'
|
|
endif
|
|
|
|
return ale#python#FindExecutable(a:buffer, 'python_pylint', ['pylint'])
|
|
endfunction
|
|
|
|
function! ale_linters#python#pylint#GetCommand(buffer) abort
|
|
let l:cd_string = ale#Var(a:buffer, 'python_pylint_change_directory')
|
|
\ ? ale#path#BufferCdString(a:buffer)
|
|
\ : ''
|
|
|
|
let l:executable = ale_linters#python#pylint#GetExecutable(a:buffer)
|
|
|
|
let l:exec_args = l:executable =~? 'pipenv$'
|
|
\ ? ' run pylint'
|
|
\ : ''
|
|
|
|
return l:cd_string
|
|
\ . ale#Escape(l:executable) . l:exec_args
|
|
\ . ' ' . ale#Var(a:buffer, 'python_pylint_options')
|
|
\ . ' --output-format text --msg-template="{path}:{line}:{column}: {msg_id} ({symbol}) {msg}" --reports n'
|
|
\ . ' %s'
|
|
endfunction
|
|
|
|
function! ale_linters#python#pylint#Handle(buffer, lines) abort
|
|
" Matches patterns like the following:
|
|
"
|
|
" test.py:4:4: W0101 (unreachable) Unreachable code
|
|
let l:pattern = '\v^[a-zA-Z]?:?[^:]+:(\d+):(\d+): ([[:alnum:]]+) \(([^(]*)\) (.*)$'
|
|
let l:output = []
|
|
|
|
for l:match in ale#util#GetMatches(a:lines, l:pattern)
|
|
"let l:failed = append(0, l:match)
|
|
let l:code = l:match[3]
|
|
|
|
if (l:code is# 'C0303')
|
|
\ && !ale#Var(a:buffer, 'warn_about_trailing_whitespace')
|
|
" Skip warnings for trailing whitespace if the option is off.
|
|
continue
|
|
endif
|
|
|
|
if l:code is# 'I0011'
|
|
" Skip 'Locally disabling' message
|
|
continue
|
|
endif
|
|
|
|
call add(l:output, {
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'col': l:match[2] + 1,
|
|
\ 'text': l:match[5],
|
|
\ 'code': l:match[4],
|
|
\ 'type': l:code[:0] is# 'E' ? 'E' : 'W',
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('python', {
|
|
\ 'name': 'pylint',
|
|
\ 'executable_callback': 'ale_linters#python#pylint#GetExecutable',
|
|
\ 'command_callback': 'ale_linters#python#pylint#GetCommand',
|
|
\ 'callback': 'ale_linters#python#pylint#Handle',
|
|
\ 'lint_file': 1,
|
|
\})
|