mirror of
https://github.com/dense-analysis/ale.git
synced 2025-12-06 12:44:23 +08:00
7f0ce89d2b
* First pass at optimizing ale to autoload First off, the structure/function names should be revised a bit, but I will wait for @w0rp's input before unifying the naming style. Second off, the docs probably need some more work, I just did some simple find-and-replace work. With that said, this pull brings major performance gains for ale. On my slowest system, fully loading ale and all its code takes around 150ms. I have moved all of ale's autoload-able code to autoload/, and in addition, implemented lazy-loading of linters. This brings load time on that same system down to 5ms. The only downside of lazy loading is that `g:ale_linters` cannot be changed at runtime; however, it also speeds up performance at runtime by simplfying the logic greatly. Please let me know what you think! Closes #59 * Address Travis/Vint errors For some reason, ale isn't running vint for me... * Incorporate feedback, make fixes Lazy-loading logic is much improved. * Add header comments; remove incorrect workaround * Remove unneeded plugin guards * Fix lazy-loading linter logic Set the wrong variable.... * Fix capitialization
67 lines
1.9 KiB
VimL
67 lines
1.9 KiB
VimL
" Author: w0rp <devw0rp@gmail.com>
|
|
" Description: Linter registration and lazy-loading
|
|
" Retrieves linters as requested by the engine, loading them if needed.
|
|
|
|
let s:linters = {}
|
|
|
|
function! ale#linter#Define(filetype, linter) abort
|
|
if !has_key(s:linters, a:filetype)
|
|
let s:linters[a:filetype] = []
|
|
endif
|
|
|
|
let new_linter = {
|
|
\ 'name': a:linter.name,
|
|
\ 'callback': a:linter.callback,
|
|
\}
|
|
|
|
if has_key(a:linter, 'executable_callback')
|
|
let new_linter.executable_callback = a:linter.executable_callback
|
|
else
|
|
let new_linter.executable = a:linter.executable
|
|
endif
|
|
|
|
if has_key(a:linter, 'command_callback')
|
|
let new_linter.command_callback = a:linter.command_callback
|
|
else
|
|
let new_linter.command = a:linter.command
|
|
endif
|
|
|
|
if has_key(a:linter, 'output_stream')
|
|
let new_linter.output_stream = a:linter.output_stream
|
|
else
|
|
let new_linter.output_stream = 'stdout'
|
|
endif
|
|
|
|
" TODO: Assert the value of the output_stream to be something sensible.
|
|
|
|
call add(s:linters[a:filetype], new_linter)
|
|
endfunction
|
|
|
|
function! ale#linter#Get(filetype) abort
|
|
if a:filetype ==# ''
|
|
" Empty filetype? Nothing to be done about that.
|
|
return []
|
|
endif
|
|
|
|
if has_key(s:linters, a:filetype)
|
|
" We already loaded a linter, great!
|
|
return s:linters[a:filetype]
|
|
endif
|
|
|
|
if has_key(g:ale_linters, a:filetype)
|
|
" Filter loaded linters according to list of linters specified in option.
|
|
for linter in g:ale_linters[a:filetype]
|
|
execute 'runtime! ale_linters/' . a:filetype . '/' . linter . '.vim'
|
|
endfor
|
|
else
|
|
execute 'runtime! ale_linters/' . a:filetype . '/*.vim'
|
|
endif
|
|
|
|
if !has_key(s:linters, a:filetype)
|
|
" If we couldn't load any linters, let everyone know.
|
|
let s:linters[a:filetype] = []
|
|
endif
|
|
|
|
return s:linters[a:filetype]
|
|
endfunction
|