Merge pull request #308 from kevinhwang91/master

fix: &sw may be a zero

.gitignore

@@ -0,0 +1,12 @@
+*.sw?
+*.un?
+*.vba
+*.vmb
+*.zip
+*.gz
+vimball.txt
+*.orig
+tags
+test/build
+test/*.tap
+test/*.msgout

Makefile

@@ -0,0 +1,81 @@
+PLUGIN   =  $(wildcard plugin/*.vim)
+SOURCES  =  $(PLUGIN)
+LIB      =  $(wildcard autoload/*.vim)
+SOURCES  += $(LIB)
+DOC      =  $(wildcard doc/*.txt)
+SOURCES  += $(DOC)
+NAME     =  delimitMate
+VERSION  =  $(shell $(SED) -n -e '/Current \+release/{s/^ \+\([0-9.]\+\).*/\1/;p;}' $(firstword $(DOC)))
+FILENAME =  $(NAME)-$(VERSION)
+DESTDIR  =  $(HOME)/.vim
+VIM      =  vim
+SED      =  $(shell command -v gsed || command -v sed)
+PERL     =  perl
+comma    := ,
+empty    :=
+space    := $(empty) $(empty)
+
+.PHONY: version clean distclean undo release test install uninstall
+
+all: zip gzip
+dist: version all
+vimball: $(FILENAME).vmb
+zip: $(FILENAME).zip $(FILENAME).vmb.zip
+gzip: $(FILENAME).tar.gz $(FILENAME).vmb.gz
+
+clean:
+	rm -f */*.orig *.~* .VimballRecord *.zip *.gz *.vmb
+
+distclean: clean
+	-zsh -c 'setopt extendedglob; rm -f ^(README.md|Makefile|basic_vimrc)(.)'
+	-zsh -c 'setopt extendedglob; rm -f .^(git|README.md|Makefile|basic_vimrc)*'
+
+undo:
+	for i in */*.orig; do mv -f "$$i" "$${i%.*}"; done
+
+version:
+	$(PERL) -i.orig -pne 'if (/^"\sVersion:/) {s/(\d+\.\S+)/$(VERSION)/}' $(PLUGIN) $(LIB)
+	$(PERL) -i.orig -pne \
+	  'if (/let\sdelimitMate_version/) {s/"(\d+\.\S+)"/"$(VERSION)"/}' $(PLUGIN)
+	$(PERL) -i.orig -pne 'if (/beasts/) {s/(v\d+\.\S+)/v$(VERSION)/}' $(DOC)
+	$(PERL) -i.orig -MPOSIX -pne \
+	  'if (/^"\sModified:/) {$$now_string = strftime "%F", localtime; s/(\d+-\d+-\d+)/$$now_string/e}' \
+	  $(PLUGIN) $(LIB)
+	$(PERL) -i.orig -MPOSIX -pne \
+	  'if (/^\s+$(VERSION)\s+\d+-\d+-\d+\s+\*/) {$$now_string = strftime "%F", localtime; s/(\d+-\d+-\d+)/$$now_string/}' \
+	  $(DOC)
+
+test:
+	$(MAKE) -C test
+
+install: $(SOURCES)
+	for dir in $(^D);\
+  do install -d -m 0755 $(DESTDIR)$(PREFIX)/$$dir;\
+done;\
+for file in $^;\
+  do install -m 0644 $$file $(DESTDIR)$(PREFIX)/$$file;\
+done;
+
+uninstall:
+	for file in $(SOURCES);\
+  do rm -f $(DESTDIR)$(PREFIX)/$$file;\
+done;
+
+%.vmb: $(SOURCES)
+	$(VIM) -N -es -u NORC \
+  -c 'call setline(1,["$(subst $(space),"$(comma)",$^)"])'\
+  -c "%MkVimball! $(basename $@) ." -c 'q!'
+
+%.vmb.zip: vimball
+	zip $@ $(basename $@)
+
+%.zip: $(SOURCES)
+	zip $@ $^
+
+%.vmb.gz: vimball
+	gzip -f < $(basename $@) > $@
+
+%.tar.gz: $(SOURCES)
+	tar -cvzf $@ $^
+
+# vim:ts=2:sw=2

README.md

@@ -0,0 +1,6 @@
+This plug-in provides automatic closing of quotes, parenthesis, brackets, etc., besides some other related features that
+should make your time in insert mode a little bit easier, like syntax awareness (will not insert the closing delimiter
+in comments and other configurable regions), <CR> and <Space> expansions (off by default), and some more.
+
+Most of the features can be modified or disabled permanently, using global variables, or on a FileType basis, using
+:autocmd.

autoload/delimitMate.vim

@@ -0,0 +1,656 @@
+" File:        autoload/delimitMate.vim
+" Version:     2.7
+" Modified:    2013-07-15
+" Description: This plugin provides auto-completion for quotes, parens, etc.
+" Maintainer:  Israel Chauca F. <israelchauca@gmail.com>
+" Manual:      Read ":help delimitMate".
+" ============================================================================
+
+"let delimitMate_loaded = 1
+
+if !exists('s:options')
+  let s:options = {}
+endif
+
+function! s:set(name, value) "{{{
+  let bufnr = bufnr('%')
+  if !has_key(s:options, bufnr)
+    let s:options[bufnr] = {}
+  endif
+  let s:options[bufnr][a:name] = a:value
+endfunction "}}}
+
+function! s:get(...) "{{{
+  let options = deepcopy(eval('s:options.' . bufnr('%')))
+  if a:0
+    return options[a:1]
+  endif
+  return options
+endfunction "}}}
+
+function! s:exists(name, ...) "{{{
+  let scope = a:0 ? a:1 : 's'
+  if scope == 's'
+    let bufnr = bufnr('%')
+    let name = 'options.' . bufnr . '.' . a:name
+  else
+    let name = 'delimitMate_' . a:name
+  endif
+  return exists(scope . ':' . name)
+endfunction "}}}
+
+function! s:is_jump(...) "{{{
+  " Returns 1 if the next character is a closing delimiter.
+  let char = s:get_char(0)
+  let list = s:get('right_delims') + s:get('quotes_list')
+
+  " Closing delimiter on the right.
+  if (!a:0 && index(list, char) > -1)
+        \ || (a:0 && char == a:1)
+    return 1
+  endif
+
+  " Closing delimiter with space expansion.
+  let nchar = s:get_char(1)
+  if !a:0 && s:get('expand_space') && char == " "
+    if index(list, nchar) > -1
+      return 2
+    endif
+  elseif a:0 && s:get('expand_space') && nchar == a:1 && char == ' '
+    return 3
+  endif
+
+  if !s:get('jump_expansion')
+    return 0
+  endif
+
+  " Closing delimiter with CR expansion.
+  let uchar = matchstr(getline(line('.') + 1), '^\s*\zs\S')
+  if !a:0 && s:get('expand_cr') && char == ""
+    if index(list, uchar) > -1
+      return 4
+    endif
+  elseif a:0 && s:get('expand_cr') && uchar == a:1
+    return 5
+  endif
+  return 0
+endfunction "}}}
+
+function! s:rquote(char) "{{{
+  let pos = matchstr(getline('.')[col('.') : ], escape(a:char, '[]*.^$\'), 1)
+  let i = 0
+  while s:get_char(i) ==# a:char
+    let i += 1
+  endwhile
+  return i
+endfunction "}}}
+
+function! s:lquote(char) "{{{
+  let i = 0
+  while s:get_char(i - 1) ==# a:char
+    let i -= 1
+  endwhile
+  return i * -1
+endfunction "}}}
+
+function! s:get_char(...) "{{{
+  let idx = col('.') - 1
+  if !a:0 || (a:0 && a:1 >= 0)
+    " Get char from cursor.
+    let line = getline('.')[idx :]
+    let pos = a:0 ? a:1 : 0
+    return matchstr(line, '^'.repeat('.', pos).'\zs.')
+  endif
+  " Get char behind cursor.
+  let line = getline('.')[: idx - 1]
+  let pos = 0 - (1 + a:1)
+  return matchstr(line, '.\ze'.repeat('.', pos).'$')
+endfunction "s:get_char }}}
+
+function! s:is_cr_expansion(...) " {{{
+  let nchar = getline(line('.')-1)[-1:]
+  let schar = matchstr(getline(line('.')+1), '^\s*\zs\S')
+  let isEmpty = a:0 ? getline('.') =~ '^\s*$' : empty(getline('.'))
+  if index(s:get('left_delims'), nchar) > -1
+        \ && index(s:get('left_delims'), nchar)
+        \    == index(s:get('right_delims'), schar)
+        \ && isEmpty
+    return 1
+  elseif index(s:get('quotes_list'), nchar) > -1
+        \ && index(s:get('quotes_list'), nchar)
+        \    == index(s:get('quotes_list'), schar)
+        \ && isEmpty
+    return 1
+  else
+    return 0
+  endif
+endfunction " }}} s:is_cr_expansion()
+
+function! s:is_space_expansion() " {{{
+  if col('.') > 2
+    let pchar = s:get_char(-2)
+    let nchar = s:get_char(1)
+    let isSpaces =
+          \ (s:get_char(-1)
+          \   == s:get_char(0)
+          \ && s:get_char(-1) == " ")
+
+    if index(s:get('left_delims'), pchar) > -1 &&
+        \ index(s:get('left_delims'), pchar)
+        \   == index(s:get('right_delims'), nchar) &&
+        \ isSpaces
+      return 1
+    elseif index(s:get('quotes_list'), pchar) > -1 &&
+        \ index(s:get('quotes_list'), pchar)
+        \   == index(s:get('quotes_list'), nchar) &&
+        \ isSpaces
+      return 1
+    endif
+  endif
+  return 0
+endfunction " }}} IsSpaceExpansion()
+
+function! s:is_empty_matchpair() "{{{
+  " get char before the cursor.
+  let open = s:get_char(-1)
+  let idx = index(s:get('left_delims'), open)
+  if idx == -1
+    return 0
+  endif
+  let close = get(s:get('right_delims'), idx, '')
+  return close ==# s:get_char(0)
+endfunction "}}}
+
+function! s:is_empty_quotes() "{{{
+  " get char before the cursor.
+  let quote = s:get_char(-1)
+  let idx = index(s:get('quotes_list'), quote)
+  if idx == -1
+    return 0
+  endif
+  return quote ==# s:get_char(0)
+endfunction "}}}
+
+function! s:cursor_idx() "{{{
+  let idx = len(split(getline('.')[: col('.') - 1], '\zs')) - 1
+  return idx
+endfunction "delimitMate#CursorCol }}}
+
+function! s:get_syn_name() "{{{
+  let col = col('.')
+  if  col == col('$')
+    let col = col - 1
+  endif
+  return synIDattr(synIDtrans(synID(line('.'), col, 1)), 'name')
+endfunction " }}}
+
+function! s:is_excluded_ft(ft) "{{{
+  if !exists("g:delimitMate_excluded_ft")
+    return 0
+  endif
+  return index(split(g:delimitMate_excluded_ft, ','), a:ft, 0, 1) >= 0
+endfunction "}}}
+
+function! s:is_forbidden(char) "{{{
+  if s:is_excluded_ft(&filetype)
+    return 1
+  endif
+  if !s:get('excluded_regions_enabled')
+    return 0
+  endif
+  let region = s:get_syn_name()
+  return index(s:get('excluded_regions_list'), region) >= 0
+endfunction "}}}
+
+function! s:balance_matchpairs(char) "{{{
+  " Returns:
+  " = 0 => Parens balanced.
+  " > 0 => More opening parens.
+  " < 0 => More closing parens.
+
+  let line = getline('.')
+  let col = s:cursor_idx() - 1
+  let col = col >= 0 ? col : 0
+  let list = split(line, '\zs')
+  let left = s:get('left_delims')[index(s:get('right_delims'), a:char)]
+  let right = a:char
+  let opening = 0
+  let closing = 0
+
+  " If the cursor is not at the beginning, count what's behind it.
+  if col > 0
+      " Find the first opening paren:
+      let start = index(list, left)
+      " Must be before cursor:
+      let start = start < col ? start : col - 1
+      " Now count from the first opening until the cursor, this will prevent
+      " extra closing parens from being counted.
+      let opening = count(list[start : col - 1], left)
+      let closing = count(list[start : col - 1], right)
+      " I don't care if there are more closing parens than opening parens.
+      let closing = closing > opening ? opening : closing
+  endif
+
+  " Evaluate parens from the cursor to the end:
+  let opening += count(list[col :], left)
+  let closing += count(list[col :], right)
+
+  " Return the found balance:
+  return opening - closing
+endfunction "}}}
+
+function! s:is_smart_quote(char) "{{{
+  " TODO: Allow using a:char in the pattern.
+  let tmp = s:get('smart_quotes')
+  if empty(tmp)
+    return 0
+  endif
+  let regex = matchstr(tmp, '^!\?\zs.*')
+  " Flip matched value if regex starts with !
+  let mod = tmp =~ '^!' ? [1, 0] : [0, 1]
+  let matched = search(regex, 'ncb', line('.')) > 0
+  let noescaped = substitute(getline('.'), '\\.', '', 'g')
+  let odd =  (count(split(noescaped, '\zs'), a:char) % 2)
+  let result = mod[matched] || odd
+  return result
+endfunction "delimitMate#SmartQuote }}}
+
+function! delimitMate#Set(...) "{{{
+  return call('s:set', a:000)
+endfunction "}}}
+
+function! delimitMate#Get(...) "{{{
+  return call('s:get', a:000)
+endfunction "}}}
+
+function! delimitMate#ShouldJump(...) "{{{
+  return call('s:is_jump', a:000)
+endfunction "}}}
+
+function! delimitMate#IsEmptyPair(str) "{{{
+  if strlen(substitute(a:str, ".", "x", "g")) != 2
+    return 0
+  endif
+  let idx = index(s:get('left_delims'), matchstr(a:str, '^.'))
+  if idx > -1 &&
+        \ s:get('right_delims')[idx] == matchstr(a:str, '.$')
+    return 1
+  endif
+  let idx = index(s:get('quotes_list'), matchstr(a:str, '^.'))
+  if idx > -1 &&
+        \ s:get('quotes_list')[idx] == matchstr(a:str, '.$')
+    return 1
+  endif
+  return 0
+endfunction "}}}
+
+function! delimitMate#WithinEmptyPair() "{{{
+  " if cursor is at column 1 return 0
+  if col('.') == 1
+    return 0
+  endif
+  " get char before the cursor.
+  let char1 = s:get_char(-1)
+  " get char under the cursor.
+  let char2 = s:get_char(0)
+  return delimitMate#IsEmptyPair( char1.char2 )
+endfunction "}}}
+
+function! delimitMate#SkipDelim(char) "{{{
+  if s:is_forbidden(a:char)
+    return a:char
+  endif
+  let col = col('.') - 1
+  let line = getline('.')
+  if col > 0
+    let cur = s:get_char(0)
+    let pre = s:get_char(-1)
+  else
+    let cur = s:get_char(0)
+    let pre = ""
+  endif
+  if pre == "\\"
+    " Escaped character
+    return a:char
+  elseif cur == a:char
+    " Exit pair
+    return a:char . "\<Del>"
+  elseif delimitMate#IsEmptyPair( pre . a:char )
+    " Add closing delimiter and jump back to the middle.
+    return a:char . s:joinUndo() . "\<Left>"
+  else
+    " Nothing special here, return the same character.
+    return a:char
+  endif
+endfunction "}}}
+
+function! delimitMate#ParenDelim(right) " {{{
+  let left = s:get('left_delims')[index(s:get('right_delims'),a:right)]
+  if s:is_forbidden(a:right)
+    return left
+  endif
+  " Try to balance matchpairs
+  if s:get('balance_matchpairs') &&
+        \ s:balance_matchpairs(a:right) < 0
+    return left
+  endif
+  let line = getline('.')
+  let col = col('.')-2
+  if s:get('smart_matchpairs') != ''
+    let smart_matchpairs = substitute(s:get('smart_matchpairs'), '\\!', left, 'g')
+    let smart_matchpairs = substitute(smart_matchpairs, '\\#', a:right, 'g')
+    if line[col+1:] =~ smart_matchpairs
+      return left
+    endif
+  endif
+  if len(line) == (col + 1) && s:get('insert_eol_marker') == 1
+    let tail = s:get('eol_marker')
+  else
+    let tail = ''
+  endif
+  return left . a:right . tail . repeat(s:joinUndo() . "\<Left>", len(split(tail, '\zs')) + 1)
+endfunction " }}}
+
+function! delimitMate#QuoteDelim(char) "{{{
+  if s:is_forbidden(a:char)
+    return a:char
+  endif
+  let char_at = s:get_char(0)
+  let char_before = s:get_char(-1)
+  let nesting_on = index(s:get('nesting_quotes'), a:char) > -1
+  let left_q = nesting_on ? s:lquote(a:char) : 0
+  if nesting_on && left_q > 1
+    " Nesting quotes.
+    let right_q =  s:rquote(a:char)
+    let quotes = right_q > left_q + 1 ? 0 : left_q - right_q + 2
+    let lefts = quotes - 1
+    return repeat(a:char, quotes) . repeat(s:joinUndo() . "\<Left>", lefts)
+  elseif char_at == a:char
+    " Inside an empty pair, jump out
+    return a:char . "\<Del>"
+  elseif a:char == '"' && index(split(&ft, '\.'), "vim") != -1 && getline('.') =~ '^\s*$'
+    " If we are in a vim file and it looks like we're starting a comment, do
+    " not add a closing char.
+    return a:char
+  elseif s:is_smart_quote(a:char)
+    " Seems like a smart quote, insert a single char.
+    return a:char
+  elseif (char_before == a:char && char_at != a:char)
+        \ && !empty(s:get('smart_quotes'))
+    " Seems like we have an unbalanced quote, insert one quotation
+    " mark and jump to the middle.
+    return a:char . s:joinUndo() . "\<Left>"
+  else
+    " Insert a pair and jump to the middle.
+    let sufix = ''
+    if !empty(s:get('eol_marker')) && col('.') - 1 == len(getline('.'))
+      let idx = len(s:get('eol_marker')) * -1
+      let marker = getline('.')[idx : ]
+      let has_marker = marker == s:get('eol_marker')
+      let sufix = !has_marker ? s:get('eol_marker') : ''
+    endif
+    return a:char . a:char . s:joinUndo() . "\<Left>"
+  endif
+endfunction "}}}
+
+function! delimitMate#JumpOut(char) "{{{
+  if s:is_forbidden(a:char)
+    return a:char
+  endif
+  let jump = s:is_jump(a:char)
+  if jump == 1
+    " HACK: Instead of <Right>, we remove the char to be jumped over and
+    " insert it again. This will trigger re-indenting via 'indentkeys'.
+    " Ref: https://github.com/Raimondi/delimitMate/issues/168
+    return "\<Del>".a:char
+  elseif jump == 3
+    return s:joinUndo() . "\<Right>" . s:joinUndo() . "\<Right>"
+  elseif jump == 5
+    return "\<Down>\<C-O>I" . s:joinUndo() . "\<Right>"
+  else
+    return a:char
+  endif
+endfunction " }}}
+
+function! delimitMate#JumpAny(...) " {{{
+  if s:is_forbidden('')
+    return ''
+  endif
+  if !s:is_jump()
+    return ''
+  endif
+  " Let's get the character on the right.
+  let char = s:get_char(0)
+  if char == " "
+    " Space expansion.
+    return s:joinUndo() . "\<Right>" . s:joinUndo() . "\<Right>"
+  elseif char == ""
+    " CR expansion.
+    return "\<CR>" . getline(line('.') + 1)[0] . "\<Del>\<Del>"
+  else
+    return s:joinUndo() . "\<Right>"
+  endif
+endfunction " delimitMate#JumpAny() }}}
+
+function! delimitMate#JumpMany() " {{{
+  let line = split(getline('.')[col('.') - 1 : ], '\zs')
+  let rights = ""
+  let found = 0
+  for char in line
+    if index(s:get('quotes_list'), char) >= 0 ||
+          \ index(s:get('right_delims'), char) >= 0
+      let rights .= s:joinUndo() . "\<Right>"
+      let found = 1
+    elseif found == 0
+      let rights .= s:joinUndo() . "\<Right>"
+    else
+      break
+    endif
+  endfor
+  if found == 1
+    return rights
+  else
+    return ''
+  endif
+endfunction " delimitMate#JumpMany() }}}
+
+function! delimitMate#ExpandReturn() "{{{
+  if s:is_forbidden("")
+    return "\<CR>"
+  endif
+  let escaped = s:cursor_idx() >= 2
+        \ && s:get_char(-2) == '\'
+  let expand_right_matchpair = s:get('expand_cr') == 2
+        \     && index(s:get('right_delims'), s:get_char(0)) > -1
+  let expand_inside_quotes = s:get('expand_inside_quotes')
+          \     && s:is_empty_quotes()
+          \     && !escaped
+  let is_empty_matchpair = s:is_empty_matchpair()
+  if !pumvisible(  )
+        \ && (   is_empty_matchpair
+        \     || expand_right_matchpair
+        \     || expand_inside_quotes)
+    let val = "\<Esc>a"
+    if is_empty_matchpair && s:get('insert_eol_marker') == 2
+          \ && !search(escape(s:get('eol_marker'), '[]\.*^$').'$', 'cnW', '.')
+      let tail = getline('.')[col('.') - 1 : ]
+      let times = len(split(tail, '\zs'))
+      let val .= repeat(s:joinUndo() . "\<Right>", times) . s:get('eol_marker') . repeat(s:joinUndo() . "\<Left>", times + 1)
+    endif
+    let val .= "\<CR>"
+    if &smartindent && !&cindent && !&indentexpr
+          \ && s:get_char(0) == '}'
+      " indentation is controlled by 'smartindent', and the first character on
+      " the new line is '}'. If this were typed manually it would reindent to
+      " match the current line. Let's reproduce that behavior.
+      let sw = &sw == 0 ? &ts : &sw
+      let shifts = indent('.') / sw
+      let spaces = indent('.') - (shifts * sw)
+      let val .= "^\<C-D>".repeat("\<C-T>", shifts).repeat(' ', spaces)
+    endif
+    " Expand:
+    " XXX zv prevents breaking expansion with syntax folding enabled by
+    " InsertLeave.
+    let val .= "\<Esc>zvO"
+    return val
+  else
+    return "\<CR>"
+  endif
+endfunction "}}}
+
+function! delimitMate#ExpandSpace() "{{{
+  if s:is_forbidden("\<Space>")
+    return "\<Space>"
+  endif
+  let escaped = s:cursor_idx() >= 2
+        \ && s:get_char(-2) == '\'
+  let expand_inside_quotes = s:get('expand_inside_quotes')
+          \     && s:is_empty_quotes()
+          \     && !escaped
+  if s:is_empty_matchpair() || expand_inside_quotes
+    " Expand:
+    return "\<Space>\<Space>" . s:joinUndo() . "\<Left>"
+  else
+    return "\<Space>"
+  endif
+endfunction "}}}
+
+function! delimitMate#BS() " {{{
+  if s:is_forbidden("")
+    let extra = ''
+  elseif &bs !~ 'start\|2'
+    let extra = ''
+  elseif delimitMate#WithinEmptyPair()
+    let extra = "\<Del>"
+  elseif s:is_space_expansion()
+    let extra = "\<Del>"
+  elseif s:is_cr_expansion()
+    let extra = repeat("\<Del>",
+          \ len(matchstr(getline(line('.') + 1), '^\s*\S')))
+  else
+    let extra = ''
+  endif
+  return "\<BS>" . extra
+endfunction " }}} delimitMate#BS()
+
+function! delimitMate#Test() "{{{
+  %d _
+  " Check for script options:
+  let result = [
+        \ 'delimitMate Report',
+        \ '==================',
+        \ '',
+        \ '* Options: ( ) default, (g) global, (b) buffer',
+        \ '']
+  for option in sort(keys(s:options[bufnr('%')]))
+    if s:exists(option, 'b')
+      let scope = '(b)'
+    elseif s:exists(option, 'g')
+      let scope = '(g)'
+    else
+      let scope = '( )'
+    endif
+    call add(result,
+          \ scope . ' delimitMate_' . option
+          \ . ' = '
+          \ . string(s:get(option)))
+  endfor
+  call add(result, '')
+
+  let option = 'delimitMate_excluded_ft'
+  call add(result,
+        \(exists('g:'.option) ? '(g) ' : '( ) g:') . option . ' = '
+        \. string(get(g:, option, '')))
+
+  call add(result, '--------------------')
+  call add(result, '')
+
+  " Check if mappings were set.
+  let left_delims = s:get('autoclose') ? s:get('left_delims') : []
+  let special_keys = ['<BS>', '<S-BS>', '<S-Tab>', '<C-G>g']
+  if s:get('expand_cr')
+    call add(special_keys, '<CR>')
+  endif
+  if s:get('expand_space')
+    call add(special_keys, '<Space>')
+  endif
+  let maps =
+        \ s:get('right_delims')
+        \ + left_delims
+        \ + s:get('quotes_list')
+        \ + s:get('apostrophes_list')
+        \ + special_keys
+
+  call add(result, '* Mappings:')
+  call add(result, '')
+  for map in maps
+    let output = ''
+    if map == '|'
+      let map = '<Bar>'
+    endif
+    redir => output | execute "verbose imap ".map | redir END
+    call extend(result, split(output, '\n'))
+  endfor
+
+  call add(result, '--------------------')
+  call add(result, '')
+  call add(result, '* Showcase:')
+  call add(result, '')
+  call setline(1, result)
+  call s:test_mappings(s:get('left_delims'), 1)
+  call s:test_mappings(s:get('quotes_list'), 0)
+
+  let result = []
+  redir => setoptions
+  echo " * Vim configuration:\<NL>"
+  filetype
+  echo ""
+  set
+  version
+  redir END
+  call extend(result, split(setoptions,"\n"))
+  call add(result, '--------------------')
+  setlocal nowrap
+  call append('$', result)
+  call feedkeys("\<Esc>\<Esc>", 'n')
+endfunction "}}}
+
+function! s:test_mappings(list, is_matchpair) "{{{
+  let prefix = "normal Go0\<C-D>"
+  let last = "|"
+  let open = s:get('autoclose') ? 'Open: ' : 'Open & close: '
+  for s in a:list
+    if a:is_matchpair
+      let pair = s:get('right_delims')[index(s:get('left_delims'), s)]
+    else
+      let pair = s
+    endif
+    if !s:get('autoclose')
+      let s .= pair
+    endif
+    exec prefix . open . s . last
+    exec prefix . "Delete: " . s . "\<BS>" . last
+    exec prefix . "Exit: " . s . pair . last
+    if s:get('expand_space')
+          \ && (a:is_matchpair || s:get('expand_inside_quotes'))
+      exec prefix . "Space: " . s . " " . last
+      exec prefix . "Delete space: " . s . " \<BS>" . last
+    endif
+    if s:get('expand_cr')
+          \ && (a:is_matchpair || s:get('expand_inside_quotes'))
+      exec prefix . "Car return: " . s . "\<CR>" . last
+      exec prefix . "Delete car return: " . s . "\<CR>0\<C-D>\<BS>" . last
+    endif
+    call append('$', '')
+  endfor
+endfunction "}}}
+
+function! s:joinUndo() "{{{
+  if v:version < 704
+        \ || ( v:version == 704 && !has('patch849') )
+    return ''
+  endif
+  return "\<C-G>U"
+endfunction "}}}
+
+" vim:foldmethod=marker:foldcolumn=4:ts=2:sw=2

basic_vimrc

@@ -0,0 +1,4 @@
+so ./test/_setup.vim
+let delimitMate_expand_cr = 1
+filetype indent plugin on
+

delimitMate.txt

@@ -1,440 +0,0 @@
-*delimitMate.txt* Trying to keep those beasts at bay! v.1.6
-
-
-                              REFERENCE MANUAL *delimitMate*
-
-
-==============================================================================
- 0.- CONTENTS                                           *delimitMate-contents*
-
-    1. Introduction____________________________|delimitMateIntro|
-    2. Functionality___________________________|delimitMateFunctionality|
-        2.1 Automatic closing & exiting________|delimitMateAutoClose|
-        2.2 Expansion of space and CR__________|delimitMateExpansion|
-        2.3 Deletion of empty pairs____________|delimitMateBackspace|
-        2.4 Visual wrapping____________________|delimitMateVisualWrapping|
-    3. Customization___________________________|delimitMateOptions|
-        3.1 Option summary_____________________|delimitMateOptionSummary|
-        3.2 Options details____________________|delimitMateOptionDetails|
-    4. Commands________________________________|delimitMateCommands|
-    5. TODO list_______________________________|delimitMateTodo|
-    6. Maintainer______________________________|delimitMateMaintainer|
-    7. Credits_________________________________|delimitMateCredits|
-    8. History_________________________________|delimitMateHistory|
-
-==============================================================================
- 1.- INTRODUCTION                                           *delimitMateIntro*
-
-The delimitMate plugin tries to provide some not so dumb help in the work with
-delimiters (brackets, quotes, etc.), with some optional auto-completions and
-expansions.
-
-When automatic closing is enabled, if an opening delimiter is inserted
-delimitMate inserts the closing pair and places the cursor between them. When
-automatic closing is disabled, no closing delimiters is inserted by
-delimitMate, but if a pair of delimiters is typed, the cursor is placed in the
-middle. Also, to get out of a pair of delimiters just type the right delimiter
-and the cursor will jump to the right.
-
-If the cursor is inside an empty pair of delimiters <Space> and <CR> can be
-expanded to follow your coding style, you just need to define a couple of
-options with the desired mappings for them.
-
-==============================================================================
- 2. FUNCTIONALITY                                   *delimitMateFunctionality*
-
-------------------------------------------------------------------------------
-   2.1 AUTOMATIC CLOSING AND EXITING                    *delimitMateAutoClose*
-
-With automatic closing enabled, if an opening delimiter is inserted the plugin
-inserts the closing delimiter and places the cursor between the pair. With
-automatic closing disabled, no closing delimiters is inserted by delimitMate,
-but when a pair of delimiters is typed, the cursor is placed in the middle.
-
-When the cursor is inside an empty pair or located next to the left of a
-closing delimiter, the cursor is placed outside the pair to the right of the
-closing delimiter.
-
-Unless |'b:delimitMate_matchpairs'| and |'b:delimitMate_quotes'|is set, this
-script uses the values in '&matchpairs' to identify the pairs, and ", ' and `
-for quotes respectively.
-
-The following table shows the behaviour, this applies to quotes too (the final
-position of the cursor is represented by a "|"):
-
-With auto-close: >
-                          Type   |  You get
-                        ====================
-                           (     |    (|)
-                        –––––––––|––––––––––
-                           ()    |    ()|
-<
-Without auto-close: >
-
-                          Type   |  You get
-                        ====================
-                           ()    |    (|)
-                        –––––––––|––––––––––
-                           ())   |    ()|
-<
-------------------------------------------------------------------------------
-   2.2 EXPANSION OF SPACE AND CAR RETURN                *delimitMateExpansion*
-
-When the cursor is inside an empty pair of delimiters, <Space> and <CR> can be
-expanded to follow your coding style with |'b:delimitMate_expand_space'| and
-|'b:delimitMate_expand_cr'|. e.g. (cursor represented by a "|"):
-
-Expand <Space> to: >
-
-                  <Space><Space><Left>  |  You get
-                ====================================
-                            (|)         |    ( | )
-<
-Expand <CR> to: >
-
-                    <CR><CR><Up>  |  You get
-                  ============================
-                         (|)      |    (
-                                  |    |
-                                  |    )
-<
-
-------------------------------------------------------------------------------
-   2.3 DELETION OF EMPTY PAIR                           *delimitMateBackspace*
-
-If you press backspace inside an empty pair, both delimiters are deleted.
-
-e.g.: >
-
-                 Before           |  After
-               ====================================
-                 call expand(|)   |  call expand|
-<
-
-------------------------------------------------------------------------------
-   2.4 WRAPPING OF VISUAL SELECTION                *delimitMateVisualWrapping*
-
-When visual mode is active this script allows for the selection to be enclosed
-with delimiters. But, since brackets have special meaning in visual mode, a
-leader (the value of 'mapleader' by default) should precede the delimiter.
-This feature doesn't currently work on blockwise visual mode, any suggestions
-will be welcome.
-
-e.g. (selection represented between square brackets): >
-
-             Selected text       |  After \"
-           =============================================
-            An [absurd] example! | An "absurd" example!
-<
-==============================================================================
- 3. CUSTOMIZATION                                         *delimitMateOptions*
-
-------------------------------------------------------------------------------
-   3.1 OPTIONS SUMMARY                              *delimitMateOptionSummary*
-
-The behaviour of this script can be customized setting the following options
-in your vimrc file. You can use local options to set the configuration for
-specific file types, see |delimitMateOptionDetails| for examples.
-
-|'loaded_delimitMate'|          Turns off the script.
-
-|'delimitMate_autoclose'|       Tells delimitMate whether to automagically
-                                insert the closing delimiter.
-
-|'delimitMate_matchpairs'|      Tells delimitMate which characters are
-                                matching pairs.
-
-|'delimitMate_quotes'|          Tells delimitMate which quotes should be
-                                used.
-
-|'delimitMate_visual_leader'|   Sets the leader to be used in visual mode.
-
-|'delimitMate_expand_cr'|       Sets the expansion for <CR> inside an empty
-                                pair of matching delimiters or quotes.
-
-|'delimitMate_expand_space'|    Sets the expansion for <Space> inside an
-                                empty pair of matching delimiters or quotes.
-
-|'delimitMate_excluded_ft'|     Turns off the script for the given file types.
-
-|'delimitMate_apostrophes'|     Tells delimitMate how it should "fix"
-                                balancing of single quotes when used as
-                                apostrophes.
-
-------------------------------------------------------------------------------
-   3.2 OPTIONS DETAILS                              *delimitMateOptionDetails*
-
-Add the shown lines to your vimrc file in order to set the below options.
-Local options take precedence over global ones and can be used along with
-autocmd to modify delimitMate's behavior for specific file types.
-
-                                                     *'loaded_delimitMate'*
-                                                   *'b:loaded_delimitMate'*
-This option prevents delimitMate from loading.
-e.g.: >
-        let loaded_delimitMate = 1
-        au FileType mail let b:loaded_delimitMate = 1
-<
-------------------------------------------------------------------------------
-                                                     *'delimitMate_autoclose'*
-                                                   *'b:delimitMate_autoclose'*
-Values: 0 or 1.                                                              ~
-Default: 1                                                                   ~
-
-If this option is set to 0, delimitMate will not add a closing delimiter
-automagically. See |delimitMateAutoClose| for details.
-e.g.: >
-        let delimitMate_autoclose = 0
-        au FileType mail let b:delimitMate_autoclose = 0
-<
-------------------------------------------------------------------------------
-                                                    *'delimitMate_matchpairs'*
-                                                  *'b:delimitMate_matchpairs'*
-Values: A string with |matchpairs| syntax.                                   ~
-Default: &matchpairs                                                         ~
-
-Use this option to tell delimitMate which characters should be considered
-matching pairs. Read |delimitMateAutoClose| for details.
-e.g: >
-        let delimitMate = "(:),[:],{:},<:>"
-        au FileType vim,html let b:delimitMate_matchpairs = "(:),[:],{:},<:>"
-<
-------------------------------------------------------------------------------
-                                                        *'delimitMate_quotes'*
-                                                      *'b:delimitMate_quotes'*
-Values: A string of characters separated by spaces.                          ~
-Default: "\" ' `"                                                            ~
-
-Use this option to tell delimitMate which characters should be considered as
-quotes. Read |delimitMateAutoClose| for details.
-e.g.: >
-        let b:delimitMate_quotes = "\" ' ` *"
-        au FileType html let b:delimitMate_quotes = "\" '"
-<
-------------------------------------------------------------------------------
-                                                 *'delimitMate_visual_leader'*
-                                               *'b:delimitMate_visual_leader'*
-Values: Any character.                                                       ~
-Default: q                                                                   ~
-
-The value of this option will be used to wrap the selection in visual mode
-when followed by a delimiter. Read |delimitMateVisualWrap| for details.
-e.g: >
-        let delimitMate_visual_leader = "f"
-        au FileType html let b:delimitMate_visual_leader = "f"
-<
-------------------------------------------------------------------------------
-                                                     *'delimitMate_expand_cr'*
-                                                   *'b:delimitMate_expand_cr'*
-Values: A key mapping.                                                       ~
-Default: "\<CR>"                                                             ~
-
-The value of this option will be used to expand the car return character when
-typed inside an empty delimiter pair. Read |delimitMateExpansion| for details.
-e.g.: >
-        let b:delimitMate_expand_cr = "\<CR>\<CR>\<Up>"
-        au FileType mail let b:delimitMate_expand_cr = "\<CR>
-<
-------------------------------------------------------------------------------
-                                                  *'delimitMate_expand_space'*
-                                                *'b:delimitMate_expand_space'*
-Values: A key mapping.                                                       ~
-Default: "\<Space>"                                                          ~
-
-The value of this option will be used to expand the space character when typed
-inside an empty delimiter pair. Read |delimitMateExpansion| for details.
-e.g.: >
-        let delimitMate_expand_space = "\<Space>\<Space>\<Left>"
-        au FileType tcl let b:delimitMate_expand_space = "\<Space>"
-<
-------------------------------------------------------------------------------
-                                                   *'delimitMate_excluded_ft'*
-Values: A string of file type names separated by single commas.              ~
-Default: Empty.                                                              ~
-
-This options turns delimitMate off for the listed file types, use this option
-only if don't want any of the features it provides.
-e.g.: >
-        let delimitMate_excluded_ft = "mail,txt"
-<
-------------------------------------------------------------------------------
-                                                   *'delimitMate_apostrophes'*
-Values: Strings separated by ":".                                            ~
-Default: "n't:'s:'re:'d:'ll:'ve:s'"                                          ~
-
-If auto-close is enabled, this option tells delimitMate how to try to fix the
-balancing of single quotes when used as apostrophes. The values of this option
-are strings of text where a single quote would be used as an apostrophe (e.g.:
-the "n't" of wouldn't or can't) separated by ":". Set it to an empty string to
-disable this feature.
-e.g.: >
-        let delimitMate_apostrophes = ""
-        au FileType tcl let delimitMate_apostrophes = ""
-<
-==============================================================================
- 4. COMMANDS                                             *delimitMateCommands*
-
-------------------------------------------------------------------------------
-:DelimitMateReload                                        *:DelimitMateReload*
-
-Re-sets all the mappings used for this script, use it if any option has been
-changed or if the filetype option hasn't been set yet.
-
-------------------------------------------------------------------------------
-:DelimitMateTest                                            *:DelimitMateTest*
-
-This command tests every mapping set-up for this script, useful for testing
-custom configurations.
-
-The following output corresponds to the default values, it will be different
-depending on your configuration. "Open & close:" represents the final result
-when the closing delimiter has been inserted, either manually or
-automatically, see |delimitMateExpansion|. "Delete:" typing backspace in an
-empty pair, see |delimitMateBackspace|. "Exit:" typing a closing delimiter
-inside a pair of delimiters, see |delimitMateAutoclose|. "Space:" the
-expansion, if any, of space, see |delimitMateExpansion|. "Visual-L",
-"Visual-R" and "Visual" shows visual wrapping, see
-|delimitMateVisualWrapping|. "Car return:" the expansion of car return, see
-|delimitMateExpansion|. The cursor's position at the end of every test is
-represented by an "|": >
-
-            * AUTOCLOSE:
-            Open & close: (|)
-            Delete: |
-            Exit: ()|
-            Space: ( |)
-            Visual-L: (v)
-            Visual-R: (v)
-            Car return: (
-            |)
-
-            Open & close: {|}
-            Delete: |
-            Exit: {}|
-            Space: { |}
-            Visual-L: {v}
-            Visual-R: {v}
-            Car return: {
-            |}
-
-            Open & close: [|]
-            Delete: |
-            Exit: []|
-            Space: [ |]
-            Visual-L: [v]
-            Visual-R: [v]
-            Car return: [
-            |]
-
-            Open & close: "|"
-            Delete: |
-            Exit: ""|
-            Space: " |"
-            Visual: "v"
-            Car return: "
-            |"
-
-            Open & close: '|'
-            Delete: |
-            Exit: ''|
-            Space: ' |'
-            Visual: 'v'
-            Car return: '
-            |'
-
-            Open & close: `|`
-            Delete: |
-            Exit: ``|
-            Space: ` |`
-            Visual: `v`
-            Car return: `
-            |`
-<
-
-==============================================================================
- 5. TODO LIST                                                *delimitMateTodo*
-
-- Automatic set-up by file type.
-- Make visual wrapping work on blockwise visual mode.
-- Limit behaviour by region.
-
-==============================================================================
- 6. MAINTAINER                                         *delimitMateMaintainer*
-
-Hi there! My name is Israel Chauca F. and I can be reached at:
-    mailto:israelchauca@gmail.com
-
-Feel free to send me any suggestions and/or comments about this plugin, I'll
-be very pleased to read them.
-
-==============================================================================
- 7. CREDITS                                               *delimitMateCredits*
-
-Some of the code that make this script is modified or just shamelessly copied
-from the following sources:
-
-   - Ian McCracken
-     Post titled: Vim, Part II: Matching Pairs:
-     http://concisionandconcinnity.blogspot.com/
-
-   - Aristotle Pagaltzis
-     From the comments on the previous blog post and from:
-     http://gist.github.com/144619
-
-   - Vim Scripts:
-     http://www.vim.org/scripts
-
-This script was inspired by the auto-completion of delimiters of TextMate.
-
-==============================================================================
- 8. HISTORY                                               *delimitMateHistory*
-
-  Version      Date      Release notes                                       ~
-|---------|------------|-----------------------------------------------------|
-    1.6     2009-10-10   Now delimitMate tries to fix the balancing of single
-                         quotes when used as apostrophes. You can read
-                         |delimitMate_apostrophes| for details.
-                         Fixed an error when |b:delimitMate_expand_space|
-                         wasn't set but |delimitMate_expand_space| wasn't.
-
-|---------|------------|-----------------------------------------------------|
-    1.5     2009-10-05   Fix: delimitMate should work correctly for files
-                         passed as arguments to Vim. Thanks to Ben Beuchler
-                         for helping to nail this bug.
-
-|---------|------------|-----------------------------------------------------|
-    1.4     2009-09-27   Fix: delimitMate is now enabled on new buffers even
-                         if they don't have set the file type option or were
-                         opened directly from the terminal.
-
-|---------|------------|-----------------------------------------------------|
-    1.3     2009-09-24   Now local options can be used along with autocmd
-                         for specific file type configurations.
-                         Fixes:
-                         - Unnamed register content is not lost on visual
-                         mode.
-                         - Use noremap where appropiate.
-                         - Wrapping a single empty line works as expected.
-
-|---------|------------|-----------------------------------------------------|
-    1.2	    2009-09-07   Fixes:
-                         - When inside nested empty pairs, deleting the
-                         innermost left delimiter would delete all right
-                         contiguous delimiters.
-                         - When inside an empty pair, inserting a left
-                         delimiter wouldn't insert the right one, instead
-                         the cursor would jump to the right.
-                         - New buffer inside the current window wouldn't
-                         have the mappings set.
-
-|---------|------------|-----------------------------------------------------|
-    1.1     2009-08-25   Fixed an error that ocurred when mapleader wasn't
-                         set and added support for GetLatestScripts
-                         auto-detection.
-
-|---------|------------|-----------------------------------------------------|
-    1.0     2009-08-23   Initial upload.
-
-|---------|------------|-----------------------------------------------------|
-
-vim:tw=78:ts=8:ft=help:norl:formatoptions+=tcroqn:autoindent:

delimitMate.vim

@@ -1,547 +0,0 @@
-" ============================================================================
-" File:        delimitMate.vim
-" Version:     1.6
-" Description: This plugin tries to emulate the auto-completion of delimiters
-"              that TextMate provides.
-" Maintainer:  Israel Chauca F. <israelchauca@gmail.com>
-" Manual:      Read ":help delimitMate".
-" Credits:     Some of the code is modified or just copied from the following:
-"
-"              - Ian McCracken
-"           	 Post titled: Vim, Part II: Matching Pairs:
-"           	 http://concisionandconcinnity.blogspot.com/
-"
-"              - Aristotle Pagaltzis
-"           	 From the comments on the previous blog post and from:
-"           	 http://gist.github.com/144619
-"
-"              - Vim Scripts:
-"           	 http://www.vim.org/scripts/
-
-if exists("g:loaded_delimitMate") "{{{1
-	" User doesn't want this plugin, let's get out!
-	finish
-endif
-let g:loaded_delimitMate = 1
-
-if exists("s:loaded_delimitMate") && !exists("g:delimitMate_testing")
-	" Don't define the functions if they already exist: just do the work
-	" (unless we are testing):
-	call s:DelimitMateDo()
-	finish
-endif
-
-if v:version < 700
-	echoerr "delimitMate: this plugin requires vim >= 7!"
-	finish
-endif
-
-let s:loaded_delimitMate = 1 " }}}1
-
-function! s:Init() "{{{1
-
-	if !exists("b:delimitMate_autoclose") && !exists("g:delimitMate_autoclose") " {{{
-		let s:autoclose = 1
-	elseif exists("b:delimitMate_autoclose")
-		let s:autoclose = b:delimitMate_autoclose
-	else
-		let s:autoclose = g:delimitMate_autoclose
-	endif " }}}
-
-	if !exists("b:delimitMate_matchpairs") && !exists("g:delimitMate_matchpairs") " {{{
-		if s:ValidMatchpairs(&matchpairs) == 1
-			let s:matchpairs_temp = &matchpairs
-		else
-			echoerr "delimitMate: There seems to be a problem with 'matchpairs', read ':help matchpairs' and fix it or notify the maintainer of this script if this is a bug."
-			finish
-		endif
-	elseif exists("b:delimitMate_matchpairs")
-		if s:ValidMatchpairs(b:delimitMate_matchpairs) || b:delimitMate_matchpairs == ""
-			let s:matchpairs_temp = b:delimitMate_matchpairs
-		else
-			echoerr "delimitMate: Invalid format in 'b:delimitMate_matchpairs', falling back to matchpairs. Fix the error and use the command :DelimitMateReload to try again."
-			if s:ValidMatchpairs(&matchpairs) == 1
-				let s:matchpairs_temp = &matchpairs
-			else
-				echoerr "delimitMate: There seems to be a problem with 'matchpairs', read ':help matchpairs' and fix it or notify the maintainer of this script if this is a bug."
-				let s:matchpairs_temp = ""
-			endif
-		endif
-	else
-		if s:ValidMatchpairs(g:delimitMate_matchpairs) || g:delimitMate_matchpairs == ""
-			let s:matchpairs_temp = g:delimitMate_matchpairs
-		else
-			echoerr "delimitMate: Invalid format in 'g:delimitMate_matchpairs', falling back to matchpairs. Fix the error and use the command :DelimitMateReload to try again."
-			if s:ValidMatchpairs(&matchpairs) == 1
-				let s:matchpairs_temp = &matchpairs
-			else
-				echoerr "delimitMate: There seems to be a problem with 'matchpairs', read ':help matchpairs' and fix it or notify the maintainer of this script if this is a bug."
-				let s:matchpairs_temp = ""
-			endif
-		endif
-
-	endif " }}}
-
-	if exists("b:delimitMate_quotes") " {{{
-		if b:delimitMate_quotes =~ '^\(\S\)\(\s\S\)*$' || b:delimitMate_quotes == ""
-			let s:quotes = split(b:delimitMate_quotes)
-		else
-			let s:quotes = split("\" ' `")
-			echoerr "delimitMate: There is a problem with the format of 'b:delimitMate_quotes', it should be a string of single characters separated by spaces. Falling back to default values."
-		endif
-	elseif exists("g:delimitMate_quotes")
-		if g:delimitMate_quotes =~ '^\(\S\)\(\s\S\)*$' || g:delimitMate_quotes == ""
-			let s:quotes = split(g:delimitMate_quotes)
-		else
-			let s:quotes = split("\" ' `")
-			echoerr "delimitMate: There is a problem with the format of 'g:delimitMate_quotes', it should be a string of single characters separated by spaces. Falling back to default values."
-		endif
-	else
-		let s:quotes = split("\" ' `")
-	endif " }}}
-
-	if !exists("b:delimitMate_visual_leader") && !exists("g:delimitMate_visual_leader") " {{{
-		if !exists("g:mapleader")
-			let s:visual_leader = "\\"
-		else
-			let s:visual_leader = g:mapleader
-		endif
-	elseif exists("b:delimitMate_visual_leader")
-		let s:visual_leader = b:delimitMate_visual_leader
-	else
-		let s:visual_leader = g:delimitMate_visual_leader
-	endif " }}}
-
-	if !exists("b:delimitMate_expand_space") && !exists("g:delimitMate_expand_space") " {{{
-		let s:expand_space = "\<Space>"
-	elseif exists("b:delimitMate_expand_space")
-		if b:delimitMate_expand_space == ""
-			let s:expand_space = "\<Space>"
-		else
-			let s:expand_space = b:delimitMate_expand_space
-		endif
-	else
-		if g:delimitMate_expand_space == ""
-			let s:expand_space = "\<Space>"
-		else
-			let s:expand_space = g:delimitMate_expand_space
-		endif
-
-	endif " }}}
-
-	if !exists("b:delimitMate_expand_cr") && !exists("g:delimitMate_expand_cr") " {{{
-		let s:expand_return = "\<CR>"
-	elseif exists("b:delimitMate_expand_cr")
-		if b:delimitMate_expand_cr == ""
-			let s:expand_return = "\<CR>"
-		else
-			let s:expand_return = b:delimitMate_expand_cr
-		endif
-	else
-		if g:delimitMate_expand_cr == ""
-			let s:expand_return = "\<CR>"
-		else
-			let s:expand_return = g:delimitMate_expand_cr
-		endif
-
-	endif " }}}
-
-	if !exists("b:delimitMate_apostrophes") && !exists("g:delimitMate_apostrophes") " {{{
-		let s:apostrophes = split("n't:'s:'re:'m:'d:'ll:'ve:s'",':')
-
-	elseif exists("b:delimitMate_apostrophes")
-		let s:apostrophes = split(b:delimitMate_apostrophes)
-	else
-		let s:apostrophes = split(g:delimitMate_apostrophes)
-	endif " }}}
-
-	let s:matchpairs = split(s:matchpairs_temp, ',')
-	let s:left_delims = split(s:matchpairs_temp, ':.,\=')
-	let s:right_delims = split(s:matchpairs_temp, ',\=.:')
-	let s:VMapMsg = "delimitMate: delimitMate is disabled on blockwise visual mode."
-
-	call s:UnMap()
-	if s:autoclose
-		call s:AutoClose()
-	else
-		call s:NoAutoClose()
-	endif
-	call s:VisualMaps()
-	call s:ExtraMappings()
-	let b:loaded_delimitMate = 1
-
-endfunction "}}}1
-
-function! s:ValidMatchpairs(str) "{{{1
-	if a:str !~ '^.:.\(,.:.\)*$'
-		return 0
-	endif
-	for pair in split(a:str,',')
-		if strpart(pair, 0, 1) == strpart(pair, 2, 1) || strlen(pair) != 3
-			return 0
-		endif
-	endfor
-	return 1
-endfunction "}}}1
-
-function! s:IsEmptyPair(str) "{{{1
-	for pair in s:matchpairs
-		if a:str == join( split( pair, ':' ),'' )
-			return 1
-		endif
-	endfor
-	for quote in s:quotes
-		if a:str == quote . quote
-			return 1
-		endif
-	endfor
-	return 0
-endfunction "}}}1
-
-function! s:WithinEmptyPair() "{{{1
-	let cur = strpart( getline('.'), col('.')-2, 2 )
-	return s:IsEmptyPair( cur )
-endfunction "}}}1
-
-function! s:SkipDelim(char) "{{{1
-	let cur = strpart( getline('.'), col('.')-2, 3 )
-	if cur[0] == "\\"
-		" Escaped character
-		return a:char
-	elseif cur[1] == a:char
-		" Exit pair
-		return "\<Right>"
-	elseif cur[1] == ' ' && cur[2] == a:char
-		" I'm leaving this in case someone likes it. Jump an space and delimiter.
-		return "\<Right>\<Right>"
-	elseif s:IsEmptyPair( cur[0] . a:char )
-		" Add closing delimiter and jump back to the middle.
-		return a:char . "\<Left>"
-	else
-		" Nothing special here, return the same character.
-		return a:char
-	endif
-endfunction "}}}1
-
-function! s:QuoteDelim(char) "{{{1
-	let line = getline('.')
-	let col = col('.')
-	if line[col - 2] == "\\"
-		" Seems like a escaped character, insert a single quotation mark.
-		return a:char
-	elseif line[col - 1] == a:char
-		" Get out of the string.
-		return "\<Right>"
-	else
-		" Insert a pair and jump to the middle.
-		return a:char.a:char."\<Left>"
-	endif
-endfunction "}}}1
-
-function! s:ClosePair(char) "{{{1
-	if getline('.')[col('.') - 1] == a:char
-		" Same character on the rigth, jump it.
-		return "\<Right>"
-	else
-		" Insert character.
-		return a:char
-	endif
-endfunction "}}}1
-
-function! s:ResetMappings() "{{{1
-	for delim in s:right_delims + s:left_delims + s:quotes
-		silent! exec 'iunmap <buffer> ' . delim
-		silent! exec 'vunmap <buffer> ' . s:visual_leader . delim
-	endfor
-	silent! iunmap <buffer> <CR>
-	silent! iunmap <buffer> <Space>
-endfunction "}}}1
-
-function! s:MapMsg(msg) "{{{1
-	redraw
-	echomsg a:msg
-	return ""
-endfunction "}}}1
-
-function! s:NoAutoClose() "{{{1
-	" inoremap <buffer> ) <C-R>=<SID>SkipDelim('\)')<CR>
-	for delim in s:right_delims + s:quotes
-		exec 'inoremap <buffer> ' . delim . ' <C-R>=<SID>SkipDelim("' . escape(delim,'"') . '")<CR>'
-	endfor
-endfunction "}}}1
-
-function! s:AutoClose() "{{{1
-	" Add matching pair and jump to the midle:
-	" inoremap <buffer> ( ()<Left>
-	let s:i = 0
-	while s:i < len(s:matchpairs)
-		exec 'inoremap <buffer> ' . s:left_delims[s:i] . ' ' . s:left_delims[s:i] . s:right_delims[s:i] . '<Left>'
-		let s:i += 1
-	endwhile
-
-	" Add matching quote and jump to the midle, or exit if inside a pair of matching quotes:
-	" inoremap <buffer> " <C-R>=<SID>QuoteDelim("\"")<CR>
-	for delim in s:quotes
-		exec 'inoremap <buffer> ' . delim . ' <C-R>=<SID>QuoteDelim("\' . delim . '")<CR>'
-	endfor
-
-	" Exit from inside the matching pair:
-	" inoremap <buffer> ) <C-R>=<SID>ClosePair(')')<CR>
-	for delim in s:right_delims
-		exec 'inoremap <buffer> ' . delim . ' <C-R>=<SID>ClosePair("\' . delim . '")<CR>'
-	endfor
-
-	" Try to fix the use of apostrophes:
-	" inoremap <buffer> n't n't
-	for map in s:apostrophes
-		exec "inoremap <buffer> " . map . " " . map
-	endfor
-
-endfunction "}}}1
-
-function! s:VisualMaps() " {{{1
-	" Wrap the selection with matching pairs, but do nothing if blockwise visual mode is active:
-	let s:i = 0
-	while s:i < len(s:matchpairs)
-		" Map left delimiter:
-		" vnoremap <buffer> <expr> \( <SID>IsBlockVisual() ? <SID>MapMsg("Message") : "s(\<C-R>\")\<Esc>:call <SID>RestoreRegister()<CR>"
-		exec 'vnoremap <buffer> <expr> ' . s:visual_leader . s:left_delims[s:i] . ' <SID>IsBlockVisual() ? <SID>MapMsg("' . s:VMapMsg . '") : "s' . s:left_delims[s:i] . '\<C-R>\"' . s:right_delims[s:i] . '\<Esc>:call <SID>RestoreRegister()<CR>"'
-
-		" Map right delimiter:
-		" vnoremap <buffer> <expr> \) <SID>IsBlockVisual() ? <SID>MapMsg("Message") : "s(\<C-R>\")\<Esc>:call <SID>RestoreRegister()<CR>"
-		exec 'vnoremap <buffer> <expr> ' . s:visual_leader . s:right_delims[s:i] . ' <SID>IsBlockVisual() ? <SID>MapMsg("' . s:VMapMsg . '") : "s' . s:left_delims[s:i] . '\<C-R>\"' . s:right_delims[s:i] . '\<Esc>:call <SID>RestoreRegister()<CR>"'
-		let s:i += 1
-	endwhile
-
-	" Wrap the selection with matching quotes, but do nothing if blockwise visual mode is active:
-	for quote in s:quotes
-		" vnoremap <buffer> <expr> \' <SID>IsBlockVisual() ? <SID>MapMsg("Message") : "s'\<C-R>\"'\<Esc>:call <SID>RestoreRegister()<CR>"
-		exec 'vnoremap <buffer> <expr> ' . s:visual_leader . quote . ' <SID>IsBlockVisual() ? <SID>MapMsg("' . s:VMapMsg . '") : "s' . escape(quote,'"') .'\<C-R>\"' . escape(quote,'"') . '\<Esc>:call <SID>RestoreRegister()<CR>"'
-	endfor
-endfunction "}}}1
-
-function! s:IsBlockVisual() " {{{1
-	if visualmode() == "<C-V>"
-		return 1
-	endif
-	" Store unnamed register values for later use in s:RestoreRegister().
-	let s:save_reg = getreg('"')
-	let s:save_reg_mode = getregtype('"')
-
-	if len(getline('.')) == 0
-		" This for proper wrap of empty lines.
-		let @" = "\n"
-	endif
-	return 0
-endfunction " }}}1
-
-function! s:RestoreRegister() " {{{1
-	" Restore unnamed register values store in s:IsBlockVisual().
-	call setreg('"', s:save_reg, s:save_reg_mode)
-	echo ""
-endfunction " }}}1
-
-function! s:ExpandReturn() "{{{1
-	if s:WithinEmptyPair()
-		" Expand:
-		return s:expand_return
-	else
-		" Don't
-		return "\<CR>"
-	endif
-endfunction "}}}1
-
-function! s:ExpandSpace() "{{{1
-	if s:WithinEmptyPair()
-		" Expand:
-		return s:expand_space
-	else
-		" Don't
-		return "\<Space>"
-	endif
-endfunction "}}}1
-
-function! s:ExtraMappings() "{{{1
-	" If pair is empty, delete both delimiters:
-	inoremap <buffer> <expr> <BS> <SID>WithinEmptyPair() ? "\<Right>\<BS>\<BS>" : "\<BS>"
-
-	" Expand return if inside an empty pair:
-	if exists("b:delimitMate_expand_cr") || exists("g:delimitMate_expand_cr")
-		inoremap <buffer> <CR> <C-R>=<SID>ExpandReturn()<CR>
-	endif
-
-	" Expand space if inside an empty pair:
-	if exists("b:delimitMate_expand_space") || exists("g:delimitMate_expand_space")
-		inoremap <buffer> <Space> <C-R>=<SID>ExpandSpace()<CR>
-	endif
-endfunction "}}}1
-
-function! s:TestMappings() "{{{1
-	if s:autoclose
-		 exec "normal i* AUTOCLOSE:\<CR>"
-		for i in range(len(s:left_delims))
-			exec "normal GGAOpen & close: " . s:left_delims[i]. "|"
-			exec "normal A\<CR>Delete: " . s:left_delims[i] . "\<BS>|"
-			exec "normal A\<CR>Exit: " . s:left_delims[i] . s:right_delims[i] . "|"
-			exec "normal A\<CR>Space: " . s:left_delims[i] . " |"
-			exec "normal GGA\<CR>Visual-L: v\<Esc>v" . s:visual_leader . s:left_delims[i]
-			exec "normal A\<CR>Visual-R: v\<Esc>v" . s:visual_leader . s:right_delims[i]
-			exec "normal A\<CR>Car return: " . s:left_delims[i] . "\<CR>|\<Esc>GGA\<CR>\<CR>"
-		endfor
-		for i in range(len(s:quotes))
-			exec "normal GGAOpen & close: " . s:quotes[i]	. "|"
-			exec "normal A\<CR>Delete: " . s:quotes[i] . "\<BS>|"
-			exec "normal A\<CR>Exit: " . s:quotes[i] . s:quotes[i] . "|"
-			exec "normal A\<CR>Space: " . s:quotes[i] . " |"
-			exec "normal GGA\<CR>Visual: v\<Esc>v" . s:visual_leader . s:quotes[i]
-			exec "normal A\<CR>Car return: " . s:quotes[i] . "\<CR>|\<Esc>GGA\<CR>\<CR>"
-		endfor
-	else
-		exec "normal i* NO AUTOCLOSE:\<CR>"
-		for i in range(len(s:left_delims))
-			exec "normal GGAOpen & close: " . s:left_delims[i]	. s:right_delims[i] . "|"
-			exec "normal A\<CR>Delete: " . s:left_delims[i] . s:right_delims[i] . "\<BS>|"
-			exec "normal A\<CR>Exit: " . s:left_delims[i] . s:right_delims[i] . s:right_delims[i] . "|"
-			exec "normal A\<CR>Space: " . s:left_delims[i] . s:right_delims[i] . " |"
-			exec "normal GGA\<CR>Visual-L: v\<Esc>v" . s:visual_leader . s:left_delims[i]
-			exec "normal A\<CR>Visual-R: v\<Esc>v" . s:visual_leader . s:right_delims[i]
-			exec "normal A\<CR>Car return: " . s:left_delims[i] . s:right_delims[i] . "\<CR>|\<Esc>GGA\<CR>\<CR>"
-		endfor
-		for i in range(len(s:quotes))
-			exec "normal GGAOpen & close: " . s:quotes[i]	. s:quotes[i] . "|"
-			exec "normal A\<CR>Delete: " . s:quotes[i] . s:quotes[i] . "\<BS>|"
-			exec "normal A\<CR>Exit: " . s:quotes[i] . s:quotes[i] . s:quotes[i] . "|"
-			exec "normal A\<CR>Space: " . s:quotes[i] . s:quotes[i] . " |"
-			exec "normal GGA\<CR>Visual: v\<Esc>v" . s:visual_leader . s:quotes[i]
-			exec "normal A\<CR>Car return: " . s:quotes[i] . s:quotes[i] . "\<CR>|\<Esc>GGA\<CR>\<CR>"
-		endfor
-	endif
-	exec "normal \<Esc>i"
-endfunction "}}}1
-
-function! s:SwitchAutoclose() "{{{1
-	if !exists("g:delimitMate_autoclose")
-		let g:delimitMate_autoclose = 1
-	elseif g:delimitMate_autoclose == 1
-		let g:delimitMate_autoclose = 0
-	else
-		let g:delimitMate_autoclose = 1
-	endif
-	DelimitMateReload
-endfunction "}}}1
-
-function! s:UnMap() " {{{
-	" No Autoclose Mappings:
-	for char in s:right_delims + s:quotes
-		if maparg(char,"i") =~? 'SkipDelim'
-			exec 'iunmap <buffer> ' . char
-			"echomsg 'iunmap <buffer> ' . char
-		endif
-	endfor
-
-	" Autoclose Mappings:
-	let s:i = 0
-	while s:i < len(s:matchpairs)
-		if maparg(s:left_delims[s:i],"i") =~? s:left_delims[s:i] . s:right_delims[s:i] . '<Left>'
-			exec 'iunmap <buffer> ' . s:left_delims[s:i]
-			"echomsg 'iunmap <buffer> ' . s:left_delims[s:i]
-		endif
-		let s:i += 1
-	endwhile
-	for char in s:quotes
-		if maparg(char, "i") =~? 'QuoteDelim'
-			exec 'iunmap <buffer> ' . char
-			"echomsg 'iunmap <buffer> ' . char
-		endif
-	endfor
-	for char in s:right_delims
-		if maparg(char, "i") =~? 'ClosePair'
-			exec 'iunmap <buffer> ' . char
-			"echomsg 'iunmap <buffer> ' . char
-		endif
-	endfor
-	for map in s:apostrophes
-		exec "silent! iunmap <buffer> " . map
-	endfor
-
-	" Visual Mappings:
-	for char in s:right_delims + s:left_delims + s:quotes
-		if maparg(s:visual_leader . char,"v") =~? 'IsBlock'
-			exec 'vunmap <buffer> ' . s:visual_leader . char
-			"echomsg 'vunmap <buffer> ' . s:visual_leader . char
-		endif
-	endfor
-
-	" Expansion Mappings:
-	if maparg('<BS>', "i") =~? 'WithinEmptyPair'
-		iunmap <buffer> <BS>
-		"echomsg "iunmap <buffer> <BS>"
-	endif
-	if maparg('<CR>',"i") =~? 'ExpandReturn'
-		iunmap <buffer> <CR>
-		"echomsg "iunmap <buffer> <CR>"
-	endif
-	if maparg('<Space>',"i") =~? 'ExpandSpace'
-		iunmap <buffer> <Space>
-		"echomsg "iunmap <buffer> <Space>"
-	endif
-
-endfunction " }}}
-
-function! s:TestMappingsDo() "{{{1
-	if !exists("g:delimitMate_testing")
-		call s:DelimitMateDo()
-		call s:TestMappings()
-	else
-		call s:SwitchAutoclose()
-		call s:TestMappings()
-		exec "normal i\<CR>"
-		call s:SwitchAutoclose()
-		call s:TestMappings()
-	endif
-endfunction "}}}1
-
-function! s:DelimitMateDo() "{{{1
-	if exists("g:delimitMate_excluded_ft")
-		" Check if this file type is excluded:
-		for ft in split(g:delimitMate_excluded_ft,',')
-			if ft ==? &filetype
-				if !exists("s:quotes")
-					return 1
-				endif
-				"echomsg "excluded"
-				call s:UnMap()
-				return 1
-			endif
-		endfor
-	endif
-	try
-		"echomsg "included"
-		let save_cpo = &cpo
-		set cpo&vim
-		call s:Init()
-	finally
-		let &cpo = save_cpo
-	endtry
-endfunction "}}}1
-
-" Set some commands: {{{1
-call s:DelimitMateDo()
-
-" Let me refresh without re-loading the buffer:
-command! DelimitMateReload call s:DelimitMateDo()
-
-" Quick test:
-command! DelimitMateTest call s:TestMappingsDo()
-
-" Run on file type events.
-"autocmd VimEnter * autocmd FileType * call <SID>DelimitMateDo()
-autocmd FileType * call <SID>DelimitMateDo()
-
-" Run on new buffers.
-autocmd BufNewFile,BufRead,BufEnter * if !exists("b:loaded_delimitMate") | call <SID>DelimitMateDo() | endif
-
-"function! s:GetSynRegion () | echo synIDattr(synIDtrans(synID(line('.'), col('.'), 1)), 'name') | endfunction
-
-" GetLatestVimScripts: 2754 1 :AutoInstall: delimitMate.vim
-" vim:foldmethod=marker:foldcolumn=2

doc/delimitMate.txt

@@ -0,0 +1,945 @@
+*delimitMate.txt*   Trying to keep those beasts at bay! v2.7     *delimitMate*
+
+
+
+  MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
+  MMMM  MMMMMMMMM  MMMMMMMMMMMMMMMMMMMMMMMMMM  MMMMM  MMMMMMMMMMMMMMMMMMMMM  ~
+  MMMM  MMMMMMMMM  MMMMMMMMMMMMMMMMMMMMMMMMMM   MMM   MMMMMMMMMMMMMMMMMMMMM
+  MMMM  MMMMMMMMM  MMMMMMMMMMMMMMMMMMMMM  MMM  M   M  MMMMMMMMMM  MMMMMMMMM  ~
+  MMMM  MMM   MMM  MM  MM  M  M MMM  MM    MM  MM MM  MMM   MMM    MMM   MM
+  MM    MM  M  MM  MMMMMM        MMMMMMM  MMM  MMMMM  MM  M  MMM  MMM  M  M  ~
+  M  M  MM     MM  MM  MM  M  M  MM  MMM  MMM  MMMMM  MMMMM  MMM  MMM     M
+  M  M  MM  MMMMM  MM  MM  M  M  MM  MMM  MMM  MMMMM  MMM    MMM  MMM  MMMM  ~
+  M  M  MM  M  MM  MM  MM  M  M  MM  MMM  MMM  MMMMM  MM  M  MMM  MMM  M  M
+  MM    MMM   MMM  MM  MM  M  M  MM  MMM   MM  MMMMM  MMM    MMM   MMM   MM  ~
+  MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
+
+
+
+==============================================================================
+ 0.- CONTENTS                                           *delimitMate-contents*
+
+    1. Introduction____________________________|delimitMateIntro|
+    2. Customization___________________________|delimitMateOptions|
+        2.1 Options summary____________________|delimitMateOptionSummary|
+        2.2 Options details____________________|delimitMateOptionDetails|
+    3. Functionality___________________________|delimitMateFunctionality|
+        3.1 Automatic closing & exiting________|delimitMateAutoClose|
+        3.2 Expansion of space and CR__________|delimitMateExpansion|
+        3.3 Backspace__________________________|delimitMateBackspace|
+        3.4 Smart Quotes_______________________|delimitMateSmartQuotes|
+        3.5 Balancing matching pairs___________|delimitMateBalance|
+        3.6 FileType based configuration_______|delimitMateFileType|
+        3.7 Syntax awareness___________________|delimitMateSyntax|
+    4. Commands________________________________|delimitMateCommands|
+    5. Mappings________________________________|delimitMateMappings|
+    6. Functions_______________________________|delimitMateFunctions|
+    7. Autocommands____________________________|delimitMateAutocmds|
+    8. TODO list_______________________________|delimitMateTodo|
+    9. Maintainer______________________________|delimitMateMaintainer|
+   10. Credits_________________________________|delimitMateCredits|
+   11. History_________________________________|delimitMateHistory|
+
+==============================================================================
+ 1.- INTRODUCTION                                           *delimitMateIntro*
+
+This plug-in provides automatic closing of quotes, parenthesis, brackets,
+etc.; besides some other related features that should make your time in insert
+mode a little bit easier.
+
+Most of the features can be modified or disabled permanently, using global
+variables, or on a FileType basis, using autocommands.
+
+NOTE 1: If you have any trouble with this plugin, please run |:DelimitMateTest|
+in a new buffer to see what is not working.
+
+NOTE 2: Abbreviations set with |:iabbrev| will not be expanded by delimiters
+used on delimitMate, you should use <C-]> (read |i_CTRL-]|) to expand them on
+the go.
+
+==============================================================================
+ 2. CUSTOMIZATION                                         *delimitMateOptions*
+
+You can create your own mappings for some features using the global functions.
+Read |delimitMateFunctions| for more info.
+
+------------------------------------------------------------------------------
+   2.1 OPTIONS SUMMARY                              *delimitMateOptionSummary*
+
+The behaviour of this script can be customized setting the following options
+in your vimrc file. You can use local options to set the configuration for
+specific file types, see |delimitMateOptionDetails| for examples.
+
+|'loaded_delimitMate'|            Turns off the script.
+
+|'delimitMate_autoclose'|         Tells delimitMate whether to automagically
+                                insert the closing delimiter.
+
+|'delimitMate_matchpairs'|        Tells delimitMate which characters are
+                                matching pairs.
+
+|'delimitMate_quotes'|            Tells delimitMate which quotes should be
+                                used.
+
+|'delimitMate_nesting_quotes'|    Tells delimitMate which quotes should be
+                                allowed to be nested.
+
+|'delimitMate_expand_cr'|         Turns on/off the expansion of <CR>.
+
+|'delimitMate_expand_space'|      Turns on/off the expansion of <Space>.
+
+|'delimitMate_jump_expansion'|    Turns on/off jumping over expansions.
+
+|'delimitMate_smart_quotes'|      Turns on/off the "smart quotes" feature.
+
+|'delimitMate_smart_matchpairs'|  Turns on/off the "smart matchpairs" feature.
+
+|'delimitMate_balance_matchpairs'|Turns on/off the "balance matching pairs"
+                                feature.
+
+|'delimitMate_excluded_regions'|  Turns off the script for the given regions or
+                                syntax group names.
+
+|'delimitMate_excluded_ft'|       Turns off the script for the given file types.
+
+|'delimitMate_eol_marker'|        Determines what to insert after the closing
+                                matchpair when typing an opening matchpair on
+                                the end of the line.
+
+|'delimitMate_apostrophes'|       Tells delimitMate how it should "fix"
+                                balancing of single quotes when used as
+                                apostrophes. NOTE: Not needed any more, kept
+                                for compatibility with older versions.
+
+------------------------------------------------------------------------------
+   2.2 OPTIONS DETAILS                              *delimitMateOptionDetails*
+
+Add the shown lines to your vimrc file in order to set the below options.
+Buffer variables take precedence over global ones and can be used along with
+autocmd to modify delimitMate's behavior for specific file types, read more in
+|delimitMateFileType|.
+
+Note: Use buffer variables only to set options for specific file types using
+:autocmd, use global variables to set options for all buffers. Read more in
+|g:var| and |b:var|.
+
+------------------------------------------------------------------------------
+                                                        *'loaded_delimitMate'*
+                                                      *'b:loaded_delimitMate'*
+This option prevents delimitMate from loading.
+e.g.: >
+        let loaded_delimitMate = 1
+        au FileType mail let b:loaded_delimitMate = 1
+<
+------------------------------------------------------------------------------
+                                                  *'delimitMate_offByDefault'*
+Values: 0 or 1.~
+Default: 0~
+
+If this option is set to 1, delimitMate will load, but will not take
+effect in any buffer unless |:DelimitMateSwitch| is called in that
+buffer.
+
+------------------------------------------------------------------------------
+                                                     *'delimitMate_autoclose'*
+                                                   *'b:delimitMate_autoclose'*
+Values: 0 or 1.                                                              ~
+Default: 1                                                                   ~
+
+If this option is set to 0, delimitMate will not add a closing delimiter
+automagically. See |delimitMateAutoClose| for details.
+e.g.: >
+        let delimitMate_autoclose = 0
+        au FileType mail let b:delimitMate_autoclose = 0
+<
+------------------------------------------------------------------------------
+                                                    *'delimitMate_matchpairs'*
+                                                  *'b:delimitMate_matchpairs'*
+Values: A string with |'matchpairs'| syntax, plus support for multi-byte~
+        characters.~
+Default: &matchpairs                                                         ~
+
+Use this option to tell delimitMate which characters should be considered
+matching pairs. Read |delimitMateAutoClose| for details.
+e.g: >
+        let delimitMate_matchpairs = "(:),[:],{:},<:>"
+        au FileType vim,html let b:delimitMate_matchpairs = "(:),[:],{:},<:>"
+<
+------------------------------------------------------------------------------
+                                                        *'delimitMate_quotes'*
+                                                      *'b:delimitMate_quotes'*
+Values: A string of characters separated by spaces.                          ~
+Default: "\" ' `"                                                            ~
+
+Use this option to tell delimitMate which characters should be considered as
+quotes. Read |delimitMateAutoClose| for details.
+e.g.: >
+        let delimitMate_quotes = "\" ' ` *"
+        au FileType html let b:delimitMate_quotes = "\" '"
+<
+------------------------------------------------------------------------------
+                                                *'delimitMate_nesting_quotes'*
+                                              *'b:delimitMate_nesting_quotes'*
+Values: A list of quotes.                                                    ~
+Default: []                                                                  ~
+
+When adding a third quote listed in this option is inserted, three quotes will
+be inserted to the right of the cursor and the cursor will stay in the middle.
+If more quotes are inserted the number of quotes on both sides of the cursor
+will stay balanced.
+e.g.: >
+        let delimitMate_nesting_quotes = ['"','`']
+        au FileType python let b:delimitMate_nesting_quotes = ['"']
+<
+For Python this is set by default by the plugin.
+
+------------------------------------------------------------------------------
+                                                     *'delimitMate_expand_cr'*
+                                                   *'b:delimitMate_expand_cr'*
+Values: 0, 1 or 2                                                             ~
+Default: 0                                                                   ~
+
+This option turns on/off the expansion of <CR>. Read |delimitMateExpansion|
+for details. NOTE This feature requires that 'backspace' is either set to 2 or
+has "eol" and "start" as part of its value.
+e.g.: >
+        let delimitMate_expand_cr = 1
+        au FileType mail let b:delimitMate_expand_cr = 1
+<
+------------------------------------------------------------------------------
+                                                  *'delimitMate_expand_space'*
+                                                *'b:delimitMate_expand_space'*
+Values: 1 or 0                                                               ~
+Default: 0                                                                   ~
+This option turns on/off the expansion of <Space>. Read |delimitMateExpansion|
+for details.
+e.g.: >
+        let delimitMate_expand_space = 1
+        au FileType tcl let b:delimitMate_expand_space = 1
+<
+------------------------------------------------------------------------------
+                                          *'delimitMate_expand_inside_quotes'*
+                                        *'b:delimitMate_expand_inside_quotes'*
+Values: 1 or 0                                                                ~
+Default: 0                                                                   ~
+When this option is set to 1 the expansion of space and cr will also be
+applied to quotes. Read |delimitMateExpansion| for details.
+
+e.g.: >
+        let delimitMate_expand_inside_quotes = 1
+        au FileType mail let b:delimitMate_expand_inside_quotes = 1
+<
+------------------------------------------------------------------------------
+                                                *'delimitMate_jump_expansion'*
+                                              *'b:delimitMate_jump_expansion'*
+Values: 1 or 0                                                               ~
+Default: 0                                                                   ~
+This option turns on/off the jumping over <CR> and <Space> expansions when
+inserting closing matchpairs. Read |delimitMateExpansion| for details.
+e.g.: >
+        let delimitMate_jump_expansion = 1
+        au FileType tcl let b:delimitMate_jump_expansion = 1
+<
+------------------------------------------------------------------------------
+                                                  *'delimitMate_smart_quotes'*
+                                                *'b:delimitMate_smart_quotes'*
+Values: String with an optional !  at the beginning followed by a regexp     ~
+Default:~
+'\%(\w\|[^[:punct:][:space:]]\|\%(\\\\\)*\\\)\%#\|\%#\%(\w\|[^[:space:][:punct:]]\)'                  ~
+
+A bang (!) at the beginning is removed and used to "negate" the pattern. The
+remaining text is used as a regexp to be matched on the current line. A single
+quote is inserted when the pattern matches and a bang is not present. The bang
+changes that, so a single quote is inserted only if the regexp does not match.
+
+This feature is disabled when the variable is set to an empty string, with the
+exception of apostrophes.
+
+Note that you need to use '\%#' to match the position of the cursor.  Keep in
+mind that '\%#' matches with zero width, so if you need to match the char
+under the cursor (which would be the one to the right on insert mode) use
+something like '\%#.'.
+
+e.g.: >
+        let delimitMate_smart_quotes = '\w\%#'
+        au FileType tcl let b:delimitMate_smart_quotes = '!\s\%#\w'
+<
+------------------------------------------------------------------------------
+                                              *'delimitMate_smart_matchpairs'*
+                                            *'b:delimitMate_smart_matchpairs'*
+Values: Regexp                                                               ~
+Default: '^\%(\w\|\!\|[£$]\|[^[:space:][:punct:]]\)'                                ~
+
+This regex is matched against the text to the right of cursor, if it's not
+empty and there is a match delimitMate will not autoclose the pair. At the
+moment to match the text, an escaped bang (\!) in the regex will be replaced
+by the character being inserted, while an escaped number symbol (\#) will be
+replaced by the closing pair.
+e.g.: >
+        let delimitMate_smart_matchpairs = ''
+        au FileType tcl let b:delimitMate_smart_matchpairs = '^\%(\w\|\$\)'
+<
+------------------------------------------------------------------------------
+                                            *'delimitMate_balance_matchpairs'*
+                                          *'b:delimitMate_balance_matchpairs'*
+Values: 1 or 0                                                               ~
+Default: 0                                                                   ~
+
+This option turns on/off the balancing of matching pairs. Read
+|delimitMateBalance| for details.
+e.g.: >
+        let delimitMate_balance_matchpairs = 1
+        au FileType tcl let b:delimitMate_balance_matchpairs = 1
+<
+------------------------------------------------------------------------------
+                                              *'delimitMate_excluded_regions'*
+Values: A string of syntax group names names separated by single commas.     ~
+Default: Comment                                                             ~
+
+This options turns delimitMate off for the listed regions, read |group-name|
+for more info about what is a region.
+e.g.: >
+        let delimitMate_excluded_regions = "Comment,String"
+<
+------------------------------------------------------------------------------
+                                                   *'delimitMate_excluded_ft'*
+Values: A string of file type names separated by single commas.              ~
+Default: Empty.                                                              ~
+
+This options turns delimitMate off for the listed file types, use this option
+only if you don't want any of the features it provides on those file types.
+e.g.: >
+        let delimitMate_excluded_ft = "mail,txt"
+<
+------------------------------------------------------------------------------
+                                             *'delimitMate_insert_eol_marker'*
+Values: Integer                                                              ~
+Default: 1                                                              ~
+
+Whether to insert the eol marker (EM) or not. The EM is inserted following
+rules:
+
+0 -> never
+1 -> when inserting any matchpair
+2 -> when expanding car return in matchpair
+
+e.g.: >
+        au FileType c,perl let b:delimitMate_insert_eol_marker = 2
+<
+------------------------------------------------------------------------------
+                                                    *'delimitMate_eol_marker'*
+Values: String.                                                              ~
+Default: Empty.                                                              ~
+
+The contents of this string will be inserted after the closing matchpair or
+quote when the respective opening matchpair or quote is inserted at the end
+of the line.
+e.g.: >
+        au FileType c,perl let b:delimitMate_eol_marker = ";"
+<
+------------------------------------------------------------------------------
+                                                   *'delimitMate_apostrophes'*
+Values: Strings separated by ":".                                            ~
+Default: No longer used.                                                     ~
+
+NOTE: This feature is turned off by default, it's been kept for compatibility
+with older version, read |delimitMateSmartQuotes| for details.
+If auto-close is enabled, this option tells delimitMate how to try to fix the
+balancing of single quotes when used as apostrophes. The values of this option
+are strings of text where a single quote would be used as an apostrophe (e.g.:
+the "n't" of wouldn't or can't) separated by ":". Set it to an empty string to
+disable this feature.
+e.g.: >
+        let delimitMate_apostrophes = ""
+        au FileType tcl let delimitMate_apostrophes = ""
+<
+==============================================================================
+ 3. FUNCTIONALITY                                   *delimitMateFunctionality*
+
+------------------------------------------------------------------------------
+   3.1 AUTOMATIC CLOSING AND EXITING                    *delimitMateAutoClose*
+
+With automatic closing enabled, if an opening delimiter is inserted the plugin
+inserts the closing delimiter and places the cursor between the pair. With
+automatic closing disabled, no closing delimiters is inserted by delimitMate,
+but when a pair of delimiters is typed, the cursor is placed in the middle.
+
+When the cursor is inside an empty pair or located next to the left of a
+closing delimiter, the cursor is placed outside the pair to the right of the
+closing delimiter.
+
+When |'delimitMate_smart_matchpairs'| is not empty and it matches the text to
+the right of the cursor, delimitMate will not automatically insert the closing
+pair.
+
+Unless |'delimitMate_matchpairs'| or |'delimitMate_quotes'| are set, this
+script uses the values in '&matchpairs' to identify the pairs, and ", ' and `
+for quotes respectively.
+
+<S-Tab> will jump over a single closing delimiter or quote, <C-G>g will jump
+over contiguous delimiters and/or quotes.
+
+The following table shows the behaviour, this applies to quotes too (the final
+position of the cursor is represented by a "|"):
+
+With auto-close: >
+                          Type     |  You get
+                        =======================
+                           (       |    (|)
+                        -----------|-----------
+                           ()      |    ()|
+                        -----------|-----------
+                        (<S-Tab>   |    ()|
+                        -----------|-----------
+                        {("<C-G>g  |  {("")}|
+<
+Without auto-close: >
+
+                          Type        |  You get
+                        =========================
+                           ()         |    (|)
+                        --------------|----------
+                           ())        |    ()|
+                        --------------|----------
+                        ()<S-Tab>     |    ()|
+                        --------------|----------
+                        {}()""<C-G>g  |  {("")}|
+<
+NOTE: Abbreviations will not be expanded by delimiters used on delimitMate,
+you should use <C-]> (read |i_CTRL-]|) to expand them on the go.
+
+------------------------------------------------------------------------------
+   3.2 EXPANSION OF SPACE AND CAR RETURN                *delimitMateExpansion*
+
+When the cursor is inside an empty pair of any matchpair, <Space> and <CR> can be
+expanded, see |'delimitMate_expand_space'| and
+|'delimitMate_expand_cr'|:
+
+Expand <Space> to: >
+
+                    You start with  |  You get
+                  ==============================
+                        (|)         |    ( | )
+<
+Expand <CR> to: >
+
+                   You start with   |  You get
+                  ==============================
+                        (|)         |    (
+                                    |      |
+                                    |    )
+<
+
+When you have |'delimitMate_jump_expansion'| enabled, if there is an existing
+closing paren/bracket/etc. on the next line, delimitMate will make the cursor
+jump over any whitespace/<CR> and place it after the existing closing
+delimiter instead of inserting a new one.
+
+When |'delimitMate_expand_cr'| is set to 2, the following will also happen: >
+
+                    You start with  |  You get
+                  ==============================
+                       (foo|)       |    (foo
+                                    |      |
+                                    |    )
+<
+
+Since <Space> and <CR> are used everywhere, I have made the functions involved
+in expansions global, so they can be used to make custom mappings. Read
+|delimitMateFunctions| for more details.
+
+------------------------------------------------------------------------------
+   3.3 BACKSPACE                                        *delimitMateBackspace*
+
+If you press backspace inside an empty pair, both delimiters are deleted. When
+expansions are enabled, <BS> will also delete the expansions.
+
+If you type <S-BS> (shift + backspace) instead, only the closing delimiter
+will be deleted. NOTE that this will not usually work when using Vim from the
+terminal, see 'delimitMate#JumpAny()' below to see how to fix it.
+
+e.g. typing at the "|": >
+
+                  What  |      Before       |      After
+               ==============================================
+                  <BS>  |  call expand(|)   |  call expand|
+               ---------|-------------------|-----------------
+                  <BS>  |  call expand( | ) |  call expand(|)
+               ---------|-------------------|-----------------
+                  <BS>  |  call expand(     |  call expand(|)
+                        |  |                |
+                        |  )                |
+               ---------|-------------------|-----------------
+                 <S-BS> |  call expand(|)   |  call expand(|
+<
+
+------------------------------------------------------------------------------
+   3.4 SMART QUOTES                                   *delimitMateSmartQuotes*
+
+Only one quote will be inserted following a quote, a "\", following or
+preceding a keyword character, or when the number of quotes in the current
+line is odd. This should cover closing quotes after a string, opening quotes
+before a string, escaped quotes and apostrophes. See more details about
+customizing this feature on |'delimitMate_smart_quotes'|.
+
+e.g. typing at the "|": >
+
+                     What |    Before    |     After
+                  =======================================
+                      "   |  Text |      |  Text "|"
+                      "   |  "String|    |  "String"|
+                      "   |  let i = "|  |  let i = "|"
+                      'm  |  I|          |  I'm|
+<
+------------------------------------------------------------------------------
+   3.4 SMART MATCHPAIRS                           *delimitMateSmartMatchpairs*
+
+This is similar to "smart quotes", but applied to the characters in
+|'delimitMate_matchpairs'|. The difference is that delimitMate will not
+auto-close the pair when the regex matches the text on the right of the
+cursor. See |'delimitMate_smart_matchpairs'| for more details.
+
+
+e.g. typing at the "|": >
+
+                     What |    Before    |     After
+                  =======================================
+                      (   |  function|   |  function(|)
+                      (   |  |var        |  (|var
+<
+------------------------------------------------------------------------------
+   3.5 BALANCING MATCHING PAIRS                           *delimitMateBalance*
+
+When inserting an opening paren and |'delimitMate_balance_matchpairs'| is
+enabled, delimitMate will try to balance the closing pairs in the current
+line.
+
+e.g. typing at the "|": >
+
+                     What |    Before    |     After
+                  =======================================
+                      (   |      |       |     (|)
+                      (   |      |)      |     (|)
+                      ((  |      |)      |    ((|))
+<
+------------------------------------------------------------------------------
+   3.6 FILE TYPE BASED CONFIGURATION                     *delimitMateFileType*
+
+delimitMate options can be set globally for all buffers using global
+("regular") variables in your |vimrc| file. But |:autocmd| can be used to set
+options for specific file types (see |'filetype'|) using buffer variables in
+the following way: >
+
+   au FileType mail,text let b:delimitMate_autoclose = 0
+         ^       ^           ^            ^            ^
+         |       |           |            |            |
+         |       |           |            |            - Option value.
+         |       |           |            - Option name.
+         |       |           - Buffer variable.
+         |       - File types for which the option will be set.
+         - Don't forget to put this event.
+<
+NOTE that you should use buffer variables (|b:var|) only to set options with
+|:autocmd|, for global options use regular variables (|g:var|) in your vimrc.
+
+------------------------------------------------------------------------------
+   3.7 SYNTAX AWARENESS                                    *delimitMateSyntax*
+
+The features of this plug-in might not be always helpful, comments and strings
+usualy don't need auto-completion. delimitMate monitors which region is being
+edited and if it detects that the cursor is in a comment it'll turn itself off
+until the cursor leaves the comment. The excluded regions can be set using the
+option |'delimitMate_excluded_regions'|. Read |group-name| for a list of
+regions or syntax group names.
+
+NOTE that this feature relies on a proper syntax file for the current file
+type, if the appropiate syntax file doesn't define a region, delimitMate won't
+know about it.
+
+==============================================================================
+ 4. COMMANDS                                             *delimitMateCommands*
+
+------------------------------------------------------------------------------
+:DelimitMateReload                                        *:DelimitMateReload*
+
+Re-sets all the mappings used for this script, use it if any option has been
+changed or if the filetype option hasn't been set yet.
+
+------------------------------------------------------------------------------
+:DelimitMateOn                                                *:DelimitMateOn*
+
+Enable delimitMate mappings.
+
+------------------------------------------------------------------------------
+:DelimitMateOff                                              *:DelimitMateOff*
+
+Disable delimitMate mappings.
+
+------------------------------------------------------------------------------
+:DelimitMateSwitch                                        *:DelimitMateSwitch*
+
+Switches the plug-in on and off.
+
+------------------------------------------------------------------------------
+:DelimitMateTest                                            *:DelimitMateTest*
+
+This command tests every mapping set-up for this script, useful for testing
+custom configurations.
+
+The following output corresponds to the default values, it will be different
+depending on your configuration. "Open & close:" represents the final result
+when the closing delimiter has been inserted, either manually or
+automatically, see |delimitMateExpansion|. "Delete:" typing backspace in an
+empty pair, see |delimitMateBackspace|. "Exit:" typing a closing delimiter
+inside a pair of delimiters, see |delimitMateAutoclose|. "Space:" the
+expansion, if any, of space, see |delimitMateExpansion|. "Visual-L",
+"Visual-R" and "Visual" shows visual wrapping, see
+|delimitMateVisualWrapping|. "Car return:" the expansion of car return, see
+|delimitMateExpansion|. The cursor's position at the end of every test is
+represented by an "|": >
+
+            * AUTOCLOSE:
+            Open & close: (|)
+            Delete: |
+            Exit: ()|
+            Space: ( |)
+            Visual-L: (v)
+            Visual-R: (v)
+            Car return: (
+            |)
+
+            Open & close: {|}
+            Delete: |
+            Exit: {}|
+            Space: { |}
+            Visual-L: {v}
+            Visual-R: {v}
+            Car return: {
+            |}
+
+            Open & close: [|]
+            Delete: |
+            Exit: []|
+            Space: [ |]
+            Visual-L: [v]
+            Visual-R: [v]
+            Car return: [
+            |]
+
+            Open & close: "|"
+            Delete: |
+            Exit: ""|
+            Space: " |"
+            Visual: "v"
+            Car return: "
+            |"
+
+            Open & close: '|'
+            Delete: |
+            Exit: ''|
+            Space: ' |'
+            Visual: 'v'
+            Car return: '
+            |'
+
+            Open & close: `|`
+            Delete: |
+            Exit: ``|
+            Space: ` |`
+            Visual: `v`
+            Car return: `
+            |`
+<
+
+==============================================================================
+ 5. MAPPINGS                                             *delimitMateMappings*
+
+delimitMate doesn't override any existing map, so you may encounter that it
+doesn't work as expected because a mapping is missing. In that case, the
+conflicting mappings should be resolved by either disabling the conflicting
+mapping or creating a custom mappings.
+
+In order to make custom mappings easier and prevent overwritting existing
+ones, delimitMate uses the |<Plug>| + |hasmapto()| (|usr_41.txt|) construct
+for its mappings.
+
+These are the default mappings for the extra features:
+
+<BS>         is mapped to <Plug>delimitMateBS
+<S-BS>       is mapped to <Plug>delimitMateS-BS
+<S-Tab>      is mapped to <Plug>delimitMateS-Tab
+<C-G>g       is mapped to <Plug>delimitMateJumpMany
+
+The rest of the mappings correspond to parens, quotes, CR, Space, etc. and they
+depend on the values of the delimitMate options, they have the following form:
+
+<Plug>delimitMate + char
+
+e.g.: for "(":
+
+( is mapped to <Plug>delimitMate(
+
+e.g.: If you have <CR> expansion enabled, you might want to skip it on pop-up
+menus:
+
+    imap <expr> <CR> pumvisible()
+                     \ ? "\<C-Y>"
+                     \ : "<Plug>delimitMateCR"
+
+
+==============================================================================
+ 6. FUNCTIONS                                           *delimitMateFunctions*
+
+------------------------------------------------------------------------------
+delimitMate#WithinEmptyPair()                  *delimitMate#WithinEmptyPair()*
+
+Returns 1 if the cursor is inside an empty pair, 0 otherwise.
+e.g.: >
+
+    inoremap <expr> <CR> delimitMate#WithinEmptyPair() ?
+             \ "<Plug>delimitMateCR" :
+             \ "external_mapping"
+<
+
+------------------------------------------------------------------------------
+delimitMate#ShouldJump()                            *delimitMate#ShouldJump()*
+
+Returns 1 if there is a closing delimiter or a quote to the right of the
+cursor, 0 otherwise.
+
+------------------------------------------------------------------------------
+delimitMate#JumpAny()                               *delimitMate#JumpAny()*
+
+This function returns a mapping that will make the cursor jump to the right
+when delimitMate#ShouldJump() returns 1, returns the argument "key" otherwise.
+e.g.: You can use this to create your own mapping to jump over any delimiter.
+>
+   inoremap <expr> <C-Tab> delimitMate#JumpAny()
+<
+==============================================================================
+ 7. AUTOCOMMANDS                                         *delimitMateAutocmds*
+
+delimitMate emits 2 |User| autocommands to make it easier for users to
+leverage delimitMate's support for per-filetype customization.
+
+------------------------------------------------------------------------------
+delimitMate_map                                              *delimitMate_map*
+
+This |User| event is emittted just prior to delimitMate defining its
+buffer-local key mappings. You can use this command to define your own
+mappings that are disabled when delimitMate is turned off or excludes the
+current filetype.
+>
+    au User delimitMate_map call s:delimitMate_map()
+    function s:delimitMate_map()
+        imap <buffer><expr> <C-Tab> delimitMate#JumpAny()
+    endfunction
+<
+------------------------------------------------------------------------------
+delimitMate_unmap                                          *delimitMate_unmap*
+
+This |User| event is emitted just after delimitMate clears its buffer-local
+key mappings. You can use this command to clear your own mappings that you set
+in response to |delimitMate_map|.
+>
+    au User delimitMate_unmap call s:delimitMate_unmap()
+    function s:delimitMate_unmap()
+        silent! iunmap <buffer> <C-Tab>
+    endfunction
+<
+Note: This event may be emitted before |delimitMate_map|, and may be emitted
+multiple times in a row without any intervening |delimitMate_map| events.
+
+==============================================================================
+ 8. TODO LIST                                                *delimitMateTodo*
+
+- Automatic set-up by file type.
+- Make block-wise visual wrapping work on un-even regions.
+
+==============================================================================
+ 9. MAINTAINER                                         *delimitMateMaintainer*
+
+Hi there! My name is Israel Chauca F. and I can be reached at:
+    mailto:israelchauca@gmail.com
+
+Feel free to send me any suggestions and/or comments about this plugin, I'll
+be very pleased to read them.
+
+==============================================================================
+ 10. CREDITS                                              *delimitMateCredits*
+
+Contributors: ~
+
+  - Kim Silkebækken                                                         ~
+    Fixed mappings being echoed in the terminal.
+
+  - Eric Van Dewoestine                                                     ~
+    Implemented smart matchpairs.
+
+Some of the code that makes this script was modified or just shamelessly
+copied from the following sources:
+
+  - Ian McCracken                                                          ~
+    Post titled: Vim, Part II: Matching Pairs:
+    http://concisionandconcinnity.blogspot.com/
+
+  - Aristotle Pagaltzis                                                    ~
+    From the comments on the previous blog post and from:
+    http://gist.github.com/144619
+
+  - Karl Guertin                                                           ~
+    AutoClose:
+    http://www.vim.org/scripts/script.php?script_id=1849
+
+  - Thiago Alves                                                           ~
+    AutoClose:
+    http://www.vim.org/scripts/script.php?script_id=2009
+
+  - Edoardo Vacchi                                                         ~
+    ClosePairs:
+    http://www.vim.org/scripts/script.php?script_id=2373
+
+This script was inspired by the auto-completion of delimiters on TextMate.
+
+==============================================================================
+ 11. HISTORY                                               *delimitMateHistory*
+
+  Version      Date      Release notes                                       ~
+|---------|------------|-----------------------------------------------------|
+    2.8     2013-07-15 * Current release:
+                         - Add :DelimitMateOn & :DelimitMateOff.
+|---------|------------|-----------------------------------------------------|
+    2.7     2013-07-15 * - Lots of bug fixes.
+                         - Add delimitMate_offByDefault.
+                         - Add delimitMate_eol_marker.
+                         - Reduce the number of mappings.
+                         - Stop using setline().
+                         - Better handling of nested quotes.
+                         - Allow a custom pattern for smart_quotes.
+|---------|------------|-----------------------------------------------------|
+    2.6     2011-01-14 * - Add smart_matchpairs feature.
+                         - Add mapping to jump over contiguous delimiters.
+                         - Fix behaviour of b:loaded_delimitMate.
+|---------|------------|-----------------------------------------------------|
+    2.5.1   2010-09-30 * - Remove visual wrapping. Surround.vim offers a much
+                           better implementation.
+                         - Minor mods to DelimitMateTest.
+|---------|------------|-----------------------------------------------------|
+    2.5     2010-09-22 * - Better handling of mappings.
+                         - Add report for mappings in |:DelimitMateTest|.
+                         - Allow the use of "|" and multi-byte characters in
+                           |'delimitMate_quotes'| and |'delimitMate_matchpairs'|.
+                         - Allow commands to be concatenated using |.
+|---------|------------|-----------------------------------------------------|
+    2.4.1   2010-07-31 * - Fix problem with <Home> and <End>.
+                         - Add missing doc on |'delimitMate_smart_quotes'|,
+                           |delimitMateBalance| and
+                           |'delimitMate_balance_matchpairs'|.
+|---------|------------|-----------------------------------------------------|
+    2.4     2010-07-29 * - Unbalanced parens: see :help delimitMateBalance.
+                         - Visual wrapping now works on block-wise visual
+                           with some limitations.
+                         - Arrow keys didn't work on terminal.
+                         - Added option to allow nested quotes.
+                         - Expand Smart Quotes to look for a string on the
+                           right of the cursor.
+
+|---------|------------|-----------------------------------------------------|
+    2.3.1   2010-06-06 * - Fix: an extra <Space> is inserted after <Space>
+                           expansion.
+
+|---------|------------|-----------------------------------------------------|
+    2.3     2010-06-06 * - Syntax aware: Will turn off when editing comments
+                           or other regions, customizable.
+                         - Changed format of most mappings.
+                         - Fix: <CR> expansion doesn't break automatic
+                           indentation adjustments anymore.
+                         - Fix: Arrow keys would insert A, B, C or D instead
+                           of moving the cursor when using Vim on a terminal.
+
+|---------|------------|-----------------------------------------------------|
+    2.2     2010-05-16 * - Added command to switch the plug-in on and off.
+                         - Fix: some problems with <Left>, <Right> and <CR>.
+                         - Fix: A small problem when inserting a delimiter at
+                           the beginning of the line.
+
+|---------|------------|-----------------------------------------------------|
+    2.1     2010-05-10 * - Most of the functions have been moved to an
+                           autoload script to avoid loading unnecessary ones.
+                         - Fixed a problem with the redo command.
+                         - Many small fixes.
+
+|---------|------------|-----------------------------------------------------|
+    2.0     2010-04-01 * New features:
+                         - All features are redo/undo-wise safe.
+                         - A single quote typed after an alphanumeric
+                           character is considered an apostrophe and one
+                           single quote is inserted.
+                         - A quote typed after another quote inserts a single
+                           quote and the cursor jumps to the middle.
+                         - <S-Tab> jumps out of any empty pair.
+                         - <CR> and <Space> expansions are fixed, but the
+                           functions used for it are global and can be used in
+                           custom mappings. The previous system is still
+                           active if you have any of the expansion options
+                           set.
+                         - <S-Backspace> deletes the closing delimiter.
+                         * Fixed bug:
+                         - s:vars were being used to store buffer options.
+
+|---------|------------|-----------------------------------------------------|
+    1.6     2009-10-10 * Now delimitMate tries to fix the balancing of single
+                         quotes when used as apostrophes. You can read
+                         |delimitMate_apostrophes| for details.
+                         Fixed an error when |b:delimitMate_expand_space|
+                         wasn't set but |delimitMate_expand_space| wasn't.
+
+|---------|------------|-----------------------------------------------------|
+    1.5     2009-10-05 * Fix: delimitMate should work correctly for files
+                         passed as arguments to Vim. Thanks to Ben Beuchler
+                         for helping to nail this bug.
+
+|---------|------------|-----------------------------------------------------|
+    1.4     2009-09-27 * Fix: delimitMate is now enabled on new buffers even
+                         if they don't have set the file type option or were
+                         opened directly from the terminal.
+
+|---------|------------|-----------------------------------------------------|
+    1.3     2009-09-24 * Now local options can be used along with autocmd
+                         for specific file type configurations.
+                         Fixes:
+                         - Unnamed register content is not lost on visual
+                         mode.
+                         - Use noremap where appropiate.
+                         - Wrapping a single empty line works as expected.
+
+|---------|------------|-----------------------------------------------------|
+    1.2     2009-09-07 * Fixes:
+                         - When inside nested empty pairs, deleting the
+                         innermost left delimiter would delete all right
+                         contiguous delimiters.
+                         - When inside an empty pair, inserting a left
+                         delimiter wouldn't insert the right one, instead
+                         the cursor would jump to the right.
+                         - New buffer inside the current window wouldn't
+                         have the mappings set.
+
+|---------|------------|-----------------------------------------------------|
+    1.1     2009-08-25 * Fixed an error that ocurred when mapleader wasn't
+                         set and added support for GetLatestScripts
+                         auto-detection.
+
+|---------|------------|-----------------------------------------------------|
+    1.0     2009-08-23 * Initial upload.
+
+|---------|------------|-----------------------------------------------------|
+
+
+  `\|||/´         MMM           \|/            www            __^__          ~
+   (o o)         (o o)          @ @           (O-O)          /(o o)\\        ~
+ooO_(_)_Ooo__ ooO_(_)_Ooo___oOO_(_)_OOo___oOO__(_)__OOo___oOO__(_)__OOo_____ ~
+_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|____ ~
+__|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_ ~
+_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|_____|____ ~
+
+vim:tw=78:et:ts=8:sw=2:ft=help:norl:formatoptions+=tcroqn:autoindent:

plugin/delimitMate.vim

@@ -0,0 +1,403 @@
+" File:        plugin/delimitMate.vim
+" Version:     2.7
+" Modified:    2013-07-15
+" Description: This plugin provides auto-completion for quotes, parens, etc.
+" Maintainer:  Israel Chauca F. <israelchauca@gmail.com>
+" Manual:      Read ":help delimitMate".
+" ============================================================================
+
+" Initialization: {{{
+
+if exists("g:loaded_delimitMate") || &cp
+  " User doesn't want this plugin or compatible is set, let's get out!
+  finish
+endif
+let g:loaded_delimitMate = 1
+let save_cpo = &cpo
+set cpo&vim
+
+if v:version < 700
+  echoerr "delimitMate: this plugin requires vim >= 7!"
+  finish
+endif
+
+let s:loaded_delimitMate = 1
+let delimitMate_version = "2.8"
+
+"}}}
+
+" Functions: {{{
+
+function! s:option_init(name, default) "{{{
+  let opt_name = "delimitMate_" . a:name
+  " Find value to use.
+  if !has_key(b:, opt_name) && !has_key(g:, opt_name)
+    let value = a:default
+  elseif has_key(b:, opt_name)
+    let value = b:[opt_name]
+  else
+    let value = g:[opt_name]
+  endif
+  call s:set(a:name, value)
+endfunction "}}}
+
+function! s:init() "{{{
+" Initialize variables:
+  " autoclose
+  call s:option_init("autoclose", 1)
+  " matchpairs
+  call s:option_init("matchpairs", string(&matchpairs)[1:-2])
+  call s:option_init("matchpairs_list", map(split(s:get('matchpairs', ''), '.:.\zs,\ze.:.'), 'split(v:val, ''^.\zs:\ze.$'')'))
+  let pairs = s:get('matchpairs_list', [])
+  if len(filter(pairs, 'v:val[0] ==# v:val[1]'))
+    echohl ErrorMsg
+    echom 'delimitMate: each member of a pair in delimitMate_matchpairs must be different from each other.'
+    echom 'delimitMate: invalid pairs: ' . join(map(pairs, 'join(v:val, ":")'), ', ')
+    echohl Normal
+    return 0
+  endif
+  call s:option_init("left_delims", map(copy(s:get('matchpairs_list', [])), 'v:val[0]'))
+  call s:option_init("right_delims", map(copy(s:get('matchpairs_list', [])), 'v:val[1]'))
+  " quotes
+  call s:option_init("quotes", "\" ' `")
+  call s:option_init("quotes_list",split(s:get('quotes', ''), '\s\+'))
+  " nesting_quotes
+  call s:option_init("nesting_quotes", [])
+  " excluded_regions
+  call s:option_init("excluded_regions", "Comment")
+  call s:option_init("excluded_regions_list", split(s:get('excluded_regions', ''), ',\s*'))
+  let enabled = len(s:get('excluded_regions_list', [])) > 0
+  call s:option_init("excluded_regions_enabled", enabled)
+  " expand_space
+  if exists("b:delimitMate_expand_space") && type(b:delimitMate_expand_space) == type("")
+    echom "b:delimitMate_expand_space is '".b:delimitMate_expand_space."' but it must be either 1 or 0!"
+    echom "Read :help 'delimitMate_expand_space' for more details."
+    unlet b:delimitMate_expand_space
+    let b:delimitMate_expand_space = 1
+  endif
+  if exists("g:delimitMate_expand_space") && type(g:delimitMate_expand_space) == type("")
+    echom "delimitMate_expand_space is '".g:delimitMate_expand_space."' but it must be either 1 or 0!"
+    echom "Read :help 'delimitMate_expand_space' for more details."
+    unlet g:delimitMate_expand_space
+    let g:delimitMate_expand_space = 1
+  endif
+  call s:option_init("expand_space", 0)
+  " expand_cr
+  if exists("b:delimitMate_expand_cr") && type(b:delimitMate_expand_cr) == type("")
+    echom "b:delimitMate_expand_cr is '".b:delimitMate_expand_cr."' but it must be either 1 or 0!"
+    echom "Read :help 'delimitMate_expand_cr' for more details."
+    unlet b:delimitMate_expand_cr
+    let b:delimitMate_expand_cr = 1
+  endif
+  if exists("g:delimitMate_expand_cr") && type(g:delimitMate_expand_cr) == type("")
+    echom "delimitMate_expand_cr is '".g:delimitMate_expand_cr."' but it must be either 1 or 0!"
+    echom "Read :help 'delimitMate_expand_cr' for more details."
+    unlet g:delimitMate_expand_cr
+    let g:delimitMate_expand_cr = 1
+  endif
+  if ((&backspace !~ 'eol' || &backspace !~ 'start') && &backspace != 2) &&
+        \ ((exists('b:delimitMate_expand_cr') && b:delimitMate_expand_cr == 1) ||
+        \ (exists('g:delimitMate_expand_cr') && g:delimitMate_expand_cr == 1))
+    echom "delimitMate: There seems to be some incompatibility with your settings that may interfer with the expansion of <CR>. See :help 'delimitMate_expand_cr' for details."
+  endif
+  call s:option_init("expand_cr", 0)
+  " expand_in_quotes
+  call s:option_init('expand_inside_quotes', 0)
+  " jump_expansion
+  call s:option_init("jump_expansion", 0)
+  " smart_matchpairs
+  call s:option_init("smart_matchpairs", '^\%(\w\|\!\|[£$]\|[^[:punct:][:space:]]\)')
+  " smart_quotes
+  " XXX: backward compatibility. Ugly, should go the way of the dodo soon.
+  let quotes = escape(join(s:get('quotes_list', []), ''), '\-^[]')
+  let default_smart_quotes = '\%(\w\|[^[:punct:][:space:]' . quotes . ']\|\%(\\\\\)*\\\)\%#\|\%#\%(\w\|[^[:space:][:punct:]' . quotes . ']\)'
+  if exists('g:delimitMate_smart_quotes') && type(g:delimitMate_smart_quotes) == type(0)
+    if g:delimitMate_smart_quotes
+      unlet g:delimitMate_smart_quotes
+    else
+      unlet g:delimitMate_smart_quotes
+      let g:delimitMate_smart_quotes = ''
+    endif
+  endif
+  if exists('b:delimitMate_smart_quotes') && type(b:delimitMate_smart_quotes) == type(0)
+    if b:delimitMate_smart_quotes
+      unlet b:delimitMate_smart_quotes
+      if exists('g:delimitMate_smart_quotes') && type(g:delimitMate_smart_quotes) && g:delimitMate_smart_quotes
+        let b:delimitMate_smart_quotes = default_smart_quotes
+      endif
+    else
+      unlet b:delimitMate_smart_quotes
+      let b:delimitMate_smart_quotes = ''
+    endif
+  endif
+  call s:option_init("smart_quotes", default_smart_quotes)
+  " apostrophes
+  call s:option_init("apostrophes", "")
+  call s:option_init("apostrophes_list", split(s:get('apostrophes', ''), ":\s*"))
+  " tab2exit
+  call s:option_init("tab2exit", 1)
+  " balance_matchpairs
+  call s:option_init("balance_matchpairs", 0)
+  " eol marker
+  call s:option_init("insert_eol_marker", 1)
+  call s:option_init("eol_marker", "")
+  " Everything is fine.
+  return 1
+endfunction "}}} Init()
+
+function! s:get(name, default) "{{{
+  let bufoptions = delimitMate#Get()
+  return get(bufoptions, a:name, a:default)
+endfunction "}}}
+
+function! s:set(...) " {{{
+  return call('delimitMate#Set', a:000)
+endfunction " }}}
+
+function! s:Map() "{{{
+  " Set mappings:
+  try
+    let save_keymap = &keymap
+    let save_iminsert = &iminsert
+    let save_imsearch = &imsearch
+    let save_cpo = &cpo
+    set keymap=
+    set cpo&vim
+    silent! doautocmd <nomodeline> User delimitMate_map
+    if s:get('autoclose', 1)
+      call s:AutoClose()
+    else
+      call s:NoAutoClose()
+    endif
+    call s:ExtraMappings()
+  finally
+    let &cpo = save_cpo
+    let &keymap = save_keymap
+    let &iminsert = save_iminsert
+    let &imsearch = save_imsearch
+  endtry
+
+  let b:delimitMate_enabled = 1
+endfunction "}}} Map()
+
+function! s:Unmap() " {{{
+  let imaps =
+        \ s:get('right_delims', []) +
+        \ s:get('left_delims', []) +
+        \ s:get('quotes_list', []) +
+        \ s:get('apostrophes_list', []) +
+        \ ['<BS>', '<C-h>', '<S-BS>', '<Del>', '<CR>', '<Space>', '<S-Tab>', '<Esc>'] +
+        \ ['<Up>', '<Down>', '<Left>', '<Right>', '<LeftMouse>', '<RightMouse>'] +
+        \ ['<C-Left>', '<C-Right>'] +
+        \ ['<Home>', '<End>', '<PageUp>', '<PageDown>', '<S-Down>', '<S-Up>', '<C-G>g']
+
+  for map in imaps
+    if maparg(map, "i") =~# '^<Plug>delimitMate'
+      if map == '|'
+        let map = '<Bar>'
+      endif
+      exec 'silent! iunmap <buffer> ' . map
+    endif
+  endfor
+  silent! doautocmd <nomodeline> User delimitMate_unmap
+  let b:delimitMate_enabled = 0
+endfunction " }}} s:Unmap()
+
+function! s:test() "{{{
+  if &modified
+    let confirm = input("Modified buffer, type \"yes\" to write and proceed "
+          \ . "with test: ") ==? 'yes'
+    if !confirm
+      return
+    endif
+  endif
+  call delimitMate#Test()
+  g/\%^$/d
+  0
+endfunction "}}}
+
+function! s:setup(...) "{{{
+  let swap = a:0 && a:1 == 2
+  let enable = a:0 && a:1
+  let disable = a:0 && !a:1
+  " First, remove all magic, if needed:
+  if get(b:, 'delimitMate_enabled', 0)
+    call s:Unmap()
+    " Switch
+    if swap
+      echo "delimitMate is disabled."
+      return
+    endif
+  endif
+  if disable
+    " Just disable the mappings.
+    return
+  endif
+  if !a:0
+    " Check if this file type is excluded:
+    if exists("g:delimitMate_excluded_ft") &&
+          \ index(split(g:delimitMate_excluded_ft, ','), &filetype, 0, 1) >= 0
+      " Finish here:
+      return 1
+    endif
+    " Check if user tried to disable using b:loaded_delimitMate
+    if exists("b:loaded_delimitMate")
+      return 1
+    endif
+  endif
+  " Initialize settings:
+  if ! s:init()
+    " Something went wrong.
+    return
+  endif
+  if enable || swap || !get(g:, 'delimitMate_offByDefault', 0)
+    " Now, add magic:
+    call s:Map()
+    if a:0
+      echo "delimitMate is enabled."
+    endif
+  endif
+endfunction "}}}
+
+function! s:TriggerAbb() "{{{
+  if v:version < 703
+        \ || ( v:version == 703 && !has('patch489') )
+        \ || pumvisible()
+    return ''
+  endif
+  return "\<C-]>"
+endfunction "}}}
+
+function! s:NoAutoClose() "{{{
+  " inoremap <buffer> ) <C-R>=delimitMate#SkipDelim('\)')<CR>
+  for delim in s:get('right_delims', []) + s:get('quotes_list', [])
+    if delim == '|'
+      let delim = '<Bar>'
+    endif
+    exec 'inoremap <silent> <Plug>delimitMate' . delim . ' <C-R>=<SID>TriggerAbb().delimitMate#SkipDelim("' . escape(delim,'"') . '")<CR>'
+    exec 'silent! imap <unique> <buffer> '.delim.' <Plug>delimitMate'.delim
+  endfor
+endfunction "}}}
+
+function! s:AutoClose() "{{{
+  " Add matching pair and jump to the midle:
+  " inoremap <silent> <buffer> ( ()<Left>
+  let i = 0
+  while i < len(s:get('matchpairs_list', []))
+    let ld = s:get('left_delims', [])[i] == '|' ? '<bar>' : s:get('left_delims', [])[i]
+    let rd = s:get('right_delims', [])[i] == '|' ? '<bar>' : s:get('right_delims', [])[i]
+    exec 'inoremap <expr><silent> <Plug>delimitMate' . ld
+                \. ' <SID>TriggerAbb().delimitMate#ParenDelim("' . escape(rd, '|') . '")'
+    exec 'silent! imap <unique> <buffer> '.ld
+                \.' <Plug>delimitMate'.ld
+    let i += 1
+  endwhile
+
+  " Exit from inside the matching pair:
+  for delim in s:get('right_delims', [])
+    let delim = delim == '|' ? '<bar>' : delim
+    exec 'inoremap <expr><silent> <Plug>delimitMate' . delim
+                \. ' <SID>TriggerAbb().delimitMate#JumpOut("\' . delim . '")'
+    exec 'silent! imap <unique> <buffer> ' . delim
+                \. ' <Plug>delimitMate'. delim
+  endfor
+
+  " Add matching quote and jump to the midle, or exit if inside a pair of matching quotes:
+  " inoremap <silent> <buffer> " <C-R>=delimitMate#QuoteDelim("\"")<CR>
+  for delim in s:get('quotes_list', [])
+    if delim == '|'
+      let delim = '<Bar>'
+    endif
+    exec 'inoremap <expr><silent> <Plug>delimitMate' . delim
+                \. ' <SID>TriggerAbb()."<C-R>=delimitMate#QuoteDelim(\"\\\' . delim . '\")<CR>"'
+    exec 'silent! imap <unique> <buffer> ' . delim
+                \. ' <Plug>delimitMate' . delim
+  endfor
+
+  " Try to fix the use of apostrophes (kept for backward compatibility):
+  " inoremap <silent> <buffer> n't n't
+  for map in s:get('apostrophes_list', [])
+    exec "inoremap <silent> " . map . " " . map
+    exec 'silent! imap <unique> <buffer> ' . map . ' <Plug>delimitMate' . map
+  endfor
+endfunction "}}}
+
+function! s:ExtraMappings() "{{{
+  " If pair is empty, delete both delimiters:
+  inoremap <silent> <Plug>delimitMateBS <C-R>=delimitMate#BS()<CR>
+  if !hasmapto('<Plug>delimitMateBS','i')
+    if empty(maparg('<BS>', 'i'))
+      silent! imap <unique> <buffer> <BS> <Plug>delimitMateBS
+    endif
+    if empty(maparg('<C-H>', 'i'))
+      silent! imap <unique> <buffer> <C-h> <Plug>delimitMateBS
+    endif
+  endif
+  " If pair is empty, delete closing delimiter:
+  inoremap <silent> <expr> <Plug>delimitMateS-BS delimitMate#WithinEmptyPair() ? "\<Del>" : "\<S-BS>"
+  if !hasmapto('<Plug>delimitMateS-BS','i') && maparg('<S-BS>', 'i') == ''
+    silent! imap <unique> <buffer> <S-BS> <Plug>delimitMateS-BS
+  endif
+  " Expand return if inside an empty pair:
+  inoremap <expr><silent> <Plug>delimitMateCR <SID>TriggerAbb()."\<C-R>=delimitMate#ExpandReturn()\<CR>"
+  if s:get('expand_cr', 0) && !hasmapto('<Plug>delimitMateCR', 'i') && maparg('<CR>', 'i') == ''
+    silent! imap <unique> <buffer> <CR> <Plug>delimitMateCR
+  endif
+  " Expand space if inside an empty pair:
+  inoremap <expr><silent> <Plug>delimitMateSpace <SID>TriggerAbb()."\<C-R>=delimitMate#ExpandSpace()\<CR>"
+  if s:get('expand_space', 0) && !hasmapto('<Plug>delimitMateSpace', 'i') && maparg('<Space>', 'i') == ''
+    silent! imap <unique> <buffer> <Space> <Plug>delimitMateSpace
+  endif
+  " Jump over any delimiter:
+  inoremap <expr><silent> <Plug>delimitMateS-Tab <SID>TriggerAbb()."\<C-R>=delimitMate#JumpAny()\<CR>"
+  if s:get('tab2exit', 0) && !hasmapto('<Plug>delimitMateS-Tab', 'i') && maparg('<S-Tab>', 'i') == ''
+    silent! imap <unique> <buffer> <S-Tab> <Plug>delimitMateS-Tab
+  endif
+  " Jump over next delimiters
+  inoremap <expr><buffer> <Plug>delimitMateJumpMany <SID>TriggerAbb()."\<C-R>=delimitMate#JumpMany()\<CR>"
+  if !hasmapto('<Plug>delimitMateJumpMany', 'i') && maparg("<C-G>g", 'i') == ''
+    imap <silent> <buffer> <C-G>g <Plug>delimitMateJumpMany
+  endif
+endfunction "}}}
+
+"}}}
+
+" Commands: {{{
+
+" Let me refresh without re-loading the buffer:
+command! -bar DelimitMateReload call s:setup(1)
+" Quick test:
+command! -bar DelimitMateTest call s:test()
+" Switch On/Off:
+command! -bar DelimitMateSwitch call s:setup(2)
+" Enable mappings:
+command! -bar DelimitMateOn call s:setup(1)
+" Disable mappings:
+command! -bar DelimitMateOff call s:setup(0)
+
+"}}}
+
+" Autocommands: {{{
+
+augroup delimitMate
+  au!
+  " Run on file type change.
+  au FileType * call <SID>setup()
+  au FileType python let b:delimitMate_nesting_quotes = ['"', "'"]
+
+  " Run on new buffers.
+  au BufNewFile,BufRead,BufEnter,CmdwinEnter *
+        \ if !exists('b:delimitMate_was_here') |
+        \   call <SID>setup() |
+        \   let b:delimitMate_was_here = 1 |
+        \ endif
+augroup END
+
+"}}}
+
+" This is for the default buffer when it does not have a filetype.
+call s:setup()
+
+let &cpo = save_cpo
+" GetLatestVimScripts: 2754 1 :AutoInstall: delimitMate.vim
+" vim:foldmethod=marker:foldcolumn=4:ts=2:sw=2

test/Makefile

@@ -0,0 +1,9 @@
+all: build/runVimTests
+	build/runVimTests/bin/runVimTests.sh -0 .
+
+build/runVimTests: build/VimTAP
+	git clone https://github.com/inkarkat/runVimTests $@
+
+# Use VimTAP as directory name, as used with runVimTestsSetup.vim.
+build/VimTAP:
+	git clone https://github.com/inkarkat/vimtap $@

test/README.md

@@ -0,0 +1,18 @@
+# Automatic test setup
+You can use `make` (or `make test` from the top level directory) to run the
+tests.
+
+# Manual test setup instructions
+The plugins [runVimTests](http://www.vim.org/scripts/script.php?script_id=2565)
+and [VimTAP](http://www.vim.org/scripts/script.php?script_id=2213) are needed
+to run these tests.
+
+Besides the `_setup.vim` configuration file present in this repo you need to
+create a global one and place it in the same dir where the runVimTests
+executable is located. Assuming the executable is at '~/bin/runVimTests' this
+global configuration file should be '~/bin/runVimTestsSetup.vim' and should
+have something like the following lines inside of it:
+
+    " Prepend tests repos to &rtp
+    let &runtimepath = '/path/to/runVimTests_dir,' . &rtp
+    let &runtimepath = '/path/to/vimTAP_dir,' . &rtp

test/_setup.vim

@@ -0,0 +1,12 @@
+let &rtp = expand('<sfile>:p:h:h') . ',' . &rtp . ',' . expand('<sfile>:p:h:h') . '/after'
+set bs=2
+ru plugin/delimitMate.vim
+let runVimTests = expand('<sfile>:p:h').'/build/runVimTests'
+if isdirectory(runVimTests)
+  let &rtp = runVimTests . ',' . &rtp
+endif
+let vimTAP = expand('<sfile>:p:h').'/build/VimTAP'
+if isdirectory(vimTAP)
+  let &rtp = vimTAP . ',' . &rtp
+endif
+

test/autoclose_matchpairs.txt

@@ -0,0 +1,51 @@
+let g:delimitMate_autoclose = 1
+"(x" "(x)"
+"(\<BS>x" "x"
+"()x" "()x"
+"((\<C-G>gx" "(())x"
+"(x\<Esc>u" ""
+"@(x" "@(x)"
+"@#\<Left>(x" "@(x)#"
+"(\<S-Tab>x" "()x"
+let g:delimitMate_autoclose = 0
+"(x" "(x"
+"()x" "(x)"
+"())x" "()x"
+"()\<BS>x" "x"
+"@()x" "@(x)"
+"@#\<Left>()x" "@(x)#"
+let g:delimitMate_expand_space = 1
+let g:delimitMate_autoclose = 1
+"(\<Space>x" "( x )"
+"(\<Space>\<BS>x" "(x)"
+let g:delimitMate_autoclose = 0
+"()\<Space>\<BS>x" "(x)"
+let g:delimitMate_autoclose = 1
+# Handle backspace gracefully.
+set backspace=
+"(\<Esc>a\<BS>x" "(x)"
+set bs=2
+# closing parens removes characters. #133
+"(a\<Esc>i)" "()a)"
+
+# Add semicolon next to the closing paren. Issue #77.
+new
+let b:delimitMate_eol_marker = ';'
+"abc(x" "abc(x);"
+%d
+# BS should behave accordingly.
+"abc(\<BS>" "abc;"
+# Expand iabbreviations
+unlet b:delimitMate_eol_marker
+iabb def ghi
+"def(" "ghi()"
+iunabb def
+
+"abc а\<Left>(" "abc (а"
+"abc ñ\<Left>(" "abc (ñ"
+"abc $\<Left>(" "abc ($"
+"abc £\<Left>(" "abc (£"
+"abc d\<Left>(" "abc (d"
+"abc \<C-V>(\<Left>(" "abc (("
+"abc .\<Left>(" "abc ()."
+"abc  \<Left>(" "abc () "

test/autoclose_matchpairs.vim

@@ -0,0 +1,42 @@
+let g:delimitMate_matchpairs = '(:),{:},[:],<:>,¿:?,¡:!,,::'
+let lines = readfile(expand('<sfile>:t:r').'.txt')
+call vimtest#StartTap()
+let testsnumber = len(filter(copy(lines), 'v:val =~ ''^"'''))
+let itemsnumber = len(split(g:delimitMate_matchpairs, '.:.\zs,\ze.:.'))
+call vimtap#Plan(testsnumber * itemsnumber)
+let tcount = 1
+let reload = 1
+for item in lines
+  if item =~ '^#\|^\s*$'
+    " A comment or empty line.
+    continue
+  endif
+  if item !~ '^"'
+    " A command.
+    exec item
+    call vimtap#Diag(item)
+    let reload = 1
+    continue
+  endif
+  if reload
+    DelimitMateReload
+    call vimtap#Diag('DelimitMateReload')
+    let reload = 0
+  endif
+  let [input, output] = split(item, '"\%(\\.\|[^\\"]\)*"\zs\s*\ze"\%(\\.\|[^\\"]\)*"')
+  for [s:l,s:r] in map(split(g:delimitMate_matchpairs, '.:.\zs,\ze.:.'), 'split(v:val, ''.\zs:\ze.'')')
+    let input2 = substitute(input, '(', s:l, 'g')
+    let input2 = substitute(input2, ')', s:r, 'g')
+    let output2 = substitute(output, '(', s:l, 'g')
+    let output2 = substitute(output2, ')', s:r, 'g')
+    %d
+    exec 'normal i'.eval(input2)."\<Esc>"
+    let line = getline('.')
+    let passed = line == eval(output2)
+    call vimtap#Is(line, eval(output2), input2)
+    ", input2 . ' => ' . string(line) .
+    "      \ (passed ? ' =' : ' !') . '= ' . string(eval(output2)))
+    let tcount += 1
+  endfor
+endfor
+call vimtest#Quit()

test/autoclose_quotes.txt

@@ -0,0 +1,73 @@
+let g:delimitMate_autoclose = 1
+"'x" "'x'"
+"'x\<Esc>u" ""
+"''x" "''x"
+"'\<BS>x" "x"
+"'\<C-G>gx" "''x"
+# This will fail for double quote.
+"'\"x" "'\"x\"'"
+"@'x" "@'x'"
+"@#\<Left>'x" "@'x'#"
+"'\<S-Tab>x" "''x"
+"abc'" "abc'"
+"abc\\'x" "abc\\'x"
+"u'Привет'" "u'Привет'"
+"u'string'" "u'string'"
+let g:delimitMate_autoclose = 0
+"'x" "'x"
+"''x" "'x'"
+"'''x" "''x"
+"''\<BS>x" "x"
+"@''x" "@'x'"
+"@#\<Left>''x" "@'x'#"
+let g:delimitMate_expand_space = 1
+let g:delimitMate_autoclose = 1
+"'\<Space>x" "' x'"
+let g:delimitMate_expand_inside_quotes = 1
+"'\<Space>x" "' x '"
+"'\<Space>\<BS>x" "'x'"
+"abc\\''\<Space>x" "abc\\' x'"
+let g:delimitMate_autoclose = 0
+"''\<Space>\<BS>x" "'x'"
+let g:delimitMate_autoclose = 1
+# Handle backspace gracefully.
+set backspace=
+"'\<Esc>a\<BS>x" "'x'"
+set backspace=2
+set cpo=ces$
+"'x" "'x'"
+# Make sure smart quote works beyond first column.
+" 'x" " 'x'"
+# smart quote, check fo char on the right.
+"a\<space>b\<left>'" "a 'b"
+# Make sure we jump over a quote on the right. #89.
+"('test'x" "('test'x)"
+# Duplicate whole line when inserting quote at bol #105
+"}\<Home>'" "''}"
+"'\<Del>abc  '" "'abc  '"
+"''abc '" "''abc ''"
+# Nesting quotes:
+let g:delimitMate_nesting_quotes = split(g:delimitMate_quotes, '\s\+')
+"'''x" "'''x'''"
+"''''x" "''''x''''"
+"''x" "''x"
+"'x" "'x'"
+unlet g:delimitMate_nesting_quotes
+# expand iabbreviations
+iabb def ghi
+"def'" "ghi'"
+let g:delimitMate_smart_quotes = '\w\%#\_.'
+"xyz'x" "xyz'x"
+"xyz 'x" "xyz 'x'"
+let g:delimitMate_smart_quotes = '\s\%#\_.'
+"abc'x" "abc'x'"
+"abc 'x" "abc 'x"
+# let's try the negated form
+let g:delimitMate_smart_quotes = '!\w\%#\_.'
+"cba'x" "cba'x'"
+"cba 'x" "cba 'x"
+let g:delimitMate_smart_quotes = '!\s\%#\_.'
+"zyx'x" "zyx'x"
+"zyx 'x" "zyx 'x'"
+unlet g:delimitMate_smart_quotes
+"'\<CR>\<BS>" "''"

test/autoclose_quotes.vim

@@ -0,0 +1,47 @@
+"let g:delimitMate_quotes = '" '' ` ” « |'
+let g:delimitMate_quotes = '" '' ` « |'
+let lines = readfile(expand('<sfile>:t:r').'.txt')
+call vimtest#StartTap()
+let testsnumber = len(filter(copy(lines), 'v:val =~ ''^"'''))
+let itemsnumber = len(split(g:delimitMate_quotes, ' '))
+call vimtap#Plan(testsnumber * itemsnumber)
+let reload = 1
+let tcount = 1
+let linenr = 0
+for item in lines
+  let linenr += 1
+  if item =~ '^#\|^\s*$'
+    " A comment or empty line.
+    continue
+  endif
+  if item !~ '^"'
+    " A command.
+    exec item
+    call vimtap#Diag(item)
+    let reload = 1
+    continue
+  endif
+  if reload
+    DelimitMateReload
+    call vimtap#Diag('DelimitMateReload')
+    let reload = 0
+  endif
+  let quotes = split(g:delimitMate_quotes, '\s')
+  for quote in quotes
+    if vimtap#Skip(1, tcount != 26, "This test is invalid for double quote.")
+      let tcount += 1
+      continue
+    endif
+    let [input, output] = split(item, '"\%(\\.\|[^\\"]\)*"\zs\s*\ze"\%(\\.\|[^\\"]\)*"')
+    let input_q = substitute(input,"'" , escape(escape(quote, '"'), '\'), 'g')
+    let output_q = substitute(output,"'" , escape(escape(quote, '"'), '\'), 'g')
+    %d
+    exec 'normal i'.eval(input_q)."\<Esc>"
+    if quote == '”'
+      call vimtap#Todo(1)
+    endif
+    call vimtap#Is(getline('.'), eval(output_q), 'Line '.linenr.': '.eval(substitute(input_q, '\\<', '<','g')))
+    let tcount += 1
+  endfor
+endfor
+call vimtest#Quit()

test/eol_marker.vim

@@ -0,0 +1,44 @@
+let g:delimitMate_expand_cr = 1
+let g:delimitMate_eol_marker = ';'
+call vimtest#StartTap()
+call vimtap#Plan(8)
+" NOTE: Do not forget to update the plan ^
+let g:delimitMate_insert_eol_marker = 0
+DelimitMateReload
+normal i(
+call vimtap#Is(getline(1), '()', 'value = 1, case 1')
+%d _
+exec "normal i(\<CR>x"
+call vimtap#Like(join(getline(1,line('$')), "\<NL>"),
+      \ '^(\n\s*x\n)$', ' "normal i(\<CR>x", Value = 2, case 2')
+let g:delimitMate_insert_eol_marker = 1
+DelimitMateReload
+%d _
+normal i(
+call vimtap#Is(getline(1), '();', '"normal i(", value = 1, case 1')
+%d _
+exec "normal i(\<CR>x"
+call vimtap#Like(join(getline(1,line('$')), "\<NL>"),
+      \ '^(\n\s*x\n);$', '"normal i(\<CR>x", Value = 2, case 2')
+%d _
+let g:delimitMate_insert_eol_marker = 2
+DelimitMateReload
+normal i(
+call vimtap#Is(getline(1), '()', '"normal i(", Value = 2, case 1')
+%d _
+exec "normal i(\<CR>x"
+call vimtap#Like(join(getline(1,line('$')), "\<NL>"),
+      \ '^(\n\s*x\n);$', '"normal i(\<CR>x", Value = 2, case 2')
+
+%d _
+exec "normal i{(\<CR>x"
+call vimtap#Like(join(getline(1,line('$')), "\<NL>"),
+      \ '^{(\n\s*x\n)};$', ' "normal i{(\<CR>x", Value = 2, case 3')
+
+%d _
+exec "normal i;\<Esc>I{(\<CR>x"
+call vimtap#Like(join(getline(1,line('$')), "\<NL>"),
+      \ '^{(\n\s*x\n)};$', ' "normal i{(\<CR>x", Value = 2, case 4')
+
+" End: quit vim.
+call vimtest#Quit()

test/expand_cr.txt

@@ -0,0 +1,96 @@
+# 
+%d
+filetype indent on
+set bs=2 et sts=4 sw=4 ft=javascript
+call setline(1, '$(document).ready(function() {})')
+DelimitMateReload
+exec "normal 31|i\<CR>x\<Esc>"
+================================================================================
+$(document).ready(function() {
+    x
+})
+--------------------------------------------------------------------------------
+# Issue #95
+new
+let b:delimitMate_jump_expansion = 1
+DelimitMateReload
+exec "normal i(\<CR>test)x"
+================================================================================
+(
+test
+)x
+--------------------------------------------------------------------------------
+# Remove CR expansion on BS
+%d
+exec "normal i(\<CR>\<BS>x"
+================================================================================
+(x)
+--------------------------------------------------------------------------------
+# Consider indentation with BS inside an empty CR expansion.
+%d
+exec "normal i(  \<CR>\<BS>\<BS>x"
+================================================================================
+(x)
+--------------------------------------------------------------------------------
+# Conflict with indentation settings (cindent). Issue #95
+se cindent
+call setline(1, ['sub foo {','    while (1) {', '        ', '    }', '}'])
+call cursor(3, 8)
+normal a}x
+================================================================================
+sub foo {
+    while (1) {
+        
+    }x
+}
+--------------------------------------------------------------------------------
+%d
+call setline(1, '"{bracketed}')
+normal A"x
+================================================================================
+"{bracketed}"x
+--------------------------------------------------------------------------------
+# Syntax folding enabled by autocmd breaks expansion. But ti can't be tested
+# with :normal
+new
+autocmd InsertEnter * let w:fdm=&foldmethod | setl foldmethod=manual
+autocmd InsertLeave * let &foldmethod = w:fdm
+set foldmethod=marker
+set foldmarker={,}
+set foldlevel=0
+set backspace=2
+exec "normal iabc {\<CR>x"
+================================================================================
+abc {
+    x
+}
+--------------------------------------------------------------------------------
+# expand_cr != 2
+%d_
+call setline(1, 'abc(def)')
+exec "normal $i\<CR>x"
+================================================================================
+abc(def
+        x)
+--------------------------------------------------------------------------------
+# expand_cr == 2
+%d_
+let delimitMate_expand_cr = 2
+DelimitMateReload
+call setline(1, 'abc(def)')
+exec "normal $i\<CR>x"
+================================================================================
+abc(def
+        x
+        )
+--------------------------------------------------------------------------------
+# Play nice with smartindent
+%d_
+set all&
+set smartindent
+exec "normal $i{\<CR>x"
+================================================================================
+{
+	x
+}
+--------------------------------------------------------------------------------

test/expand_cr.vim

@@ -0,0 +1,55 @@
+let g:delimitMate_expand_cr = 1
+"DelimitMateReload
+let lines = readfile(expand('<sfile>:t:r').'.txt')
+call vimtest#StartTap()
+let testsnumber = len(filter(copy(lines), 'v:val =~ ''^=\{80}$'''))
+call vimtap#Plan(testsnumber)
+let tcount = 1
+let expect = 0
+let evaluate = 0
+let commands = []
+let header = ''
+for item in lines
+  if item =~ '^=\{80}$'
+    let expect = 1
+    let expected = []
+    continue
+  endif
+
+  if item =~ '^#' && expect == 0
+    " A comment.
+    let header = empty(header) ? item[1:] : 'Lines should match.'
+    continue
+  endif
+  if item =~ '^\s*$' && expect == 0
+    " An empty line.
+    continue
+  endif
+  if ! expect
+    " A command.
+    call add(commands, item)
+    exec item
+    "call vimtap#Diag(item)
+    continue
+  endif
+  if item =~ '^-\{80}$'
+    let expect = 0
+  endif
+  if expect
+    call add(expected, item)
+    continue
+  endif
+  let lines = getline(1, line('$'))
+  let passed = lines == expected
+  echom string(lines)
+  echom string(expected)
+  call vimtap#Is(lines, expected, header)
+  echom string(commands)
+  for cmd in commands
+    call vimtap#Diag(cmd)
+  endfor
+  let commands = []
+  let header = ''
+  let tcount += 1
+endfor
+call vimtest#Quit()

test/expand_space.txt

@@ -0,0 +1,8 @@
+# Issue #95
+new
+let b:delimitMate_jump_expansion = 1
+DelimitMateReload
+exec "normal i( test)x"
+================================================================================
+( test )x
+--------------------------------------------------------------------------------

test/expand_space.vim

@@ -0,0 +1,42 @@
+let g:delimitMate_expand_space = 1
+"DelimitMateReload
+let lines = readfile(expand('<sfile>:t:r').'.txt')
+call vimtest#StartTap()
+let testsnumber = len(filter(copy(lines), 'v:val =~ ''^=\{80}$'''))
+call vimtap#Plan(testsnumber)
+let tcount = 1
+let expect = 0
+let evaluate = 0
+for item in lines
+  if item =~ '^=\{80}$'
+    let expect = 1
+    let expected = []
+    continue
+  endif
+
+  if item =~ '^#\|^\s*$' && expect == 0
+    " A comment or empty line.
+    continue
+  endif
+  if ! expect
+    " A command.
+    exec item
+    call vimtap#Diag(item)
+    continue
+  endif
+  if item =~ '^-\{80}$'
+    let expect = 0
+  endif
+  if expect
+    call add(expected, item)
+    continue
+  endif
+  let lines = getline(1, line('$'))
+  let passed = lines == expected
+  echom string(lines)
+  echom string(expected)
+  call vimtap#Ok(passed, string(expected) .
+        \ (passed ? ' =' : ' !') . '= ' . string(lines))
+  let tcount += 1
+endfor
+call vimtest#Quit()

test/first_buffer_no_ft.vim

@@ -0,0 +1,8 @@
+let g:delimitMate_expand_cr = 1
+let g:delimitMate_eol_marker = ';'
+call vimtest#StartTap()
+call vimtap#Plan(1)
+call vimtap#Like(maparg('(', 'i'), '<Plug>delimitMate(', 'Mappings defined for the first buffer without filetype set.')
+call vimtest#Quit()
+
+