add highlighter class

autoload/airline/builder.vim

@@ -1,10 +1,11 @@
 " MIT license. Copyright (c) 2013 Bailey Ling.
-" vim: ts=2 sts=2 sw=2 fdm=indent
+" vim: et ts=2 sts=2 sw=2 fdm=indent
 
-function! airline#builder#new(active)
+function! airline#builder#new(active, highlighter)
   let builder = {}
   let builder._sections = []
   let builder._active = a:active
+  let builder._highlighter = a:highlighter
 
   function! builder.split(gutter)
     call add(self._sections, ['|', a:gutter])
@@ -18,14 +19,8 @@ function! airline#builder#new(active)
     call add(self._sections, ['_', a:text])
   endfunction
 
-  function! builder.refresh_separator_highlights()
-    for sep in self._separator_groups
-      call airline#themes#exec_highlight_separator(sep[0], sep[1])
-    endfor
-  endfunction
-
   function! builder._group(group)
-    return '%#' . (self._active ? a:group : a:group.'_inactive') . '#'
+    return self._active ? a:group : a:group.'_inactive'
   endfunction
 
   function! builder.build()
@@ -46,17 +41,19 @@ function! airline#builder#new(active)
       endif
 
       if prev_group != ''
-        let sep = side == 0 ? [section[0], prev_group] : [prev_group, section[0]]
+        let sep = side == 0
+              \ ? [self._group(section[0]), self._group(prev_group)]
+              \ : [self._group(prev_group), self._group(section[0])]
         call add(separator_groups, sep)
         let line .= side == 0
-              \ ? self._group(section[0].'_to_'.prev_group)
-              \ : self._group(prev_group.'_to_'.section[0])
+              \ ? '%#'.self._group(section[0].'_to_'.prev_group).'#'
+              \ : '%#'.self._group(prev_group.'_to_'.section[0]).'#'
         let line .= side == 0
               \ ? self._active ? g:airline_left_sep : g:airline_left_alt_sep
               \ : self._active ? g:airline_right_sep : g:airline_right_alt_sep
       endif
 
-      let line .= self._group(section[0]).section[1]
+      let line .= '%#'.self._group(section[0]).'#'.section[1]
       let prev_group = section[0]
     endfor
 

autoload/airline/extensions/ctrlp.vim

@@ -22,7 +22,7 @@ function! airline#extensions#ctrlp#load_theme()
           \ g:airline#themes#{g:airline_theme}#insert['airline_a'])
   endif
   for key in keys(theme)
-    call airline#exec_highlight(key, theme[key])
+    call airline#highlighter#exec(key, theme[key])
   endfor
 endfunction
 

autoload/airline/highlighter.vim

@@ -0,0 +1,56 @@
+" MIT license. Copyright (c) 2013 Bailey Ling.
+" vim: et ts=2 sts=2 sw=2 fdm=indent
+
+let s:is_win32term = (has('win32') || has('win64')) && !has('gui_running')
+
+function! airline#highlighter#exec(group, colors)
+  let colors = a:colors
+  if s:is_win32term
+    let colors = map(a:colors, 'v:val != "" && v:val > 128 ? v:val - 128 : v:val')
+  endif
+  exec printf('hi %s %s %s %s %s %s %s %s',
+        \ a:group,
+        \ colors[0] != '' ? 'guifg='.colors[0] : '',
+        \ colors[1] != '' ? 'guibg='.colors[1] : '',
+        \ colors[2] != '' ? 'ctermfg='.colors[2] : '',
+        \ colors[3] != '' ? 'ctermbg='.colors[3] : '',
+        \ len(colors) > 4 && colors[4] != '' ? 'gui='.colors[4] : '',
+        \ len(colors) > 4 && colors[4] != '' ? 'cterm='.colors[4] : '',
+        \ len(colors) > 4 && colors[4] != '' ? 'term='.colors[4] : '')
+endfunction
+
+function! airline#highlighter#exec_separator(from, to)
+  if a:from == a:to
+    return a:from
+  endif
+  let l:from = airline#themes#get_highlight(a:from)
+  let l:to = airline#themes#get_highlight(a:to)
+  let group = a:from.'_to_'.a:to
+  call airline#highlighter#exec(group, [ l:to[1], l:from[1], l:to[3], l:from[3] ])
+  return group
+endfunction
+
+
+function! airline#highlighter#new()
+  let highlighter = {}
+
+  function! highlighter.highlight(modes)
+    " draw the base mode, followed by any overrides
+    let mapped = map(a:modes, 'v:val == a:modes[0] ? v:val : a:modes[0]."_".v:val')
+    let suffix = a:modes[0] == 'inactive' ? '_inactive' : ''
+    for mode in mapped
+      if exists('g:airline#themes#{g:airline_theme}#{mode}')
+        for key in keys(g:airline#themes#{g:airline_theme}#{mode})
+          let colors = g:airline#themes#{g:airline_theme}#{mode}[key]
+          call airline#highlighter#exec(key.suffix, colors)
+        endfor
+      endif
+    endfor
+    for sep in w:airline_current_info.separator_groups
+      call airline#highlighter#exec_separator(sep[0].suffix, sep[1].suffix)
+    endfor
+  endfunction
+
+  return highlighter
+endfunction
+

autoload/airline/themes.vim

@@ -54,13 +54,3 @@ function! airline#themes#get_highlight2(fg, bg, ...)
   return s:get_array(fg, bg, a:000)
 endfunction
 
-function! airline#themes#exec_highlight_separator(from, to)
-  if a:from == a:to
-    return a:from
-  endif
-  let l:from = airline#themes#get_highlight(a:from)
-  let l:to = airline#themes#get_highlight(a:to)
-  let group = a:from.'_to_'.a:to
-  call airline#exec_highlight(group, [ l:to[1], l:from[1], l:to[3], l:from[3] ])
-  return group
-endfunction