mirror of
https://github.com/dense-analysis/ale.git
synced 2026-07-29 19:26:46 +08:00
Cyril RoelandtandGitHub
94a8a88f0d
Using -v0 works out of the box, but chktex grabs the "v0 format" from
its configuration file:
OutFormat
{
# -v0; silent mode
%f%b%l%b%c%b%n%b%m!n
# -v1; normal mode
...
}
Should the user modify the definition of v0, then the linter would no
longer work. We therefore use "--format" to force the output format.
Also grab the error code so it is correctly displayed.
Closes: #3856
68 lines
2.2 KiB
VimL
68 lines
2.2 KiB
VimL
" Author: Andrew Balmos - <andrew@balmos.org>
|
|
" Description: chktex for LaTeX files
|
|
|
|
call ale#Set('tex_chktex_executable', 'chktex')
|
|
call ale#Set('tex_chktex_options', '-I')
|
|
|
|
function! ale_linters#tex#chktex#GetExecutable(buffer) abort
|
|
return ale#Var(a:buffer, 'tex_chktex_executable')
|
|
endfunction
|
|
|
|
function! ale_linters#tex#chktex#GetCommand(buffer, version) abort
|
|
let l:options = ''
|
|
|
|
" Avoid bug when used without -p (last warning has gibberish for a filename)
|
|
" Do not use -v0 as the meaning of v0 might be modified by the user in
|
|
" their chktexrc file; instead, use --format to specify the output format.
|
|
let l:options .= " --format $'%f%b%l%b%c%b%n%b%m\n' -p stdin -q"
|
|
|
|
" Avoid bug of reporting wrong column when using tabs (issue #723)
|
|
if ale#semver#GTE(a:version, [1, 7, 7])
|
|
let l:options .= ' -S TabSize=1'
|
|
endif
|
|
|
|
" Check for optional .chktexrc
|
|
let l:chktex_config = ale#path#FindNearestFile(a:buffer, '.chktexrc')
|
|
|
|
if !empty(l:chktex_config)
|
|
let l:options .= ' -l ' . ale#Escape(l:chktex_config)
|
|
endif
|
|
|
|
let l:options .= ' ' . ale#Var(a:buffer, 'tex_chktex_options')
|
|
|
|
return '%e' . l:options
|
|
endfunction
|
|
|
|
function! ale_linters#tex#chktex#Handle(buffer, lines) abort
|
|
" Mattes lines like:
|
|
"
|
|
" stdin:499:2:24:Delete this space to maintain correct pagereferences.
|
|
" stdin:507:81:3:You should enclose the previous parenthesis with `{}'.
|
|
let l:pattern = '^stdin:\(\d\+\):\(\d\+\):\(\d\+\):\(.\+\)$'
|
|
let l:output = []
|
|
|
|
for l:match in ale#util#GetMatches(a:lines, l:pattern)
|
|
call add(l:output, {
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'col': l:match[2] + 0,
|
|
\ 'text': l:match[4],
|
|
\ 'code': l:match[3] + 0,
|
|
\ 'type': 'W',
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('tex', {
|
|
\ 'name': 'chktex',
|
|
\ 'executable': function('ale_linters#tex#chktex#GetExecutable'),
|
|
\ 'command': {buffer -> ale#semver#RunWithVersionCheck(
|
|
\ buffer,
|
|
\ ale_linters#tex#chktex#GetExecutable(buffer),
|
|
\ '%e --version',
|
|
\ function('ale_linters#tex#chktex#GetCommand'),
|
|
\ )},
|
|
\ 'callback': 'ale_linters#tex#chktex#Handle'
|
|
\})
|