mirror of
https://github.com/dense-analysis/ale.git
synced 2026-03-05 06:34:21 +08:00
7f0ce89d2b
* First pass at optimizing ale to autoload First off, the structure/function names should be revised a bit, but I will wait for @w0rp's input before unifying the naming style. Second off, the docs probably need some more work, I just did some simple find-and-replace work. With that said, this pull brings major performance gains for ale. On my slowest system, fully loading ale and all its code takes around 150ms. I have moved all of ale's autoload-able code to autoload/, and in addition, implemented lazy-loading of linters. This brings load time on that same system down to 5ms. The only downside of lazy loading is that `g:ale_linters` cannot be changed at runtime; however, it also speeds up performance at runtime by simplfying the logic greatly. Please let me know what you think! Closes #59 * Address Travis/Vint errors For some reason, ale isn't running vint for me... * Incorporate feedback, make fixes Lazy-loading logic is much improved. * Add header comments; remove incorrect workaround * Remove unneeded plugin guards * Fix lazy-loading linter logic Set the wrong variable.... * Fix capitialization
40 lines
1.0 KiB
VimL
40 lines
1.0 KiB
VimL
" Author: KabbAmine <amine.kabb@gmail.com>
|
|
" Description: Statusline related function(s)
|
|
|
|
function! ale#statusline#Status() abort
|
|
" Returns a formatted string that can be integrated in the
|
|
" statusline
|
|
|
|
let buf = bufnr('%')
|
|
let bufLoclist = g:ale_buffer_loclist_map
|
|
|
|
if !has_key(bufLoclist, buf)
|
|
return ''
|
|
endif
|
|
|
|
let errors = 0
|
|
let warnings = 0
|
|
for e in bufLoclist[buf]
|
|
if e.type ==# 'E'
|
|
let errors += 1
|
|
else
|
|
let warnings += 1
|
|
endif
|
|
endfor
|
|
|
|
let errors = errors ? printf(g:ale_statusline_format[0], errors) : ''
|
|
let warnings = warnings ? printf(g:ale_statusline_format[1], warnings) : ''
|
|
let no_errors = g:ale_statusline_format[2]
|
|
|
|
" Different formats if no errors or no warnings
|
|
if empty(errors) && empty(warnings)
|
|
let res = no_errors
|
|
elseif !empty(errors) && !empty(warnings)
|
|
let res = printf('%s %s', errors, warnings)
|
|
else
|
|
let res = empty(errors) ? warnings : errors
|
|
endif
|
|
|
|
return res
|
|
endfunction
|