add jellybeans theme using new highlight group methods

autoload/airline/themes.vim

@@ -13,3 +13,25 @@ function! airline#themes#generate_color_map(section1, section2, section3, file)
       \ 'file':           [ a:file[0]     , a:file[1]     , a:file[2]     , a:file[3]     , get(a:file    , 4, ''    ) ] ,
       \ }
 endfunction
+
+function! s:get_syn(group, what)
+  return synIDattr(synIDtrans(hlID(a:group)), a:what)
+endfunction
+
+function! s:get_array(fg, bg, opts)
+  return has('gui_running')
+        \ ? [ a:fg, a:bg, '', '', join(a:opts, ',') ]
+        \ : [ '', '', a:fg >= 0 ? a:fg : '', a:bg >= 0 ? a:bg : '', join(a:opts, ',') ]
+endfunction
+
+function! airline#themes#get_highlight(group, ...)
+  let fg = s:get_syn(a:group, 'fg')
+  let bg = s:get_syn(a:group, 'bg')
+  return s:get_array(fg, bg, a:000)
+endfunction
+
+function! airline#themes#get_highlight2(fg, bg, ...)
+  let fg = s:get_syn(a:fg[0], a:fg[1])
+  let bg = s:get_syn(a:bg[0], a:bg[1])
+  return s:get_array(fg, bg, a:000)
+endfunction

autoload/airline/themes/jellybeans.vim

@@ -0,0 +1,33 @@
+" This theme is an example of how to use helper functions to extract highlight
+" values from the corresponding colorscheme. It was written in a hurry, so it
+" is very minimalistic. If you are a jellybeans user and want to make updates,
+" please send pull requests.
+
+" Here are examples where the entire highlight group is copied and an airline
+" compatible color array is generated.
+let s:file = airline#themes#get_highlight('Constant')
+let s:N1 = airline#themes#get_highlight('DbgCurrent', 'bold')
+let s:N2 = airline#themes#get_highlight('Folded')
+let s:N3 = airline#themes#get_highlight('NonText')
+let g:airline#themes#jellybeans#normal = airline#themes#generate_color_map(s:N1, s:N2, s:N3, s:file)
+
+let s:I1 = airline#themes#get_highlight('DiffAdd', 'bold')
+let s:I2 = s:N2
+let s:I3 = s:N3
+let g:airline#themes#jellybeans#insert = airline#themes#generate_color_map(s:I1, s:I2, s:I3, s:file)
+
+let s:R1 = airline#themes#get_highlight('WildMenu', 'bold')
+let s:R2 = s:N2
+let s:R3 = s:N3
+let g:airline#themes#jellybeans#replace = airline#themes#generate_color_map(s:R1, s:R2, s:R3, s:file)
+
+" Sometimes you want to mix and match colors from different groups, you can do
+" that with this method.
+let s:V1 = airline#themes#get_highlight2(['TabLineSel', 'bg'], ['DiffDelete', 'bg'], 'bold')
+let s:V2 = s:N2
+let s:V3 = s:N3
+let g:airline#themes#jellybeans#visual = airline#themes#generate_color_map(s:V1, s:V2, s:V3, s:file)
+
+" And of course, you can always do it manually as well.
+let s:IA = [ '#444444', '#1c1c1c', 237, 234 ]
+let g:airline#themes#jellybeans#inactive = airline#themes#generate_color_map(s:IA, s:IA, s:IA, s:file)