mirror of
https://github.com/dense-analysis/ale.git
synced 2026-10-25 15:17:21 +08:00
Markus Koller
422c0e8ef4
CI / Build (push) Canceled after 0s
CI / Lint (push) Canceled after 0s
CI / Lua (push) Canceled after 0s
CI / Neovim 0.10 Linux (push) Canceled after 0s
CI / Neovim 0.12 Linux (push) Canceled after 0s
CI / Vim 8.2 Linux (push) Canceled after 0s
CI / Vim 9.2 Linux (push) Canceled after 0s
CI / Neovim 0.10 Windows (push) Canceled after 0s
CI / Neovim 0.12 Windows (push) Canceled after 0s
CI / Vim 8.2 Windows (push) Canceled after 0s
CI / Vim 9.2 Windows (push) Canceled after 0s
* elixir: Don't use temp dir for mix linter The mix linter sets `MIX_BUILD_PATH` to a temporary directory on every run, which is very slow and inefficient. We can just use the default build path to speed this up. The default directory is `_build` inside the project, this is also automatically added to `.gitignore` by `mix new` so hopefully shouldn't cause any unwanted clutter. The `%s` argument is removed since `mix compile` doesn't actually support passing a filename. The output stream is changed to `stderr` since that's where the errors appear. Other options: - `mix compile` has a `--no-compile` flag, but this misses most errors including basic syntax errors - `mix format` has a `--dry-run` flag, but this only catches basic syntax errors and misses other errors like undefined functions Fixes https://github.com/dense-analysis/ale/issues/3816 * elixir: Fix error parsing for mix linter and support warnings The error parsing stopped working at some point, probably when Elixir introduced its new error formatting in for 1.16 in 2023.
89 lines
2.8 KiB
VimL
89 lines
2.8 KiB
VimL
" Author: evnu - https://github.com/evnu
|
|
" Author: colbydehart - https://github.com/colbydehart
|
|
" Author: toupeira - https://github.com/toupeira
|
|
" Description: Mix compile checking for Elixir files
|
|
|
|
function! ale_linters#elixir#mix#Handle(buffer, lines) abort
|
|
" Example output from Elixir 1.20.0:
|
|
"
|
|
" warning: variable "a" is unused (if the variable is not meant to be used, prefix it with an underscore)
|
|
" │
|
|
" 16 │ a = missing_var
|
|
" │ ~
|
|
" │
|
|
" └─ lib/foo.ex:16:5: Foo.hello/0
|
|
"
|
|
" warning: variable "b" is unused (if the variable is not meant to be used, prefix it with an underscore)
|
|
" │
|
|
" 17 │ b = another_missing_var
|
|
" │ ~
|
|
" │
|
|
" └─ lib/foo.ex:17:5: Foo.hello/0
|
|
"
|
|
" error: undefined variable "another_missing_var"
|
|
" │
|
|
" 17 │ b = another_missing_var
|
|
" │ ^^^^^^^^^^^^^^^^^^^
|
|
" │
|
|
" └─ lib/foo.ex:17:9: Foo.hello/0
|
|
"
|
|
" error: undefined variable "missing_var"
|
|
" │
|
|
" 16 │ a = missing_var
|
|
" │ ^^^^^^^^^^^
|
|
" │
|
|
" └─ lib/foo.ex:16:9: Foo.hello/0
|
|
"
|
|
"
|
|
" == Compilation error in file lib/foo.ex ==
|
|
" ** (CompileError) lib/foo.ex: cannot compile module Foo (errors have been logged)
|
|
"
|
|
" NOTE: The line with the error class is not captured because it always
|
|
" seems to be either a `CompileError` or a `SyntaxError`, with a generic
|
|
" message.
|
|
"
|
|
let l:pattern_text = '\v^ (warning|error): (.+)$'
|
|
let l:pattern_file = '\v^ └─ ([^ :]+):([0-9]+):([0-9]+)?'
|
|
|
|
let l:match_texts = ale#util#GetMatches(a:lines, l:pattern_text)
|
|
let l:match_files = ale#util#GetMatches(a:lines, l:pattern_file)
|
|
|
|
let l:output = []
|
|
let l:index = 0
|
|
|
|
" Always add the full output as detail
|
|
let l:detail = join(a:lines, "\n")
|
|
|
|
for l:match_text in l:match_texts
|
|
let l:type = toupper(l:match_text[1][0])
|
|
let l:match_file = get(l:match_files, l:index, [])
|
|
|
|
if !ale#path#IsBufferPath(a:buffer, get(l:match_file, 1))
|
|
continue
|
|
endif
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'type': l:type,
|
|
\ 'detail': l:detail,
|
|
\ 'text': get(l:match_text, 2, v:null),
|
|
\ 'lnum': str2nr(get(l:match_file, 2, v:null)),
|
|
\ 'col': str2nr(get(l:match_file, 3, v:null)),
|
|
\})
|
|
|
|
let l:index += 1
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('elixir', {
|
|
\ 'name': 'mix',
|
|
\ 'executable': 'mix',
|
|
\ 'cwd': function('ale#handlers#elixir#FindMixProjectRoot'),
|
|
\ 'command': '%e compile',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'callback': 'ale_linters#elixir#mix#Handle',
|
|
\ 'lint_file': 1,
|
|
\})
|