fish: Command history improvements (#4672)

This change provides the following improvements:

- Changes the view of the command history list, so that the script no longer depends on perl for performance.
- Enables syntax color highlighting on fish v4.3.3 and newer.
- Provides a preview window with the selected commands, and expanded view of the highlighted command if available.
- Improves the delete functionality, by successfully handling very large numbers of selected commands.
- Inserts commands in their formatted form with `<Alt-Enter>`.

---

* fish: Change history list view

The view of the command history is changed, so that no manipulation is
performed on the output of history command: The history item count
number is replaced by the Unix time of the command, multi-line display
is disabled and line wrapping is enabled by default. On fish v4.3.3
and newer, the use of ANSI color codes for syntax highlighting is now
possible, while the script no longer depends on perl for performance.

Fixes #4661

* fish: Reformat selected history commands with ALT-ENTER

* Add $FZF_WRAP environment variable

The variable is set when line wrapping is enabled. It has the value
`word` if word wrapping mode is set, otherwise it has the value `char`.

* fish: Add command history preview

The preview shows the highlighted command and any selected commands,
after first being formatted and colorized by fish_indent. The timestamp
of the highlighted command in the preview is converted to strftime
format "%F %a %T" if the date command is available.

The preview is hidden on start, and is displayed if more than 100
columns are available and one of the following conditions are met:
- The highlighted item doesn't completely fit in list view (line
wrapping is enabled for the preview and is now disabled for the list).
- The highlighted item contains newlines (multi-line commands or
strings).
- The highlighted item contains chained commands in a single line, that
can be broken down by the formatter for cleaner view.
- One or more commands are marked as selected.

* fish: Handle deletion of large number of selected history entries

* fish: Change wrapping options for the preview-window

shell/key-bindings.fish

@@ -21,8 +21,8 @@
 function fzf_key_bindings
 
   # Check fish version
-  set -l fish_ver (string match -r '^(\d+).(\d+)' $version 2> /dev/null; or echo 0\n0\n0)
-  if test \( "$fish_ver[2]" -lt 3 \) -o \( "$fish_ver[2]" -eq 3 -a "$fish_ver[3]" -lt 1 \)
+  if set -l -- fish_ver (string match -r '^(\d+)\.(\d+)' $version 2>/dev/null)
+  and test "$fish_ver[2]" -lt 3 -o "$fish_ver[2]" -eq 3 -a "$fish_ver[3]" -lt 1
     echo "This script requires fish version 3.1b1 or newer." >&2
     return 1
   else if not type -q fzf
@@ -182,24 +182,46 @@ function fzf_key_bindings
     set -l -- total_lines (count $command_line)
     set -l -- fzf_query (string escape -- $command_line[$current_line])
 
-    set -lx FZF_DEFAULT_OPTS (__fzf_defaults '' \
-      '--nth=2..,.. --scheme=history --multi --wrap-sign="\t↳ "' \
-      '--bind=\'shift-delete:execute-silent(eval history delete --exact --case-sensitive -- (string escape -n -- {+} | string replace -r -a "^\d*\\\\\\t|(?<=\\\\\\n)\\\\\\t" ""))+reload(eval $FZF_DEFAULT_COMMAND)\'' \
+    set -lx -- FZF_DEFAULT_OPTS (__fzf_defaults '' \
+      '--nth=2..,.. --scheme=history --multi --no-multi-line --no-wrap --wrap-sign="\t\t\t↳ " --preview-wrap-sign="↳ "' \
+      '--bind=\'shift-delete:execute-silent(for i in (string split0 -- <{+f}); eval builtin history delete --exact --case-sensitive -- (string escape -n -- $i | string replace -r "^\d*\\\\\\t" ""); end)+reload(eval $FZF_DEFAULT_COMMAND)\'' \
+      '--bind="alt-enter:become(string join0 -- (string collect -- {+2..} | fish_indent -i))"' \
       "--bind=ctrl-r:toggle-sort,alt-r:toggle-raw --highlight-line $FZF_CTRL_R_OPTS" \
-      '--accept-nth=2.. --read0 --print0 --with-shell='(status fish-path)\\ -c)
+      '--accept-nth=2.. --delimiter="\t" --tabstop=4 --read0 --print0 --with-shell='(status fish-path)\\ -c)
+
+    # Add dynamic preview options if preview command isn't already set by user
+    if string match -qvr -- '--preview[= ]' "$FZF_DEFAULT_OPTS"
+      # Convert the highlighted timestamp using the date command if available
+      set -l -- date_cmd '{1}'
+      if type -q date
+        if date -d @0 '+%s' 2>/dev/null | string match -q 0
+          # GNU date
+          set -- date_cmd '(date -d @{1} \\"+%F %a %T\\")'
+        else if date -r 0 '+%s' 2>/dev/null | string match -q 0
+          # BSD date
+          set -- date_cmd '(date -r {1} \\"+%F %a %T\\")'
+        end
+      end
+
+      # Prepend the options to allow user customizations
+      set -p -- FZF_DEFAULT_OPTS \
+        '--bind="focus,resize:bg-transform:if test \\"$FZF_COLUMNS\\" -gt 100 -a \\\\( \\"$FZF_SELECT_COUNT\\" -gt 0 -o \\\\( -z \\"$FZF_WRAP\\" -a (string length -- {}) -gt (math $FZF_COLUMNS - 4) \\\\) -o (string collect -- {2..} | fish_indent | count) -gt 1 \\\\); echo show-preview; else echo hide-preview; end"' \
+        '--preview="string collect -- (test \\"$FZF_SELECT_COUNT\\" -gt 0; and string collect -- {+2..}) \\"\\n# \\"'$date_cmd' {2..} | fish_indent --ansi"' \
+        '--preview-window="right,50%,wrap-word,follow,info,hidden"'
+    end
 
     set -lx FZF_DEFAULT_OPTS_FILE
-    set -lx FZF_DEFAULT_COMMAND
 
-    if type -q perl
-      set -a FZF_DEFAULT_OPTS '--tac'
-      set FZF_DEFAULT_COMMAND 'builtin history -z --reverse | command perl -0 -pe \'s/^/$.\t/g; s/\n/\n\t/gm\''
-    else
-      set FZF_DEFAULT_COMMAND \
-        'set -l h (builtin history -z --reverse | string split0);' \
-        'for i in (seq (count $h) -1 1);' \
-        'string join0 -- $i\t(string replace -a -- \n \n\t $h[$i] | string collect);' \
-        'end'
+    set -lx -- FZF_DEFAULT_COMMAND 'builtin history -z --show-time="%s%t"'
+
+    # Enable syntax highlighting colors on fish v4.3.3 and newer
+    if set -l -- v (string match -r -- '^(\d+)\.(\d+)(?:\.(\d+))?' $version)
+    and test "$v[2]" -gt 4 -o "$v[2]" -eq 4 -a \
+      \( "$v[3]" -gt 3 -o "$v[3]" -eq 3 -a \
+      \( -n "$v[4]" -a "$v[4]" -ge 3 \) \)
+
+      set -a -- FZF_DEFAULT_OPTS '--ansi'
+      set -a -- FZF_DEFAULT_COMMAND '--color=always'
     end
 
     # Merge history from other sessions before searching
@@ -207,11 +229,11 @@ function fzf_key_bindings
 
     if set -l result (eval $FZF_DEFAULT_COMMAND \| (__fzfcmd) --query=$fzf_query | string split0)
       if test "$total_lines" -eq 1
-        commandline -- (string replace -a -- \n\t \n $result)
+        commandline -- $result
       else
         set -l a (math $current_line - 1)
         set -l b (math $current_line + 1)
-        commandline -- $command_line[1..$a] (string replace -a -- \n\t \n $result)
+        commandline -- $command_line[1..$a] $result
         commandline -a -- '' $command_line[$b..-1]
       end
     end