vim9: Add Vim9 implementations for util helpers (#2750)

autoload/airline/util.vim

@@ -1,4 +1,4 @@
-" MIT License. Copyright (c) 2013-2026 Bailey Ling, Christian Brabandt et al.
+" MIT License. Copyright (c) 2013-2021 Bailey Ling Christian Brabandt et al.
 " vim: et ts=2 sts=2 sw=2
 
 scriptencoding utf-8
@@ -13,6 +13,15 @@ let s:has_strchars = exists('*strchars')
 let s:has_strcharpart = exists('*strcharpart')
 let s:focusgained_ignore_time = 0
 
+function! airline#util#has_vim9_script()
+  " Returns true, if Vim is new enough to understand vim9 script
+  return (exists(":def") &&
+    \ exists("v:versionlong") &&
+    \ v:versionlong >= 8022844 &&
+    \ get(g:, "airline_experimental", 0))
+endfunction
+
+if !exists(":def") || !airline#util#has_vim9_script()
   " TODO: Try to cache winwidth(0) function
   " e.g. store winwidth per window and access that, only update it, if the size
   " actually changed.
@@ -242,17 +251,205 @@ function! airline#util#try_focusgained()
     return dt >= 1
   endfunction
 
-function! airline#util#has_vim9_script()
-  " Returns true, if Vim is new enough to understand vim9 script
-  return (exists(":def") &&
-    \ exists("v:versionlong") &&
-    \ v:versionlong >= 8022844 &&
-    \ get(g:, "airline_experimental", 0))
-endfunction
-
   function! airline#util#has_multiline()
     " Returns true, if Vim supports multiline statusline (Vim 9.2.0083)
     return (exists("+statuslineopt") &&
       \ get(g:, "airline_multiline", 0))
   endfunction
 
+else
+
+  def airline#util#winwidth(...args: list<any>): number
+    const nr = get(args, 0, 0)
+    # When statusline is on top, or using global statusline for Neovim
+    # always return the number of columns
+    if get(g:, 'airline_statusline_ontop', 0) || &laststatus > 2
+      return &columns
+    else
+      return winwidth(nr)
+    endif
+  enddef
+
+  def airline#util#shorten(text: string, winwidth: number, minwidth: number, ...args: list<any>): string
+    if airline#util#winwidth() < winwidth && len(split(text, '\zs')) > minwidth
+      if get(args, 0, 0)
+        # shorten from tail
+        return '…' .. matchstr(text, '.\{' .. minwidth .. '}$')
+      else
+        # shorten from beginning of string
+        return matchstr(text, '^.\{' .. minwidth .. '}') .. '…'
+      endif
+    else
+      return text
+    endif
+  enddef
+
+  def airline#util#wrap(text: string, minwidth: number): string
+    if minwidth > 0 && airline#util#winwidth() < minwidth
+      return ''
+    endif
+    return text
+  enddef
+
+  def airline#util#append(text: string, minwidth: number): string
+    if minwidth > 0 && airline#util#winwidth() < minwidth
+      return ''
+    endif
+    const prefix = s:spc == "\ua0" ? s:spc : s:spc .. s:spc
+    return empty(text) ? '' : prefix .. g:airline_left_alt_sep .. s:spc .. text
+  enddef
+
+  def airline#util#warning(msg: string)
+    echohl WarningMsg
+    echomsg "airline: " .. msg
+    echohl Normal
+  enddef
+
+  def airline#util#prepend(text: string, minwidth: number): string
+    if minwidth > 0 && airline#util#winwidth() < minwidth
+      return ''
+    endif
+    return empty(text) ? '' : text .. s:spc .. g:airline_right_alt_sep .. s:spc
+  enddef
+
+  def airline#util#getbufvar(bufnr: number, key: string, def: any): any
+    return getbufvar(bufnr, key, def)
+  enddef
+
+  def airline#util#getwinvar(winnr: number, key: string, def: any): any
+    return getwinvar(winnr, key, def)
+  enddef
+
+  def airline#util#exec_funcrefs(list: list<any>, ...args: list<any>): number
+    for Fn in list
+      var code = call(Fn, args)
+      if code != 0
+        return code
+      endif
+    endfor
+    return 0
+  enddef
+
+  def airline#util#strchars(str: string): number
+    if s:has_strchars
+      return strchars(str)
+    else
+      return strlen(substitute(str, '.', 'a', 'g'))
+    endif
+  enddef
+
+  def airline#util#strcharpart(...values: list<any>): string 
+    if s:has_strcharpart
+      return call('strcharpart',  values)
+    else
+      # does not handle multibyte chars :(
+      return values[1][values[2] : values[3]]
+    endif
+  enddef
+
+  def airline#util#ignore_buf(name: string): bool
+    var pat = '\c\v' .. get(g:, 'airline#ignore_bufadd_pat', '') .. get(g:, 'airline#extensions#tabline#ignore_bufadd_pat', '!|defx|gundo|nerd_tree|startify|tagbar|term://|undotree|vimfiler')
+    return match(name, pat) > -1
+  enddef
+
+  def airline#util#has_fugitive(): bool
+    if !exists("s:has_fugitive")
+      s:has_fugitive = exists('*FugitiveHead')
+    endif
+    return s:has_fugitive
+  enddef
+
+  def airline#util#has_zhihu(): number
+    return 0
+  enddef
+
+  def airline#util#has_gina(): bool
+    if !exists("s:has_gina")
+      s:has_gina = (exists(':Gina') && v:version >= 800)
+    endif
+    return s:has_gina
+  enddef
+
+  def airline#util#has_lawrencium(): bool 
+    if !exists("s:has_lawrencium")
+      s:has_lawrencium  = exists('*lawrencium#statusline')
+    endif
+    return s:has_lawrencium
+  enddef
+
+  def airline#util#has_vcscommand(): bool 
+    if !exists("s:has_vcscommand")
+      s:has_vcscommand = exists('*VCSCommandGetStatusLine')
+    endif
+    return get(g:, 'airline#extensions#branch#use_vcscommand', 0) && s:has_vcscommand
+  enddef
+
+  def airline#util#has_custom_scm(): bool
+    return !empty(get(g:, 'airline#extensions#branch#custom_head', ''))
+  enddef
+
+  def airline#util#doautocmd(event: string)
+    if !exists('#airline') && event !=? 'AirlineToggledOff'
+      # airline disabled
+      return
+    endif
+    try
+      exe printf("silent doautocmd %s User %s", s:nomodeline, event)
+    catch /^Vim\%((\a\+)\)\=:E48:/
+      # Catch: Sandbox mode
+      # no-op
+    endtry
+  enddef
+
+  def airline#util#themes(match_str: string): list<string>
+    const files = split(globpath(&rtp, 'autoload/airline/themes/' .. match_str .. '*.vim', true), "\n")
+    var theme_names = files->mapnew((_, val) => fnamemodify(val, ":t:r"))
+    if "random" =~ match_str
+      theme_names->add("random")
+    endif
+    return theme_names->sort()
+  enddef
+
+  def airline#util#stl_disabled(winnr: number): bool
+    # setting the statusline is disabled,
+    # either globally, per window, or per buffer
+    # w:airline_disabled is deprecated!
+    return get(g:, 'airline_disable_statusline', 0) ||
+          \ airline#util#getwinvar(winnr, 'airline_disable_statusline', 0) ||
+          \ airline#util#getwinvar(winnr, 'airline_disabled', 0) ||
+          \ airline#util#getbufvar(winbufnr(winnr), 'airline_disable_statusline', 0)
+  enddef
+
+  def airline#util#ignore_next_focusgain()
+    if has('win32')
+      # Setup an ignore for platforms that trigger FocusLost on calls to
+      # system(). macvim (gui and terminal) and Linux terminal vim do not.
+      s:focusgained_ignore_time = localtime()
+    endif
+  enddef
+
+  def airline#util#is_popup_window(winnr: number): bool
+    # Keep the statusline active if it's a popup window
+    if exists('*win_gettype')
+      return win_gettype(winnr) ==# 'popup' || win_gettype(winnr) ==# 'autocmd'
+    else
+      return airline#util#getwinvar(winnr, '&buftype', '') ==# 'popup'
+    endif
+  enddef
+
+  def airline#util#try_focusgained(): bool
+    # Ignore lasts for at most one second and is cleared on the first
+    # focusgained. We use ignore to prevent system() calls from triggering
+    # FocusGained (which occurs 100% on win32 and seem to sometimes occur under
+    # tmux).
+    const dt = localtime() - s:focusgained_ignore_time
+    s:focusgained_ignore_time = 0
+    return dt >= 1
+  enddef
+
+  def airline#util#has_multiline(): bool
+    # Returns true, if Vim supports multiline statusline (Vim 9.2.0083)
+    return (exists("+statuslineopt") &&
+          \ get(g:, "airline_multiline", 0))
+  enddef
+endif