tests: move/rename/cleanup vspec based tests (#860)

The main motivation is to being able to use normal/other pytest based
tests.

Therefore this moves everything from conftest into test_integration
itself.

test/vspec/completions.vim

@@ -0,0 +1,112 @@
+let g:jedi#completions_command = 'X'
+source plugin/jedi.vim
+
+describe 'completions'
+    before
+        new
+        set filetype=python
+    end
+
+    after
+        " default
+        let g:jedi#popup_select_first = 1
+        bd!
+    end
+
+    it 'longest in completeopt'
+        " This gets set up with Vim only on VimEnter.
+        if has('nvim')
+            Expect stridx(&completeopt, 'longest') > -1
+        else
+            Expect stridx(&completeopt, 'longest') == -1
+            doautocmd VimEnter
+            Expect stridx(&completeopt, 'longest') > -1
+        endif
+
+        " Do not use it for following tests.
+        set completeopt-=longest
+    end
+
+    it 'smart import'
+        exec "normal ifrom os "
+        Expect getline('.') == 'from os import '
+    end
+
+    it 'no smart import after space'
+        exec "normal! ifrom os "
+        exec "normal  a "
+        Expect getline('.') == 'from os  '
+    end
+
+    it 'import'
+        " X is the completion command
+        normal oimporX
+        Expect getline('.') == 'import'
+        normal a subproX
+        Expect getline('.') == 'import subprocess'
+    end
+
+    it 'exception'
+        normal oIndentationErrX
+        Expect getline('.') == 'IndentationError'
+
+        " Do not remap keys (".") here, otherwise this triggers completion in
+        " Neovim already.
+        normal! a().filena
+
+        normal aX
+        Expect getline('.') == 'IndentationError().filename'
+    end
+
+    it 'multi complete'
+        " NOTE: nvim results in "importErr()" here with completeopt+=longest,
+        " but Vim is fine.
+        " This is due to `pumvisible()` in jedi#complete_opened being true
+        " with nvim still, but it is 0 with Vim, i.e. Vim appears to close
+        " the pum already (with the tests).
+        "
+        " This might be a misunderstanding though, since the test might not
+        " expect the "import" keyword to be offered for completion?!
+        normal oImpXErrX()
+        Expect getline('.') == 'ImportError()'
+    end
+
+    it 'cycling through entries popup_select_first=0'
+        set completeopt+=longest
+        let g:jedi#popup_select_first = 0
+        execute "normal oraise impX\<C-n>"
+
+        Expect getline('.') == 'raise ImportError'
+        set completeopt-=longest
+    end
+
+    it 'cycling through entries popup_select_first=1'
+        execute "normal oraise impX\<C-n>"
+        Expect getline('.') == 'raise ImportWarning'
+    end
+
+    it 'cycling through entries popup_select_first=1 and longest'
+        set completeopt+=longest
+        execute "normal oraise impX"
+        Expect getline('.') == 'raise Import'
+
+        " With Neovim pumvisible() is 1 in jedi#complete_opened, which then
+        " triggers the <Down>.  This is not the case with Vim.
+        if has('nvim')
+            execute "normal oraise impX\<C-n>"
+            Expect getline('.') == 'raise ImportWarning'
+
+            execute "normal oraise impX\<C-n>\<C-n>"
+            Expect getline('.') == 'raise imp'
+        else
+            execute "normal oraise impX\<C-n>"
+            Expect getline('.') == 'raise ImportError'
+
+            execute "normal oraise impX\<C-n>\<C-n>"
+            Expect getline('.') == 'raise ImportWarning'
+        endif
+        set completeopt-=longest
+    end
+end
+
+" vim: et:ts=4:sw=4

test/vspec/completions_disabled.vim

@@ -0,0 +1,20 @@
+let g:jedi#completions_command = 'X'
+let g:jedi#completions_enabled = 0
+source plugin/jedi.vim
+
+describe 'completions_disabled'
+    before
+        set filetype=python
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+    end
+
+    it 'typing'
+        normal oraise ImportErrX
+        Expect getline('.') == 'raise ImportErrX'
+    end
+end
+
+" vim: et:ts=4:sw=4

test/vspec/documentation.vim

@@ -0,0 +1,31 @@
+source plugin/jedi.vim
+
+describe 'documentation docstrings'
+    before
+        set filetype=python
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+    end
+
+    it 'simple'
+        Expect maparg('K') == ':call jedi#show_documentation()<CR>'
+        put = 'ImportError'
+        normal GK
+        Expect bufname('%') == "__doc__"
+        Expect &filetype == 'rst'
+        let content = join(getline(1,'$'), "\n")
+        Expect stridx(content, "Import can't find module") > 0
+        normal K
+        Expect bufname('%') == ''
+    end
+
+    it 'no documentation'
+        put = 'x = 2'
+        normal o<ESC>GK
+        Expect bufname('%') == ''
+    end
+end
+
+" vim: et:ts=4:sw=4

test/vspec/goto.vim

@@ -0,0 +1,217 @@
+let mapleader = '\'
+source plugin/jedi.vim
+source test/_utils.vim
+
+describe 'goto simple'
+    before
+        new
+        set filetype=python
+        put =[
+        \   'def a(): pass',
+        \   'b = a',
+        \   'c = b',
+        \ ]
+        normal! ggdd
+        normal! G$
+        Expect line('.') == 3
+    end
+
+    after
+        bd!
+    end
+
+    it 'goto definitions'
+        normal \d
+        Expect line('.') == 2
+        Expect col('.') == 1
+    end
+
+    it 'goto assignments'
+        normal \g
+        Expect line('.') == 2
+        Expect col('.') == 1
+
+        " cursor before `=` means that it stays there.
+        normal \g
+        Expect line('.') == 2
+        Expect col('.') == 1
+
+        " going to the last line changes it.
+        normal! $
+        normal \g
+        Expect line('.') == 1
+        Expect col('.') == 5
+    end
+end
+
+
+describe 'goto with tabs'
+    before
+        set filetype=python
+        let g:jedi#use_tabs_not_buffers = 1
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+    end
+
+    it 'follow import'
+        put = ['import subprocess', 'subprocess']
+        normal G\g
+        Expect getline('.') == 'import subprocess'
+        Expect line('.') == 2
+        Expect col('.') == 8
+
+        normal G\d
+        Expect CurrentBufferIsModule('subprocess') == 1
+        Expect line('.') == 1
+        Expect col('.') == 1
+        Expect tabpagenr('$') == 2
+        Expect winnr('$') == 1
+        bwipe
+
+        Expect tabpagenr('$') == 1
+        Expect bufname('%') == ''
+    end
+
+    " it 'multi definitions'
+    "     " This used to behave differently. Now we don't have any real multi
+    "     " definitions.
+    "
+    "     " put = ['import tokenize']
+    "     " normal G$\d
+    "     " Expect CurrentBufferIsModule('tokenize') == 1
+    "     " Expect CurrentBufferIsModule('token') == 0
+    "     " execute "normal \<CR>"
+    "     " Expect tabpagenr('$') == 2
+    "     " Expect winnr('$') == 1
+    "     " Expect CurrentBufferIsModule('token') == 1
+    "
+    "     " bd
+    "     " normal G$\d
+    "     " execute "normal j\<CR>"
+    "     " Expect tabpagenr('$') == 2
+    "     " Expect winnr('$') == 1
+    "     " Expect CurrentBufferIsModule('tokenize') == 1
+    " end
+end
+
+
+describe 'goto with buffers'
+    before
+        set filetype=python
+        let g:jedi#use_tabs_not_buffers = 0
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+        set nohidden
+    end
+
+    it 'no new tabs'
+        put = ['import os']
+        normal G$
+        call jedi#goto_assignments()
+        PythonJedi jedi_vim.goto()
+        Expect CurrentBufferIsModule('os') == 0
+        " Without hidden, it's not possible to open a new buffer, when the old
+        " one is not saved.
+        set hidden
+        call jedi#goto_assignments()
+        Expect CurrentBufferIsModule('os') == 1
+        Expect winnr('$') == 1
+        Expect tabpagenr('$') == 1
+        Expect line('.') == 1
+        Expect col('.') == 1
+    end
+
+    " it 'multi definitions'
+    "     " set hidden
+    "     " put = ['import tokenize']
+    "     " normal G$\d
+    "     " Expect CurrentBufferIsModule('tokenize') == 0
+    "     " Expect CurrentBufferIsModule('token') == 0
+    "     " execute "normal \<CR>"
+    "     " Expect tabpagenr('$') == 1
+    "     " Expect winnr('$') == 1
+    "     " Expect CurrentBufferIsModule('token') == 1
+    "
+    "     " bd
+    "     " normal G$\d
+    "     " execute "normal j\<CR>"
+    "     " Expect tabpagenr('$') == 1
+    "     " Expect winnr('$') == 1
+    "     " Expect CurrentBufferIsModule('tokenize') == 1
+    " end
+end
+
+
+
+describe 'goto with splits'
+    before
+        enew!
+        set filetype=python
+        let g:jedi#use_splits_not_buffers = 'left'
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+    end
+
+    it 'follow import'
+        put = ['import subprocess', 'subprocess']
+        normal G\g
+        Expect getline('.') == 'import subprocess'
+        Expect line('.') == 2
+        Expect col('.') == 8
+
+        normal G\d
+        Expect CurrentBufferIsModule('subprocess') == 1
+        Expect line('.') == 1
+        Expect col('.') == 1
+        Expect winnr('$') == 2
+        wincmd l
+        Expect bufname('%') == ''
+    end
+
+end
+
+
+describe 'goto wildignore'
+    before
+        enew!
+        set filetype=python
+        set wildignore=*,with\ spaces,*.pyc
+        set hidden
+        let g:jedi#use_tag_stack = 1
+        let g:jedi#use_tabs_not_buffers = 0
+        " Need to use splits for code coverage in new_buffer()
+        let g:jedi#use_splits_not_buffers = 1
+
+        put = ['from subprocess import Popen', 'Popen']
+        Expect CurrentBufferIsModule('subprocess') == 0
+        normal G
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+        set wildignore&vim
+    end
+
+    it 'restores wildignore'
+        let before = &wildignore
+        call jedi#goto()
+        Expect getline('.') =~ 'Popen'
+        Expect &wildignore == before
+    end
+
+    it 'not using tagstack'
+        let g:jedi#use_tag_stack = 0
+        call jedi#goto()
+        Expect CurrentBufferIsModule('subprocess') == 1
+        Expect getline('.') =~ 'Popen'
+    end
+end
+
+
+" vim: et:ts=4:sw=4

test/vspec/pyimport.vim

@@ -0,0 +1,35 @@
+source plugin/jedi.vim
+source test/_utils.vim
+
+describe 'pyimport'
+    before
+        let g:jedi#use_tabs_not_buffers = 1
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+    end
+
+    it 'open_tab'
+        Pyimport os 
+        Expect CurrentBufferIsModule('os') == 1
+        Pyimport subprocess 
+        Expect CurrentBufferIsModule('subprocess') == 1
+        " the empty tab is sometimes also a tab
+        Expect tabpagenr('$') >= 2
+    end
+
+    it 'completion'
+        " don't know how to test this directly
+        "execute "Pyimport subproc\<Tab>"
+        "Expect CurrentBufferIsModule('subprocess') == 1
+
+        Expect jedi#py_import_completions('subproc', 0, 0) == 'subprocess'
+        Expect jedi#py_import_completions('subprocess', 0, 0) == 'subprocess'
+        let g:comp = jedi#py_import_completions('zip', 0, 0)
+        " Sometimes zipapp is in there sometimes not, depends on Python
+        " version.
+        let g:comp = substitute(g:comp, '^zipapp\n', '', '')
+        Expect g:comp == "zipfile\nzipimport"
+    end
+end

test/vspec/signatures.vim

@@ -0,0 +1,129 @@
+source plugin/jedi.vim
+
+describe 'signatures'
+    before
+        enew
+        set filetype=python
+    end
+
+    after
+        try | %bwipeout! | catch | endtry
+    end
+
+    it 'simple'
+        normal odef xyz(number): return
+        normal o
+        normal oxyz()
+        doautocmd CursorHoldI
+        Expect getline(3) == '?!?jedi=0, ?!?   (*_*number*_*) ?!?jedi?!?'
+
+        doautocmd InsertLeave
+        Expect getline(3) == ''
+    end
+
+    it 'multiple buffers'
+        set hidden
+        new
+        setfiletype python
+        redir => autocmds
+        autocmd jedi_call_signatures * <buffer>
+        redir END
+        Expect autocmds =~# 'jedi_call_signatures'
+        buffer #
+        redir => autocmds
+        autocmd jedi_call_signatures * <buffer>
+        redir END
+        Expect autocmds =~# 'jedi_call_signatures'
+    end
+
+    it 'simple after CursorHoldI with only parenthesis'
+        noautocmd normal o
+        doautocmd CursorHoldI
+        noautocmd normal istr()
+        doautocmd CursorHoldI
+        Expect getline(1) == '?!?jedi=0, ?!?   (*_*object*_*) ?!?jedi?!?'
+    end
+
+    it 'no signature'
+        exe 'normal ostr '
+        Python jedi_vim.show_call_signatures()
+        Expect getline(1, '$') == ['', 'str ']
+    end
+
+    it 'signatures disabled'
+        let g:jedi#show_call_signatures = 0
+
+        exe 'normal ostr( '
+        Python jedi_vim.show_call_signatures()
+        Expect getline(1, '$') == ['', 'str( ']
+
+        let g:jedi#show_call_signatures = 1
+    end
+
+    it 'command line simple'
+        let g:jedi#show_call_signatures = 2
+        call jedi#configure_call_signatures()
+
+        exe 'normal ostr( '
+        redir => msg
+        Python jedi_vim.show_call_signatures()
+        redir END
+        Expect msg == "\nstr(object)"
+
+        redir => msg
+        doautocmd InsertLeave
+        redir END
+        Expect msg == "\n"
+
+        normal Sdef foo(a, b): pass
+        exe 'normal ofoo(a, b, c, '
+        redir => msg
+        Python jedi_vim.show_call_signatures()
+        redir END
+        Expect msg == "\nfoo(a, b)"
+    end
+
+    it 'command line truncation'
+        let g:jedi#show_call_signatures = 2
+        call jedi#configure_call_signatures()
+
+        function! Signature()
+            redir => msg
+            Python jedi_vim.show_call_signatures()
+            redir END
+            return msg
+        endfunction
+
+        let funcname = repeat('a', &columns - (30 + (&ruler ? 18 : 0)))
+        put = 'def '.funcname.'(arg1, arg2, arg3, a, b, c):'
+        put = '    pass'
+        execute "normal o\<BS>".funcname."( "
+        Expect Signature() == "\n".funcname."(arg1, …)"
+
+        exe 'normal sarg1, '
+        Expect Signature() == "\n".funcname."(…, arg2, …)"
+
+        exe 'normal sarg2, arg3, '
+        Expect Signature() == "\n".funcname."(…, a, b, c)"
+
+        exe 'normal sa, b, '
+        Expect Signature() == "\n".funcname."(…, c)"
+
+        g/^/d
+        put = 'def '.funcname.'('.repeat('b', 20).', arg2):'
+        put = '    pass'
+        execute "normal o\<BS>".funcname."( "
+        Expect Signature() == "\n".funcname."(…)"
+    end
+
+    it 'command line no signature'
+        let g:jedi#show_call_signatures = 2
+        call jedi#configure_call_signatures()
+
+        exe 'normal ostr '
+        redir => msg
+        Python jedi_vim.show_call_signatures()
+        redir END
+        Expect msg == "\n"
+    end
+end