mirror of
https://github.com/dense-analysis/ale.git
synced 2025-12-08 05:24:46 +08:00
7d8fb2ba17
* Add poetry support to python linters and black fixer. * Update python.vim to detect poetry project. * Update ale.vim, add an option for poetry `g:ale_python_auto_poetry`. * Update ale-python.txt, add poetry support. * Add and update poetry related tests. Co-authored-by: unc0 <unc0@users.noreply.github.com>
41 lines
1.5 KiB
VimL
41 lines
1.5 KiB
VimL
" Author: dsifford <dereksifford@gmail.com>
|
|
" Description: A performant type-checker supporting LSP for Python 3 created by Facebook
|
|
|
|
call ale#Set('python_pyre_executable', 'pyre')
|
|
call ale#Set('python_pyre_use_global', get(g:, 'ale_use_global_executables', 0))
|
|
call ale#Set('python_pyre_auto_pipenv', 0)
|
|
call ale#Set('python_pyre_auto_poetry', 0)
|
|
|
|
function! ale_linters#python#pyre#GetExecutable(buffer) abort
|
|
if (ale#Var(a:buffer, 'python_auto_pipenv') || ale#Var(a:buffer, 'python_pyre_auto_pipenv'))
|
|
\ && ale#python#PipenvPresent(a:buffer)
|
|
return 'pipenv'
|
|
endif
|
|
|
|
if (ale#Var(a:buffer, 'python_auto_poetry') || ale#Var(a:buffer, 'python_pyre_auto_poetry'))
|
|
\ && ale#python#PoetryPresent(a:buffer)
|
|
return 'poetry'
|
|
endif
|
|
|
|
return ale#python#FindExecutable(a:buffer, 'python_pyre', ['pyre'])
|
|
endfunction
|
|
|
|
function! ale_linters#python#pyre#GetCommand(buffer) abort
|
|
let l:executable = ale_linters#python#pyre#GetExecutable(a:buffer)
|
|
|
|
let l:exec_args = l:executable =~? 'pipenv\|poetry$'
|
|
\ ? ' run pyre persistent'
|
|
\ : ' persistent'
|
|
|
|
return ale#Escape(l:executable) . l:exec_args
|
|
endfunction
|
|
|
|
call ale#linter#Define('python', {
|
|
\ 'name': 'pyre',
|
|
\ 'lsp': 'stdio',
|
|
\ 'executable': function('ale_linters#python#pyre#GetExecutable'),
|
|
\ 'command': function('ale_linters#python#pyre#GetCommand'),
|
|
\ 'project_root': function('ale#python#FindProjectRoot'),
|
|
\ 'completion_filter': 'ale#completion#python#CompletionItemFilter',
|
|
\})
|